mdw@git.distorted.org.uk Git - lisp/blob - mdw-base.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; $Id$
   4 ;;;
   5 ;;; Basic definitions
   6 ;;;
   7 ;;; (c) 2005 Mark Wooding
   8 ;;;
   9
  10 ;;;----- Licensing notice ---------------------------------------------------
  11 ;;;
  12 ;;; This program is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; This program is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with this program; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 ;;;--------------------------------------------------------------------------
  27 ;;; Package things.
  28
  29 (defpackage #:mdw.base
  30   (:use #:common-lisp)
  31   (:export #:compile-time-defun
  32            #:show
  33            #:stringify #:listify #:fix-pair #:pairify #:parse-body
  34            #:whitespace-char-p
  35            #:slot-uninitialized
  36            #:nlet #:while #:case2 #:ecase2
  37            #:with-gensyms #:let*/gensyms #:with-places
  38            #:locp #:locf #:ref #:with-locatives
  39            #:update-place #:update-place-after
  40            #:incf-after #:decf-after))
  41 (in-package #:mdw.base)
  42
  43 ;;;--------------------------------------------------------------------------
  44 ;;; Some simple macros to get things going.
  45
  46 (defmacro compile-time-defun (name args &body body)
  47   "Define a function which can be used by macros during the compilation
  48 process."
  49   `(eval-when (:compile-toplevel :load-toplevel)
  50      (defun ,name ,args ,@body)))
  51
  52 (defmacro show (x)
  53   "Debugging tool: print the expression X and its value."
  54   (let ((tmp (gensym)))
  55     `(let ((,tmp ,x))
  56        (format t "~&~S: ~S~%" ',x ,tmp)
  57        ,tmp)))
  58
  59 (defun stringify (str)
  60   "Return a string representation of STR.  Strings are returned unchanged;
  61 symbols are converted to their names (unqualified!).  Other objects are
  62 converted to their print representations."
  63   (typecase str
  64     (string str)
  65     (symbol (symbol-name str))
  66     (t (with-output-to-string (s)
  67          (princ str s)))))
  68
  69 (compile-time-defun listify (x)
  70   "If X is a (possibly empty) list, return X; otherwise return (list X)."
  71   (if (listp x) x (list x)))
  72
  73 (compile-time-defun do-fix-pair (x y defaultp)
  74   "Helper function for fix-pair and pairify."
  75   (flet ((singleton (x) (values x (if defaultp y x))))
  76     (cond ((atom x) (singleton x))
  77           ((null (cdr x)) (singleton (car x)))
  78           ((atom (cdr x)) (values (car x) (cdr x)))
  79           ((cddr x) (error "Too many elements for a pair."))
  80           (t (values (car x) (cadr x))))))
  81
  82 (compile-time-defun fix-pair (x &optional (y nil defaultp))
  83   "Return two values extracted from X.  It works as follows:
  84   (A) -> A, Y
  85   (A B) -> A, B
  86   (A B . C) -> error
  87   (A . B) -> A, B
  88   A -> A, Y
  89 where Y defaults to A if not specified."
  90   (do-fix-pair x y defaultp))
  91
  92 (compile-time-defun pairify (x &optional (y nil defaultp))
  93   "As for fix-pair, but returns a list instead of two values."
  94   (multiple-value-call #'list (do-fix-pair x y defaultp)))
  95
  96 (defun whitespace-char-p (ch)
  97   "Return whether CH is a whitespace character or not."
  98   (case ch
  99     ((#\space #\tab #\newline #\return #\vt #\formfeed) t)
 100     (t nil)))
 101
 102 (declaim (ftype (function nil ()) slot-unitialized))
 103 (defun slot-uninitialized ()
 104   "A function which signals an error.  Can be used as an initializer form in
 105 structure definitions without doom ensuing."
 106   (error "No initializer for slot."))
 107
 108 (compile-time-defun parse-body (body)
 109   "Given a BODY (a list of forms), parses it into three sections: a
 110 docstring, a list of declarations (forms beginning with the symbol `declare')
 111 and the body forms.  The result is returned as three lists (even the
 112 docstring), suitable for interpolation into a backquoted list using `@,'."
 113   (multiple-value-bind
 114       (doc body)
 115       (if (and (consp body)
 116                (stringp (car body)))
 117           (values (list (car body)) (cdr body))
 118           (values nil body))
 119     (loop for forms on body
 120           for form = (car forms)
 121           while (and (consp form)
 122                      (eq (car form) 'declare))
 123           collect form into decls
 124           finally (return (values doc decls forms)))))
 125
 126 ;;;--------------------------------------------------------------------------
 127 ;;; Generating symbols.
 128
 129 (defmacro with-gensyms (syms &body body)
 130   "Everyone's favourite macro helper."
 131   `(let (,@(mapcar (lambda (sym) `(,sym (gensym ,(symbol-name sym))))
 132                    (listify syms)))
 133      ,@body))
 134
 135 (defmacro let*/gensyms (binds &body body)
 136   "A macro helper.  BINDS is a list of binding pairs (VAR VALUE), where VALUE
 137 defaults to VAR.  The result is that BODY is evaluated in a context where
 138 each VAR is bound to a gensym, and in the final expansion, each of those
 139 gensyms will be bound to the corresponding VALUE."
 140   (labels ((more (binds)
 141              (let ((tmp (gensym "TMP")) (bind (car binds)))
 142                `((let ((,tmp ,(cadr bind))
 143                        (,(car bind) (gensym ,(symbol-name (car bind)))))
 144                    `(let ((,,(car bind) ,,tmp))
 145                       ,,@(if (cdr binds)
 146                              (more (cdr binds))
 147                              body)))))))
 148     (if (null binds)
 149         `(progn ,@body)
 150         (car (more (mapcar #'pairify (listify binds)))))))
 151
 152 ;;;--------------------------------------------------------------------------
 153 ;;; Some simple yet useful control structures.
 154
 155 (defmacro nlet (name binds &body body)
 156   "Scheme's named let."
 157   (multiple-value-bind (vars vals)
 158       (loop for bind in binds
 159             for (var val) = (pairify bind nil)
 160             collect var into vars
 161             collect val into vals
 162             finally (return (values vars vals)))
 163     `(labels ((,name ,vars
 164                 ,@body))
 165        (,name ,@vals))))
 166
 167 (defmacro while (cond &body body)
 168   "If COND is false, evaluate to nil; otherwise evaluate BODY and try again."
 169   `(loop
 170      (unless ,cond (return))
 171      ,@body))
 172
 173 (compile-time-defun do-case2-like (kind vform clauses)
 174   "Helper function for `case2' and `ecase2'."
 175   (with-gensyms (scrutinee argument)
 176     `(multiple-value-bind (,scrutinee ,argument) ,vform
 177        (declare (ignorable ,argument))
 178        (,kind ,scrutinee
 179          ,@(mapcar (lambda (clause)
 180                      (destructuring-bind
 181                          (cases (&optional var) &rest forms)
 182                          clause
 183                        `(,cases
 184                          ,@(if var
 185                                (list `(let ((,var ,argument)) ,@forms))
 186                                forms))))
 187                    clauses)))))
 188
 189 (defmacro case2 (vform &body clauses)
 190   "VFORM is a form which evaluates to two values, SCRUTINEE and ARGUMENT.
 191 The CLAUSES have the form (CASES ([VAR]) FORMS...), where a standard `case'
 192 clause has the form (CASES FORMS...).  The `case2' form evaluates the VFORM,
 193 and compares the SCRUTINEE to the various CASES, in order, just like `case'.
 194 If there is a match, then the corresponding FORMs are evaluated with VAR (if
 195 specified) bound to the value of ARGUMENT."
 196   (do-case2-like 'case vform clauses))
 197
 198 (defmacro ecase2 (vform &body clauses)
 199   "Like `case2', but signals an error if no clause matches the SCRUTINEE."
 200   (do-case2-like 'ecase vform clauses))
 201
 202 ;;;--------------------------------------------------------------------------
 203 ;;; with-places
 204
 205 (defmacro %place-ref (getform setform newtmp)
 206   "Grim helper macro for with-places."
 207   (declare (ignore setform newtmp))
 208   getform)
 209
 210 (define-setf-expander %place-ref (getform setform newtmp)
 211   "Grim helper macro for with-places."
 212   (values nil nil newtmp setform getform))
 213
 214 (defmacro with-places ((&key environment) places &body body)
 215   "A hairy helper, for writing setf-like macros.  PLACES is a list of binding
 216 pairs (VAR PLACE), where PLACE defaults to VAR.  The result is that BODY is
 217 evaluated in a context where each VAR is bound to a gensym, and in the final
 218 expansion, each of those gensyms will be bound to a symbol-macro capable of
 219 reading or setting the value of the corresponding PLACE."
 220   (if (null places)
 221       `(progn ,@body)
 222       (let*/gensyms (environment)
 223         (labels
 224             ((more (places)
 225                (let ((place (car places)))
 226                  (with-gensyms (tmp valtmps valforms
 227                                     newtmps setform getform)
 228                    `((let ((,tmp ,(cadr place))
 229                            (,(car place)
 230                             (gensym ,(symbol-name (car place)))))
 231                        (multiple-value-bind
 232                            (,valtmps ,valforms
 233                             ,newtmps ,setform ,getform)
 234                            (get-setf-expansion ,tmp
 235                                                ,environment)
 236                          (list 'let*
 237                                (mapcar #'list ,valtmps ,valforms)
 238                                `(symbol-macrolet ((,,(car place)
 239                                                    (%place-ref ,,getform
 240                                                                ,,setform
 241                                                                ,,newtmps)))
 242                                   ,,@(if (cdr places)
 243                                          (more (cdr places))
 244                                          body))))))))))
 245           (car (more (mapcar #'pairify (listify places))))))))
 246
 247 ;;;--------------------------------------------------------------------------
 248 ;;; Update-in-place macros built using with-places.
 249
 250 (defmacro update-place (op place arg &environment env)
 251   "Update PLACE with the value of OP PLACE ARG, returning the new value."
 252   (with-places (:environment env) (place)
 253     `(setf ,place (,op ,place ,arg))))
 254
 255 (defmacro update-place-after (op place arg &environment env)
 256   "Update PLACE with the value of OP PLACE ARG, returning the old value."
 257   (with-places (:environment env) (place)
 258     (with-gensyms (x)
 259       `(let ((,x ,place))
 260          (setf ,place (,op ,x ,arg))
 261          ,x))))
 262
 263 (defmacro incf-after (place &optional (by 1))
 264   "Increment PLACE by BY, returning the old value."
 265   `(update-place-after + ,place ,by))
 266
 267 (defmacro decf-after (place &optional (by 1))
 268   "Decrement PLACE by BY, returning the old value."
 269   `(update-place-after - ,place ,by))
 270
 271 ;;;--------------------------------------------------------------------------
 272 ;;; Locatives.
 273
 274 (defstruct (loc (:predicate locp) (:constructor make-loc (reader writer)))
 275   "Locative data type.  See `locf' and `ref'."
 276   (reader (slot-uninitialized) :type function)
 277   (writer (slot-uninitialized) :type function))
 278
 279 (defmacro locf (place &environment env)
 280   "Slightly cheesy locatives.  (locf PLACE) returns an object which, using
 281 the `ref' function, can be used to read or set the value of PLACE.  It's
 282 cheesy because it uses closures rather than actually taking the address of
 283 something.  Also, unlike Zetalisp, we don't overload `car' to do our dirty
 284 work."
 285   (multiple-value-bind
 286       (valtmps valforms newtmps setform getform)
 287       (get-setf-expansion place env)
 288     `(let* (,@(mapcar #'list valtmps valforms))
 289        (make-loc (lambda () ,getform)
 290                  (lambda (,@newtmps) ,setform)))))
 291
 292 (declaim (inline loc (setf loc)))
 293
 294 (defun ref (loc)
 295   "Fetch the value referred to by a locative."
 296   (funcall (loc-reader loc)))
 297
 298 (defun (setf ref) (new loc)
 299   "Store a new value in the place referred to by a locative."
 300   (funcall (loc-writer loc) new))
 301
 302 (defmacro with-locatives (locs &body body)
 303   "LOCS is a list of items of the form (SYM [LOC-EXPR]), where SYM is a
 304 symbol and LOC-EXPR evaluates to a locative.  If LOC-EXPR is omitted, it
 305 defaults to SYM.  As an abbreviation for a common case, LOCS may be a symbol
 306 instead of a list.  The BODY is evaluated in an environment where each SYM is
 307 a symbol macro which expands to (ref LOC-EXPR) -- or, in fact, something
 308 similar which doesn't break if LOC-EXPR has side-effects.  Thus, references,
 309 including `setf' forms, fetch or modify the thing referred to by the
 310 LOC-EXPR.  Useful for covering over where something uses a locative."
 311   (setf locs (mapcar #'pairify (listify locs)))
 312   (let ((tt (mapcar (lambda (l) (declare (ignore l)) (gensym)) locs))
 313         (ll (mapcar #'cadr locs))
 314         (ss (mapcar #'car locs)))
 315     `(let (,@(mapcar (lambda (tmp loc) `(,tmp ,loc)) tt ll))
 316        (symbol-macrolet (,@(mapcar (lambda (sym tmp)
 317                                      `(,sym (ref ,tmp))) ss tt))
 318          ,@body))))
 319
 320 ;;;----- That's all, folks --------------------------------------------------