mdw@git.distorted.org.uk Git - lisp/blob - mdw-base.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; $Id$
   4 ;;;
   5 ;;; Basic definitions
   6 ;;;
   7 ;;; (c) 2005 Mark Wooding
   8 ;;;
   9
  10 ;;;----- Licensing notice ---------------------------------------------------
  11 ;;;
  12 ;;; This program is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; This program is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with this program; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 ;;;--------------------------------------------------------------------------
  27 ;;; Package things.
  28
  29 (defpackage #:mdw.base
  30   (:use #:common-lisp)
  31   (:export #:unsigned-fixnum
  32            #:compile-time-defun
  33            #:show
  34            #:stringify #:mappend #:listify #:fix-pair #:pairify #:parse-body
  35            #:whitespace-char-p
  36            #:slot-uninitialized
  37            #:nlet #:while #:until #:case2 #:ecase2
  38            #:with-gensyms #:let*/gensyms #:with-places
  39            #:locp #:locf #:ref #:with-locatives
  40            #:update-place #:update-place-after
  41            #:incf-after #:decf-after
  42            #:fixnump)
  43   #+cmu (:import-from #:extensions #:fixnump))
  44
  45 (in-package #:mdw.base)
  46
  47 ;;;--------------------------------------------------------------------------
  48 ;;; Useful types.
  49
  50 (deftype unsigned-fixnum ()
  51   "Unsigned fixnums; useful as array indices and suchlike."
  52   `(mod ,most-positive-fixnum))
  53
  54 ;;;--------------------------------------------------------------------------
  55 ;;; Some simple macros to get things going.
  56
  57 (defmacro compile-time-defun (name args &body body)
  58   "Define a function which can be used by macros during the compilation
  59    process."
  60   `(eval-when (:compile-toplevel :load-toplevel)
  61      (defun ,name ,args ,@body)))
  62
  63 (defmacro show (x)
  64   "Debugging tool: print the expression X and its values."
  65   (let ((tmp (gensym)))
  66     `(let ((,tmp (multiple-value-list ,x)))
  67        (format t "~&")
  68        (pprint-logical-block (*standard-output* nil :per-line-prefix ";; ")
  69          (format t
  70                  "~S = ~@_~:I~:[#<no values>~;~:*~{~S~^ ~_~}~]"
  71                  ',x
  72                  ,tmp))
  73        (terpri)
  74        (values-list ,tmp))))
  75
  76 (defun stringify (str)
  77   "Return a string representation of STR.  Strings are returned unchanged;
  78    symbols are converted to their names (unqualified!).  Other objects are
  79    converted to their print representations."
  80   (typecase str
  81     (string str)
  82     (symbol (symbol-name str))
  83     (t (with-output-to-string (s)
  84          (princ str s)))))
  85
  86 (defun mappend (function list &rest more-lists)
  87   "Apply FUNCTION to corresponding elements of LIST and MORE-LISTS, yielding
  88    a list.  Return the concatenation of all the resulting lists.  Like
  89    mapcan, but nondestructive."
  90   (apply #'append (apply #'mapcar function list more-lists)))
  91
  92 (compile-time-defun listify (x)
  93   "If X is a (possibly empty) list, return X; otherwise return (list X)."
  94   (if (listp x) x (list x)))
  95
  96 (compile-time-defun do-fix-pair (x y defaultp)
  97   "Helper function for fix-pair and pairify."
  98   (flet ((singleton (x) (values x (if defaultp y x))))
  99     (cond ((atom x) (singleton x))
 100           ((null (cdr x)) (singleton (car x)))
 101           ((atom (cdr x)) (values (car x) (cdr x)))
 102           ((cddr x) (error "Too many elements for a pair."))
 103           (t (values (car x) (cadr x))))))
 104
 105 (compile-time-defun fix-pair (x &optional (y nil defaultp))
 106   "Return two values extracted from X.  It works as follows:
 107      (A) -> A, Y
 108      (A B) -> A, B
 109      (A B . C) -> error
 110      (A . B) -> A, B
 111      A -> A, Y
 112    where Y defaults to A if not specified."
 113   (do-fix-pair x y defaultp))
 114
 115 (compile-time-defun pairify (x &optional (y nil defaultp))
 116   "As for fix-pair, but returns a list instead of two values."
 117   (multiple-value-call #'list (do-fix-pair x y defaultp)))
 118
 119 (defun whitespace-char-p (ch)
 120   "Return whether CH is a whitespace character or not."
 121   (case ch
 122     ((#\space #\tab #\newline #\return #\vt
 123               #+cmu #\formfeed
 124               #+clisp #\page) t)
 125     (t nil)))
 126
 127 (declaim (ftype (function nil ()) slot-unitialized))
 128 (defun slot-uninitialized ()
 129   "A function which signals an error.  Can be used as an initializer form in
 130    structure definitions without doom ensuing."
 131   (error "No initializer for slot."))
 132
 133 (compile-time-defun parse-body (body &key (allow-docstring-p t))
 134   "Given a BODY (a list of forms), parses it into three sections: a
 135    docstring, a list of declarations (forms beginning with the symbol
 136    `declare') and the body forms.  The result is returned as three lists
 137    (even the docstring), suitable for interpolation into a backquoted list
 138    using `@,'.  If ALLOW-DOCSTRING-P is nil, docstrings aren't allowed at
 139    all."
 140   (let ((doc nil) (decls nil))
 141     (do ((forms body (cdr forms))) (nil)
 142       (let ((form (and forms (car forms))))
 143         (cond ((and allow-docstring-p (not doc) (stringp form) (cdr forms))
 144                (setf doc form))
 145               ((and (consp form)
 146                     (eq (car form) 'declare))
 147                (setf decls (append decls (cdr form))))
 148               (t (return (values (and doc (list doc))
 149                                  (and decls (list (cons 'declare decls)))
 150                                  forms))))))))
 151
 152 #-cmu
 153 (progn
 154   (declaim (inline fixnump))
 155   (defun fixnump (object)
 156     "Answer non-nil if OBJECT is a fixnum, or nil if it isn't."
 157     (typep object 'fixnum)))
 158
 159 ;;;--------------------------------------------------------------------------
 160 ;;; Generating symbols.
 161
 162 (defmacro with-gensyms (syms &body body)
 163   "Everyone's favourite macro helper."
 164   `(let (,@(mapcar (lambda (sym) `(,sym (gensym ,(symbol-name sym))))
 165                    (listify syms)))
 166      ,@body))
 167
 168 (defmacro let*/gensyms (binds &body body)
 169   "A macro helper.  BINDS is a list of binding pairs (VAR VALUE), where VALUE
 170    defaults to VAR.  The result is that BODY is evaluated in a context where
 171    each VAR is bound to a gensym, and in the final expansion, each of those
 172    gensyms will be bound to the corresponding VALUE."
 173   (labels ((more (binds)
 174              (let ((tmp (gensym "TMP")) (bind (car binds)))
 175                `((let ((,tmp ,(cadr bind))
 176                        (,(car bind) (gensym ,(symbol-name (car bind)))))
 177                    `(let ((,,(car bind) ,,tmp))
 178                       ,,@(if (cdr binds)
 179                              (more (cdr binds))
 180                              body)))))))
 181     (if (null binds)
 182         `(progn ,@body)
 183         (car (more (mapcar #'pairify (listify binds)))))))
 184
 185 ;;;--------------------------------------------------------------------------
 186 ;;; Some simple yet useful control structures.
 187
 188 (defmacro nlet (name binds &body body)
 189   "Scheme's named let."
 190   (multiple-value-bind (vars vals)
 191       (loop for bind in binds
 192             for (var val) = (pairify bind nil)
 193             collect var into vars
 194             collect val into vals
 195             finally (return (values vars vals)))
 196     `(labels ((,name ,vars
 197                 ,@body))
 198        (,name ,@vals))))
 199
 200 (defmacro while (cond &body body)
 201   "If COND is false, evaluate to nil; otherwise evaluate BODY and try again."
 202   `(loop (unless ,cond (return)) (progn ,@body)))
 203
 204 (defmacro until (cond &body body)
 205   "If COND is true, evaluate to nil; otherwise evaluate BODY and try again."
 206   `(loop (when ,cond (return)) (progn ,@body)))
 207
 208 (compile-time-defun do-case2-like (kind vform clauses)
 209   "Helper function for `case2' and `ecase2'."
 210   (with-gensyms (scrutinee argument)
 211     `(multiple-value-bind (,scrutinee ,argument) ,vform
 212        (declare (ignorable ,argument))
 213        (,kind ,scrutinee
 214          ,@(mapcar (lambda (clause)
 215                      (destructuring-bind
 216                          (cases (&optional varx vary) &rest forms)
 217                          clause
 218                        `(,cases
 219                          ,@(if varx
 220                                (list `(let ((,(or vary varx) ,argument)
 221                                             ,@(and vary
 222                                                    `((,varx ,scrutinee))))
 223                                         ,@forms))
 224                                forms))))
 225                    clauses)))))
 226
 227 (defmacro case2 (vform &body clauses)
 228   "VFORM is a form which evaluates to two values, SCRUTINEE and ARGUMENT.
 229    The CLAUSES have the form (CASES ([[SCRUVAR] ARGVAR]) FORMS...), where a
 230    standard `case' clause has the form (CASES FORMS...).  The `case2' form
 231    evaluates the VFORM, and compares the SCRUTINEE to the various CASES, in
 232    order, just like `case'.  If there is a match, then the corresponding
 233    FORMs are evaluated with ARGVAR bound to the ARGUMENT and SCRUVAR bound to
 234    the SCRUTINEE (where specified).  Note the bizarre defaulting behaviour:
 235    ARGVAR is less optional than SCRUVAR."
 236   (do-case2-like 'case vform clauses))
 237
 238 (defmacro ecase2 (vform &body clauses)
 239   "Like `case2', but signals an error if no clause matches the SCRUTINEE."
 240   (do-case2-like 'ecase vform clauses))
 241
 242 ;;;--------------------------------------------------------------------------
 243 ;;; with-places
 244
 245 (defmacro %place-ref (getform setform newtmp)
 246   "Grim helper macro for with-places."
 247   (declare (ignore setform newtmp))
 248   getform)
 249
 250 (define-setf-expander %place-ref (getform setform newtmp)
 251   "Grim helper macro for with-places."
 252   (values nil nil newtmp setform getform))
 253
 254 (defmacro with-places ((&key environment) places &body body)
 255   "A hairy helper, for writing setf-like macros.  PLACES is a list of binding
 256    pairs (VAR PLACE), where PLACE defaults to VAR.  The result is that BODY
 257    is evaluated in a context where each VAR is bound to a gensym, and in the
 258    final expansion, each of those gensyms will be bound to a symbol-macro
 259    capable of reading or setting the value of the corresponding PLACE."
 260   (if (null places)
 261       `(progn ,@body)
 262       (let*/gensyms (environment)
 263         (labels
 264             ((more (places)
 265                (let ((place (car places)))
 266                  (with-gensyms (tmp valtmps valforms
 267                                     newtmps setform getform)
 268                    `((let ((,tmp ,(cadr place))
 269                            (,(car place)
 270                             (gensym ,(symbol-name (car place)))))
 271                        (multiple-value-bind
 272                            (,valtmps ,valforms
 273                             ,newtmps ,setform ,getform)
 274                            (get-setf-expansion ,tmp
 275                                                ,environment)
 276                          (list 'let*
 277                                (mapcar #'list ,valtmps ,valforms)
 278                                `(symbol-macrolet ((,,(car place)
 279                                                    (%place-ref ,,getform
 280                                                                ,,setform
 281                                                                ,,newtmps)))
 282                                   ,,@(if (cdr places)
 283                                          (more (cdr places))
 284                                          body))))))))))
 285           (car (more (mapcar #'pairify (listify places))))))))
 286
 287 ;;;--------------------------------------------------------------------------
 288 ;;; Update-in-place macros built using with-places.
 289
 290 (defmacro update-place (op place arg &environment env)
 291   "Update PLACE with the value of OP PLACE ARG, returning the new value."
 292   (with-places (:environment env) (place)
 293     `(setf ,place (,op ,place ,arg))))
 294
 295 (defmacro update-place-after (op place arg &environment env)
 296   "Update PLACE with the value of OP PLACE ARG, returning the old value."
 297   (with-places (:environment env) (place)
 298     (with-gensyms (x)
 299       `(let ((,x ,place))
 300          (setf ,place (,op ,x ,arg))
 301          ,x))))
 302
 303 (defmacro incf-after (place &optional (by 1))
 304   "Increment PLACE by BY, returning the old value."
 305   `(update-place-after + ,place ,by))
 306
 307 (defmacro decf-after (place &optional (by 1))
 308   "Decrement PLACE by BY, returning the old value."
 309   `(update-place-after - ,place ,by))
 310
 311 ;;;--------------------------------------------------------------------------
 312 ;;; Locatives.
 313
 314 (defstruct (loc (:predicate locp) (:constructor make-loc (reader writer)))
 315   "Locative data type.  See `locf' and `ref'."
 316   (reader (slot-uninitialized) :type function)
 317   (writer (slot-uninitialized) :type function))
 318
 319 (defmacro locf (place &environment env)
 320   "Slightly cheesy locatives.  (locf PLACE) returns an object which, using
 321    the `ref' function, can be used to read or set the value of PLACE.  It's
 322    cheesy because it uses closures rather than actually taking the address of
 323    something.  Also, unlike Zetalisp, we don't overload `car' to do our dirty
 324    work."
 325   (multiple-value-bind
 326       (valtmps valforms newtmps setform getform)
 327       (get-setf-expansion place env)
 328     `(let* (,@(mapcar #'list valtmps valforms))
 329        (make-loc (lambda () ,getform)
 330                  (lambda (,@newtmps) ,setform)))))
 331
 332 (declaim (inline loc (setf loc)))
 333
 334 (defun ref (loc)
 335   "Fetch the value referred to by a locative."
 336   (funcall (loc-reader loc)))
 337
 338 (defun (setf ref) (new loc)
 339   "Store a new value in the place referred to by a locative."
 340   (funcall (loc-writer loc) new))
 341
 342 (defmacro with-locatives (locs &body body)
 343   "LOCS is a list of items of the form (SYM [LOC-EXPR]), where SYM is a
 344    symbol and LOC-EXPR evaluates to a locative.  If LOC-EXPR is omitted, it
 345    defaults to SYM.  As an abbreviation for a common case, LOCS may be a
 346    symbol instead of a list.  The BODY is evaluated in an environment where
 347    each SYM is a symbol macro which expands to (ref LOC-EXPR) -- or, in fact,
 348    something similar which doesn't break if LOC-EXPR has side-effects.  Thus,
 349    references, including `setf' forms, fetch or modify the thing referred to
 350    by the LOC-EXPR.  Useful for covering over where something uses a
 351    locative."
 352   (setf locs (mapcar #'pairify (listify locs)))
 353   (let ((tt (mapcar (lambda (l) (declare (ignore l)) (gensym)) locs))
 354         (ll (mapcar #'cadr locs))
 355         (ss (mapcar #'car locs)))
 356     `(let (,@(mapcar (lambda (tmp loc) `(,tmp ,loc)) tt ll))
 357        (symbol-macrolet (,@(mapcar (lambda (sym tmp)
 358                                      `(,sym (ref ,tmp))) ss tt))
 359          ,@body))))
 360
 361 ;;;----- That's all, folks --------------------------------------------------