git.distorted.org.uk Git - u/mdw/catacomb/blob - Makefile.m4

   1 ## -*-makefile-*-
   2 ##
   3 ## $Id: Makefile.m4,v 1.35 2000/07/16 20:00:46 mdw Exp $
   4 ##
   5 ## Makefile for Catacomb
   6 ##
   7 ## (c) 1999 Straylight/Edgeware
   8 ##
   9
  10 ##----- Licensing notice ----------------------------------------------------
  11 ##
  12 ## This file is part of Catacomb.
  13 ##
  14 ## Catacomb is free software; you can redistribute it and/or modify
  15 ## it under the terms of the GNU Library General Public License as
  16 ## published by the Free Software Foundation; either version 2 of the
  17 ## License, or (at your option) any later version.
  18 ##
  19 ## Catacomb is distributed in the hope that it will be useful,
  20 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ## GNU Library General Public License for more details.
  23 ##
  24 ## You should have received a copy of the GNU Library General Public
  25 ## License along with Catacomb; if not, write to the Free
  26 ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  27 ## MA 02111-1307, USA.
  28
  29 ##----- Revision history ----------------------------------------------------
  30 ##
  31 ## $Log: Makefile.m4,v $
  32 ## Revision 1.35  2000/07/16 20:00:46  mdw
  33 ## Bug fixes to distribution.
  34 ##
  35 ## Revision 1.34  2000/07/15 20:55:32  mdw
  36 ## More hashes and ciphers.  An extra tool.
  37 ##
  38 ## Revision 1.33  2000/07/09 21:34:15  mdw
  39 ## New hash functions and other stuff.
  40 ##
  41 ## Revision 1.32  2000/07/01 11:27:32  mdw
  42 ## Name changes and new files.
  43 ##
  44 ## Revision 1.31  2000/06/25 13:02:07  mdw
  45 ## Fix cleaning of generated files.
  46 ##
  47 ## Revision 1.30  2000/06/22 19:10:33  mdw
  48 ## Fix Makefile to test mp-sqrt.c.
  49 ##
  50 ## Revision 1.29  2000/06/22 19:04:19  mdw
  51 ## More new functions to be added.
  52 ##
  53 ## Revision 1.28  2000/06/18 23:31:18  mdw
  54 ## Rearrange build order to ensure that `mptypes.h' exists by the time it's
  55 ## needed.
  56 ##
  57 ## Revision 1.27  2000/06/17 13:28:50  mdw
  58 ## Minor tidying and fixing.
  59 ##
  60 ## Revision 1.26  2000/06/17 10:33:43  mdw
  61 ## Lots of new ciphers and other files.
  62 ##
  63 ## Revision 1.25  2000/02/12 18:55:40  mdw
  64 ## Make it all compile properly.
  65 ##
  66 ## Revision 1.24  2000/02/12 18:22:26  mdw
  67 ## Missed a file.  Whoops.
  68 ##
  69 ## Revision 1.23  2000/02/12 18:21:01  mdw
  70 ## Overhaul of key management (again).
  71 ##
  72 ## Revision 1.22  1999/12/22 16:04:06  mdw
  73 ## Lots of new files.
  74 ##
  75 ## Revision 1.21  1999/12/13 15:47:58  mdw
  76 ## Fix a couple of minor bugs in the distribution set.
  77 ##
  78 ## Revision 1.19  1999/12/11 10:58:24  mdw
  79 ## Fix bug in test rig link flags.  Add Karatsuba squaring.
  80 ##
  81 ## Revision 1.18  1999/12/10 23:30:01  mdw
  82 ## Lots of new files.
  83 ##
  84 ## Revision 1.17  1999/11/25 11:38:31  mdw
  85 ## Support for conversions between MPs and C integers.
  86 ##
  87 ## Revision 1.16  1999/11/22 20:51:33  mdw
  88 ## Add yet more source files.
  89 ##
  90 ## Revision 1.15  1999/11/22 14:08:30  mdw
  91 ## Improve dependencies for test programs.
  92 ##
  93 ## Revision 1.14  1999/11/22 00:17:09  mdw
  94 ## Create object files for test programs so that rebuilding doesn't take so
  95 ## long.
  96 ##
  97 ## Revision 1.12  1999/11/20 22:36:26  mdw
  98 ## Improve dependencies.  Move mpx testing into mpx.c.
  99 ##
 100 ## Revision 1.11  1999/11/20 22:24:53  mdw
 101 ## Add Diffie-Hellman support.
 102 ##
 103 ## Revision 1.10  1999/11/19 19:28:24  mdw
 104 ## Add DSA files and tests.
 105 ##
 106 ## Revision 1.9  1999/11/17 18:05:35  mdw
 107 ## Many new files and test cases for multiprecision arithmetic.
 108 ##
 109 ## Revision 1.8  1999/11/13 01:56:07  mdw
 110 ## Include multiprecision maths stuff.
 111 ##
 112 ## Revision 1.7  1999/11/11 19:01:02  mdw
 113 ## Use `libtool' to generate a shared library.
 114 ##
 115 ## Revision 1.6  1999/11/11 17:47:34  mdw
 116 ## Updates for new configuration system, and `mptypes' generator.
 117 ##
 118 ## Revision 1.5  1999/11/11 00:59:17  mdw
 119 ## Minor reformatting.
 120 ##
 121 ## Revision 1.4  1999/10/24 10:20:36  mdw
 122 ## Modify for standalone distribution.  The library's getting far too large
 123 ## to be sensibly embedded in other programs.
 124 ##
 125 ## Revision 1.3  1999/10/24 10:04:26  mdw
 126 ## Install headers in the right directory.
 127 ##
 128 ## Revision 1.2  1999/10/23 12:55:35  mdw
 129 ## The `CVS' directory can't be hardlinked.  Don't worry about this
 130 ## overmuch.
 131 ##
 132 ## Revision 1.1  1999/09/03 08:41:11  mdw
 133 ## Initial import.
 134 ##
 135
 136 AUTOMAKE_OPTIONS = foreign
 137
 138 SUBDIRS = tests
 139
 140 archincludedir = $(libdir)/catacomb/include
 141
 142 ## --- List handling macros ---
 143 ##
 144 ## List handling is nice, usually.  Unfortunately, I based this design on
 145 ## TeX list macros rather than anything sensible...
 146
 147 define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'')
 148 define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')')
 149 define(`join',
 150 `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')')
 151 define(`addsuffix', `adorn(`', `$1', `$2')')
 152 define(`lit', `adorn(`', `$1', `')')
 153 define(`nl', `
 154 ')
 155
 156 define(`allwithsuffix',
 157 `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl
 158 addsuffix(join(`$1', `-', `$2'), `$3')')
 159
 160 ## --- Autogenerated source files ---
 161
 162 define(`ciphers', `dnl
 163 _(des) _(des3) dnl
 164 _(idea) dnl
 165 _(blowfish) _(twofish) dnl
 166 _(tea) _(xtea) dnl
 167 _(rc2) _(rc5) dnl
 168 _(skipjack) dnl
 169 _(cast128) _(cast256) dnl
 170 _(square) _(rijndael) dnl
 171 _(serpent)')
 172 define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)')
 173
 174 define(`hashes', `dnl
 175 _(md5) _(md4) _(sha) _(tiger) dnl
 176 _(rmd128) _(rmd160) _(rmd256) _(rmd320)')
 177 define(`hash_modes', `_(mgf) _(hmac)')
 178
 179 MODES = \
 180         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \
 181         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \
 182         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \
 183         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h')
 184
 185 $(MODES):
 186         cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')"
 187         cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')"
 188
 189 des-tab.h: des-mktab
 190         ./des-mktab >des-tab.h
 191 blowfish-tab.h: blowfish-mktab
 192         ./blowfish-mktab >blowfish-tab.h
 193 twofish-tab.h: twofish-mktab
 194         ./twofish-mktab >twofish-tab.h
 195 square-tab.h: square-mktab
 196         ./square-mktab >square-tab.h
 197 rijndael-tab.h: rijndael-mktab
 198         ./rijndael-mktab >rijndael-tab.h
 199 tiger-tab.h: tiger-mktab
 200         ./tiger-mktab >tiger-tab.h
 201 gfshare-tab.h: gfshare-mktab
 202         ./gfshare-mktab >gfshare-tab.h
 203
 204 primetab.c primetab.h: genprimes
 205         ./genprimes -h primetab.h -c primetab.c -m 255 \
 206                 -t "unsigned char" -i primetab
 207
 208 archinclude_HEADERS = mptypes.h
 209
 210 mptypes.h: mptypes
 211         ./mptypes >mptypes.h
 212
 213 BUILT_SOURCES = \
 214         getdate.c \
 215         des-tab.h blowfish-tab.h twofish-tab.h rijndael-tab.h \
 216         gfshare-tab.h \
 217         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 218         addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \
 219         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 220         addsuffix(join(`hashes', `-', `hash_modes'), `.h')
 221
 222 ## --- Building the main library ---
 223
 224 lib_LTLIBRARIES = libcatacomb.la
 225
 226 libcatacomb_la_LDFLAGS = -version-info 2:0:0
 227 ## Middle number is the patchlevel.  Final number is the minor version.  The
 228 ## difference between the first and last numbers is major version.
 229
 230 pkginclude_HEADERS = \
 231         arena.h paranoia.h \
 232         blkc.h hash.h \
 233         gcipher.h ghash.h gmac.h grand.h \
 234         ghash-def.h \
 235         rc4.h seal.h \
 236         rand.h noise.h fipstest.h maurer.h \
 237         key.h key-data.h passphrase.h pixie.h lmem.h \
 238         lcrand.h fibrand.h \
 239         mpx.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \
 240         mpbarrett.h mpmont.h mpcrt.h \
 241         mprand.h mpmul.h \
 242         primetab.h pfilt.h primorial.h rabin.h \
 243         pgen.h prim.h strongprime.h limlee.h \
 244         bbs.h rsa.h dh.h dsarand.h dsa.h \
 245         oaep.h pkcs1.h \
 246         gfshare.h share.h \
 247         rho.h \
 248         allwithsuffix(`ciphers', `cipher_modes', `.h') \
 249         allwithsuffix(`hashes', `hash_modes', `.h') \
 250         addsuffix(`cipher_modes', `-def.h') \
 251         addsuffix(`hash_modes', `-def.h')
 252
 253 libcatacomb_la_SOURCES = \
 254         grand.c keysz.c \
 255         des-base.c des-base.h \
 256         cast-s.c cast-sk.c cast-base.h cast-tab.h \
 257         serpent-sbox.h \
 258         skipjack-tab.h \
 259         tiger-base.h \
 260         daftstory.h \
 261         rc4.c seal.c \
 262         rand.c noise.c fipstest.c maurer.c \
 263         arena.c \
 264         passphrase.c pixie-client.c pixie-common.c lmem.c \
 265         lcrand.c fibrand.c \
 266         mpx.c mpx-kmul.c mpx-ksqr.c mpx-kmac.h mpscan.c mparena.c \
 267         mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \
 268         mp-sqrt.c mp-gcd.c mp-jacobi.c mp-modsqrt.c \
 269         mpint.c \
 270         mptext.c mptext-file.c mptext-string.c mptext-dstr.c \
 271         mpbarrett.c mpmont.c mpmont-mexp.c \
 272         mpcrt.c mpmul.c \
 273         mprand.c \
 274         primetab.c pfilt.c rabin.c primorial.c \
 275         pgen.c pgen-stdev.c pgen-safe.c pgen-gcd.c prim.c strongprime.c \
 276         limlee.c \
 277         bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \
 278         rsa-priv.c rsa-pub.c rsa-gen.c rsa-recover.c rsa-fetch.c \
 279         oaep.c pkcs1.c \
 280         dh-gen.c dh-fetch.c \
 281         dsarand.c dsa-sign.c dsa-verify.c dsa-gen.c dsa-fetch.c \
 282         gfshare.c share.c \
 283         rho.c \
 284         key-data.c key-flags.c key-text.c key-binary.c key-pass.c \
 285                 key-pack.c \
 286         key-misc.c key-file.c key-attr.c key-io.c key-moan.c key-error.c \
 287                 key-fetch.c \
 288         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 289         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 290         addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c')
 291
 292 des-base.lo: des-tab.h
 293 blowfish.lo: blowfish-tab.h
 294 twofish.lo: twofish-tab.h
 295 square.lo: square-tab.h
 296 rijndael.lo: rijndael-tab.h
 297 tiger.lo: tiger-tab.h
 298 mpx.lo: mptypes.h
 299
 300 ## --- Utility programs ---
 301
 302 bin_PROGRAMS = dsig key pixie rspit factorial hashsum
 303 bin_SCRIPTS = catacomb-config xpixie
 304 noinst_PROGRAMS = \
 305         genprimes mptypes \
 306         des-mktab blowfish-mktab twofish-mktab square-mktab rijndael-mktab \
 307         tiger-mktab serpent-check \
 308         gfshare-mktab
 309 LDADD = libcatacomb.la
 310
 311 dsig_SOURCES = dsig.c getdate.y getdate.h
 312 key_SOURCES = keyutil.c getdate.y getdate.h
 313 hashsum_SOURCES = hashsum.c
 314 rspit_SOURCES = rspit.c
 315 factorial_SOURCES = factorial.c
 316 pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c
 317 pixie_LDADD =
 318
 319 des_mktab_SOURCES = des-mktab.c
 320 des_mktab_LDADD =
 321 blowfish_mktab_SOURCES = blowfish-mktab.c
 322 blowfish_mktab_LDADD =
 323 twofish_mktab_SOURCES = twofish-mktab.c
 324 twofish_mktab_LDADD =
 325 square_mktab_SOURCES = square-mktab.c
 326 square_mktab_LDADD =
 327 rijndael_mktab_SOURCES = rijndael-mktab.c
 328 rijndael_mktab_LDADD =
 329 serpent_check_SOURCES = serpent-check.c
 330 serpent_check_LDADD =
 331 gfshare_mktab_SOURCES = gfshare-mktab.c
 332 gfshare_mktab_LDADD =
 333 tiger_mktab_SOURCES = tiger-mktab.c
 334 tiger_mktab_LDADD =
 335
 336 genprimes_SOURCES = genprimes.c
 337 genprimes_LDADD =
 338
 339 mptypes_SOURCES = mptypes.c
 340 mptypes_LDADD =
 341
 342 ## --- Install the pixie setuid-root if we can ---
 343
 344 changequote(<, >)
 345 install-exec-hook:
 346         @pixie="$(bindir)/`echo pixie|sed $(transform)`"; \
 347         if chown root $$pixie && chmod 4755 $$pixie; then \
 348           echo "chown root $$pixie"; \
 349           echo "chmod 4755 $$pixie"; \
 350         else \
 351           echo "***"; \
 352           echo "*** You should probably install $$pixie setuid-root."; \
 353           echo "***"; \
 354         fi
 355 changequote(`, ')
 356
 357 ## --- Documentation ---
 358
 359 man_MANS = key.1 keyring.5
 360
 361 ## --- Other handy definitions ---
 362
 363 EXTRA_DIST = \
 364         Makefile.m4 genmodes $(man_MANS) xpixie \
 365         README.cipher README.hash README.random README.mp
 366
 367 dist-hook:
 368         @ln getdate.c $(distdir) || ln $(srcdir)/getdate.c $(distdir) || true
 369         @mkdir $(distdir)/tests || true
 370         @ln $(srcdir)/tests/* $(distdir)/tests || true
 371         @rm -f $(distdir)/tests/*~
 372 #       kr=$$HOME/.catacomb/dsig-keyring; \
 373 #       if [ -r $$kr ]; then \
 374 #         cd $(distdir); \
 375 #         ../key -k $$kr extract -f -secret KEYRING; \
 376 #         find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \
 377 #       fi
 378
 379 ## --- Testing ---
 380
 381 define(`testprogs', `')
 382
 383 define(`CTESTRIG',
 384 `define(`testprogs', testprogs \
 385         $1.t)dnl
 386 $1.to: $1.c
 387         $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to
 388 $1.t: $1.to $1.o libcatacomb.la
 389         $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t')
 390
 391 CTESTRIG(rc4)
 392 CTESTRIG(seal)
 393 adorn(`nl`'CTESTRIG(', `ciphers', `)')
 394 adorn(`nl`'CTESTRIG(', `hashes', `)')
 395 adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)')
 396 adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)')
 397 CTESTRIG(lcrand)
 398 CTESTRIG(oaep)
 399 CTESTRIG(mpx)
 400 CTESTRIG(mpx-kmul)
 401 CTESTRIG(mpx-ksqr)
 402 CTESTRIG(mp-arith)
 403 CTESTRIG(mp-modsqrt)
 404 CTESTRIG(mp-gcd)
 405 CTESTRIG(mp-jacobi)
 406 CTESTRIG(mp-sqrt)
 407 CTESTRIG(mptext)
 408 CTESTRIG(mpint)
 409 CTESTRIG(mpbarrett)
 410 CTESTRIG(mpmont)
 411 CTESTRIG(mpmont-mexp)
 412 CTESTRIG(mpcrt)
 413 CTESTRIG(mpmul)
 414 CTESTRIG(pgen)
 415 CTESTRIG(dsa-gen)
 416 CTESTRIG(dsa-sign)
 417 CTESTRIG(dsa-verify)
 418 CTESTRIG(bbs-rand)
 419 CTESTRIG(bbs-jump)
 420 CTESTRIG(gfshare)
 421 CTESTRIG(share)
 422 CTESTRIG(rho)
 423
 424 TESTS = serpent-check testprogs
 425
 426 CLEANFILES = \
 427         *.t *.to \
 428         mptypes.h primetab.c primetab.h \
 429         des-tab.h twofish-tab.h blowfish-tab.h gfshare-tab.h rijndael-tab.h
 430
 431 ## --- Makefile building (haha!) ---
 432
 433 $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4
 434         m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am
 435
 436 MAINTAINERCLEANFILES = \
 437         $(srcdir)/Makefile.am \
 438         $(srcdir)/getdate.c getdate.c \
 439         $(MODES)
 440
 441 ##----- That's all, folks ---------------------------------------------------