git.distorted.org.uk Git - u/mdw/catacomb/blob - Makefile.m4

   1 ## -*-m4-*-
   2 ##
   3 ## $Id$
   4 ##
   5 ## Makefile for Catacomb
   6 ##
   7 ## (c) 1999 Straylight/Edgeware
   8 ##
   9
  10 ##----- Licensing notice ----------------------------------------------------
  11 ##
  12 ## This file is part of Catacomb.
  13 ##
  14 ## Catacomb is free software; you can redistribute it and/or modify
  15 ## it under the terms of the GNU Library General Public License as
  16 ## published by the Free Software Foundation; either version 2 of the
  17 ## License, or (at your option) any later version.
  18 ##
  19 ## Catacomb is distributed in the hope that it will be useful,
  20 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ## GNU Library General Public License for more details.
  23 ##
  24 ## You should have received a copy of the GNU Library General Public
  25 ## License along with Catacomb; if not, write to the Free
  26 ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  27 ## MA 02111-1307, USA.
  28
  29 AUTOMAKE_OPTIONS = foreign
  30
  31 SUBDIRS = tests
  32
  33 archincludedir = $(libdir)/catacomb/include
  34
  35 ## --- List handling macros ---
  36 ##
  37 ## List handling is nice, usually.  Unfortunately, I based this design on
  38 ## TeX list macros rather than anything sensible...
  39
  40 define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'')
  41 define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')')
  42 define(`join',
  43 `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')')
  44 define(`addsuffix', `adorn(`', `$1', `$2')')
  45 define(`lit', `adorn(`', `$1', `')')
  46 define(`nl', `
  47 ')
  48
  49 define(`allwithsuffix',
  50 `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl
  51 addsuffix(join(`$1', `-', `$2'), `$3')')
  52
  53 ## --- Autogenerated source files ---
  54
  55 define(`ciphers', `dnl
  56 _(des) _(desx) _(des3) _(mars) dnl
  57 _(idea) _(safer) _(safersk) dnl
  58 _(blowfish) _(twofish) dnl
  59 _(tea) _(xtea) dnl
  60 _(rc2) _(rc5) dnl
  61 _(skipjack) dnl
  62 _(cast128) _(cast256) dnl
  63 _(square) _(rijndael) _(rijndael192) _(rijndael256) dnl
  64 _(serpent) _(noekeon)')
  65 define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)')
  66
  67 define(`hashes', `dnl
  68 _(md5) _(md4) _(md2) _(tiger) _(has160) dnl
  69 _(sha) _(sha224) _(sha256) _(sha384) _(sha512) dnl
  70 _(whirlpool) _(whirlpool256) dnl
  71 _(rmd128) _(rmd160) _(rmd256) _(rmd320)')
  72 define(`hash_modes', `_(mgf) _(hmac)')
  73
  74 MODES = \
  75         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \
  76         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \
  77         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \
  78         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h')
  79
  80 $(MODES): modes-stamp
  81 modes-stamp: genmodes
  82         cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')"
  83         cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')"
  84         echo datestamp >modes-stamp
  85
  86 define(`gen_tables', `dnl
  87 _(des) _(blowfish) _(twofish) dnl
  88 _(square) _(rijndael) _(whirlpool) dnl
  89 _(safer) _(mars) _(tiger) dnl
  90 _(gfshare) _(gfx-sqr)')
  91
  92 autoheaders: addsuffix(`gen_tables', `-tab.h') primetab.h mptypes.h
  93 define(`emit', `
  94 _item`'-tab.h: _item`'-mktab$(EXEEXT)
  95         ./_item`'-mktab >_item`'-tab.h.new
  96         mv _item`'-tab.h.new _item`'-tab.h')dnl
  97 gen_tables
  98
  99 primetab.h: primetab.c
 100 primetab.c: genprimes$(EXEEXT)
 101         ./genprimes -h primetab.h -c primetab.c \
 102                 -s CATACOMB_PRIMETAB_H -n 256 \
 103                 -t "unsigned short" -i primetab
 104 archinclude_HEADERS = mptypes.h
 105 mptypes.h: mptypes$(EXEEXT)
 106         ./mptypes >mptypes.h.new
 107         mv mptypes.h.new mptypes.h
 108
 109 ectab.c: ectab.in ec-gentab.awk mpdump$(EXEEXT)
 110         $(srcdir)/ec-gentab.awk <$(srcdir)/ectab.in >ectab.c.new
 111         mv ectab.c.new ectab.c
 112
 113 ptab.c: ptab.in p-gentab.awk mpdump$(EXEEXT)
 114         $(srcdir)/p-gentab.awk <$(srcdir)/ptab.in >ptab.c.new
 115         mv ptab.c.new ptab.c
 116
 117 bintab.c: bintab.in bin-gentab.awk mpdump$(EXEEXT)
 118         $(srcdir)/bin-gentab.awk <$(srcdir)/bintab.in >bintab.c.new
 119         mv bintab.c.new bintab.c
 120
 121 gciphertab.c: gengctab
 122         $(srcdir)/gengctab gccipher gcipher >gciphertab.c.new \
 123                 "lit(join(`ciphers', `-', `cipher_modes')) \
 124                 lit(join(`hashes', `-', `_(mgf)')) \
 125                 rc4 seal"
 126         mv gciphertab.c.new gciphertab.c
 127
 128 gmactab.c: gengctab
 129         $(srcdir)/gengctab gcmac gmac >gmactab.c.new \
 130                 "lit(join(`hashes', `-', `_(hmac)'))"
 131         mv gmactab.c.new gmactab.c
 132
 133 ghashtab.c: gengctab
 134         $(srcdir)/gengctab gchash ghash >ghashtab.c.new \
 135                 "lit(`hashes') \
 136                 crc32=gcrc32"
 137         mv ghashtab.c.new ghashtab.c
 138
 139 BUILT_SOURCES = \
 140         getdate.c modes-stamp gciphertab.c gmactab.c ghashtab.c \
 141         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 142         addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \
 143         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 144         addsuffix(join(`hashes', `-', `hash_modes'), `.h')
 145
 146 ## --- Building the main library ---
 147
 148 lib_LTLIBRARIES = libcatacomb.la
 149
 150 libcatacomb_la_LDFLAGS = -version-info 3:0:1
 151 ## Middle number is the patchlevel.  Final number is the minor version.  The
 152 ## difference between the first and last numbers is major version.
 153
 154 pkginclude_HEADERS = \
 155         arena.h paranoia.h buf.h qdparse.h \
 156         blkc.h hash.h gcipher.h ghash.h gmac.h grand.h ghash-def.h \
 157         lcrand.h fibrand.h rc4.h seal.h rand.h noise.h fipstest.h maurer.h \
 158         key.h key-error.h key-data.h passphrase.h pixie.h lmem.h \
 159         mpx.h bitops.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \
 160         exp.h mpbarrett.h mpmont.h mpreduce.h mp-exp.h \
 161         mpcrt.h mprand.h mpmul.h \
 162         gfx.h gf.h gfreduce.h gfn.h gf-exp.h \
 163         primetab.h pfilt.h rabin.h \
 164         pgen.h prim.h strongprime.h limlee.h keycheck.h \
 165         bbs.h rsa.h dh.h dsarand.h dsa.h gdsa.h gkcdsa.h \
 166         tlsprf.h sslprf.h \
 167         gfshare.h share.h \
 168         rho.h \
 169         field.h field-guts.h field-exp.h \
 170         ec.h ec-guts.h ec-exp.h ec-test.h ectab.h ec-keys.h ec-raw.h \
 171         ptab.h bintab.h group.h group-guts.h \
 172         allwithsuffix(`ciphers', `cipher_modes', `.h') \
 173         allwithsuffix(`hashes', `hash_modes', `.h') \
 174         addsuffix(`cipher_modes', `-def.h') \
 175         addsuffix(`hash_modes', `-def.h') crc32.h
 176
 177 define(`MP_SOURCES',
 178         `mpx.c mpx-kmul.c mpx-ksqr.c mpscan.c mparena.c qdparse.c \
 179         mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \
 180         mp-sqrt.c mp-gcd.c mp-jacobi.c mp-modsqrt.c mp-exp.c \
 181         mpint.c mptext.c mptext-file.c mptext-string.c mptext-dstr.c \
 182         mptext-len.c \
 183         exp.c mpcrt.c mpmul.c mprand.c \
 184         mpbarrett.c mpbarrett-exp.c mpbarrett-mexp.c mpbarrett-exp.h \
 185         mpmont.c mpmont-exp.c mpmont-mexp.c mpmont-exp.h \
 186         mpreduce.c mpreduce-exp.h \
 187         group-stdops.c group-exp.c group-exp.h g-prime.c g-bin.c \
 188           group-parse.c \
 189         group-string.c group-file.c group-dstr.c \
 190         rho.c buf.c ptab.c bintab.c \
 191         GF_SOURCES PGEN_SOURCES EC_SOURCES')
 192
 193 define(`GF_SOURCES',
 194         `gfx.c gfx-kmul.c gfx-sqr.c gf-arith.c gf-exp.c gf-gcd.c \
 195         gfreduce.c gfreduce-exp.h gfn.c')
 196
 197 define(`EC_SOURCES',
 198         `field.c field-parse.c field-exp.c \
 199         f-prime.c f-niceprime.c f-binpoly.c \
 200         ec.c ec-exp.c ec-prime.c ec-bin.c ec-test.c ec-info.c ectab.c \
 201         ec-fetch.c ec-raw.c g-ec.c')
 202
 203 define(`PGEN_SOURCES',
 204         `pfilt.c rabin.c \
 205         pgen.c pgen-stdev.c pgen-gcd.c pgen-simul.c \
 206           prim.c strongprime.c limlee.c \
 207         keycheck.c keycheck-mp.c keycheck-report.c \
 208         bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \
 209         rsa-priv.c rsa-pub.c rsa-gen.c rsa-recover.c rsa-fetch.c \
 210         oaep.c pkcs1.c pss.c \
 211         dh-gen.c dh-limlee.c dh-kcdsa.c dh-check.c dh-fetch.c dh-param.c \
 212         dsarand.c dsa-sign.c dsa-verify.c dsa-gen.c dsa-check.c \
 213         gdsa.c gkcdsa.c \
 214         key-data.c key-flags.c key-text.c key-binary.c key-pass.c \
 215         key-pack.c key-misc.c key-file.c key-attr.c key-io.c key-moan.c \
 216         key-error.c key-fetch.c \
 217         primetab.c share.c')
 218
 219 libcatacomb_la_SOURCES = \
 220         grand.c keysz.c \
 221         lcrand.c fibrand.c rc4.c seal.c rand.c noise.c fipstest.c maurer.c \
 222         arena.c \
 223         passphrase.c pixie-common.c lmem.c \
 224         tlsprf.c sslprf.c \
 225         gfshare.c \
 226         MP_SOURCES karatsuba.h \
 227         gciphertab.c ghashtab.c gmactab.c \
 228         des-base.c des-base.h \
 229         desx-tab.h \
 230         rc2-tab.h \
 231         skipjack-tab.h \
 232         cast-s.c cast-sk.c cast-base.h cast-tab.h \
 233         rijndael-base.c rijndael-base.h \
 234         md2-tab.h \
 235         serpent-sbox.h skipjack-tab.h tiger-base.h \
 236         daftstory.h \
 237         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 238         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 239         addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c') crc32.c
 240
 241 des-base.lo: des-tab.h
 242 blowfish.lo: blowfish-tab.h
 243 twofish.lo: twofish-tab.h
 244 square.lo: square-tab.h
 245 rijndael-base.lo: rijndael-tab.h
 246 whirlpool.lo: whirlpool-tab.h
 247 safer.lo: safer-tab.h
 248 mars.lo: mars-tab.h
 249 tiger.lo: tiger-tab.h
 250 gfshare.lo: gfshare-tab.h
 251 gfx-sqr.lo: gfx-sqr-tab.h
 252
 253 ## --- Utility programs ---
 254
 255 bin_PROGRAMS = \
 256         dsig key pixie cookie rspit factorial hashsum mkphrase \
 257         catcrypt catsign
 258 noinst_LIBRARIES = libcatcrypt.a
 259 bin_SCRIPTS = catacomb-config xpixie
 260 noinst_PROGRAMS = \
 261         genprimes mptypes serpent-check bittest mpdump \
 262         perftest \
 263         addsuffix(`gen_tables', `-mktab')
 264 LDADD = libcatcrypt.a libcatacomb.la
 265
 266 define(`LIBCAT_SRC', `cc.h getdate.h dnl
 267         cc-sig.c cc-subcmd.c cc-enc.c cc-kem.c cc-list.c')
 268 libcatcrypt_a_SOURCES = LIBCAT_SRC getdate.y
 269
 270 patsubst(MP_SOURCES, `\.c\>', `.lo') dsig.o keyutil.o rspit.o \
 271         patsubst(LIBCAT_SRC, `\.c\>', `.o'): \
 272         mptypes.h primetab.h
 273
 274 dsig_SOURCES = dsig.c
 275 cookie_SOURCES = cookie.c
 276 catcrypt_SOURCES = catcrypt.c
 277 catsign_SOURCES = catsign.c
 278 key_SOURCES = keyutil.c
 279 hashsum_SOURCES = hashsum.c
 280 rspit_SOURCES = rspit.c
 281 factorial_SOURCES = factorial.c
 282 perftest_SOURCES = perftest.c
 283 pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c passphrase.c
 284 pixie_LDADD =
 285 pixie_CFLAGS = $(AM_CFLAGS)
 286 mkphrase_SOURCES = mkphrase.c
 287 bittest_SOURCES = bittest.c
 288 bittest_LDADD =
 289
 290 define(`emit', `
 291 patsubst(_item, `[^a-zA-Z0-9]', `_')_mktab_SOURCES = _item`'-mktab.c
 292 patsubst(_item, `[^a-zA-Z0-9]', `_')_mktab_LDADD =')dnl
 293 gen_tables
 294
 295 serpent_check_SOURCES = serpent-check.c
 296 serpent_check_LDADD =
 297
 298 genprimes_SOURCES = genprimes.c
 299 genprimes_LDADD =
 300
 301 mptypes_SOURCES = mptypes.c
 302 mptypes_LDADD =
 303
 304 mpdump_SOURCES = \
 305         mpdump.c \
 306         mpx.c mpx-kmul.c mpx-ksqr.c mpscan.c mparena.c \
 307         mp-misc.c mp-mem.c mp-const.c mp-arith.c mp-io.c \
 308         mptext.c mptext-string.c
 309 mpdump_LDADD =
 310 mpdump_CFLAGS = $(AM_CFLAGS)
 311
 312 ## --- Install the pixie setuid-root if we can ---
 313 ##
 314 ## Bodge around a bug in Automake: it doesn't call `install-exec-hook' from
 315 ## `install' if there are subdirectories.
 316
 317 changequote(<, >)
 318 # install: install-exec-hook
 319 install-exec-hook:
 320         @pixie="$(DESTDIR)$(bindir)/`echo pixie|sed $(transform)`"; \
 321         if chown root $$pixie && chmod 4755 $$pixie; then \
 322           echo "chown root $$pixie"; \
 323           echo "chmod 4755 $$pixie"; \
 324         else \
 325           echo "***"; \
 326           echo "*** You should probably install $$pixie setuid-root."; \
 327           echo "***"; \
 328         fi
 329 changequote(`, ')
 330
 331 ## --- Documentation ---
 332
 333 man_MANS = \
 334         key.1 dsig.1 cookie.1 catcrypt.1 catsign.1 hashsum.1 mkphrase.1 \
 335         keyring.5 pixie.1
 336
 337 ## --- Prime group keyring ---
 338
 339 pkgdata_DATA = pgroups.kr
 340
 341 $(srcdir)/pgroups.kr: ptab.in mkpgroups
 342         cd $(srcdir) && rm -f pgroups.kr && ./mkpgroups <ptab.in
 343
 344 ## --- Other handy definitions ---
 345
 346 EXTRA_DIST = \
 347         Makefile.m4 genmodes gengctab $(man_MANS) xpixie \
 348         group-test.c rsa-test.c \
 349         ectab.in ec-gentab.awk \
 350         ptab.in p-gentab.awk mkpgroups pgroups.kr \
 351         bintab.in bin-gentab.awk \
 352         README.cipher README.hash README.random README.mp \
 353         debian/rules debian/copyright debian/control debian/changelog \
 354         debian/catacomb-bin.postinst debian/catacomb-bin.config \
 355         debian/catacomb-bin.prerm debian/catacomb-bin.templates
 356
 357 dist-hook:
 358         @for i in getdate.c gciphertab.c ghashtab.c gmactab.c; do \
 359           ln $$i $(distdir) || ln $(srcdir)/$$i $(distdir) || true; \
 360         done
 361         @echo datestamp >$(distdir)/modes-stamp || true
 362         @for i in calc tests; do \
 363           mkdir $(distdir)/$$i; \
 364           ln $(srcdir)/$$i/*[!~] $(distdir)/$$i; \
 365         done || true
 366 #       kr=$$HOME/.catacomb/dsig-keyring; \
 367 #       if [ -r $$kr ]; then \
 368 #         cd $(distdir); \
 369 #         ../key -k $$kr extract -f -secret KEYRING; \
 370 #         find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \
 371 #       fi
 372
 373 ## --- Testing ---
 374
 375 define(`testprogs', `')
 376
 377 define(`CTESTRIG',
 378 `define(`testprogs', testprogs \
 379         $1.t$(EXEEXT))dnl
 380 $1.to: $1.c
 381         $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to
 382 $1.t$(EXEEXT): $1.to libcatacomb.la
 383         $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t$(EXEEXT)')
 384
 385 CTESTRIG(rc4)
 386 CTESTRIG(seal)
 387 adorn(`nl`'CTESTRIG(', `ciphers', `)')
 388 adorn(`nl`'CTESTRIG(', `hashes', `)')
 389 adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)')
 390 adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)')
 391 CTESTRIG(lcrand)
 392 CTESTRIG(tlsprf)
 393 CTESTRIG(sslprf)
 394 CTESTRIG(mpx)
 395 CTESTRIG(mpx-kmul)
 396 CTESTRIG(mpx-ksqr)
 397 CTESTRIG(mp-arith)
 398 CTESTRIG(mp-modsqrt)
 399 CTESTRIG(mp-gcd)
 400 CTESTRIG(mp-jacobi)
 401 CTESTRIG(mp-sqrt)
 402 CTESTRIG(mptext)
 403 CTESTRIG(mpint)
 404 CTESTRIG(mpbarrett)
 405 CTESTRIG(mpbarrett-exp)
 406 CTESTRIG(mpbarrett-mexp)
 407 CTESTRIG(mpmont)
 408 CTESTRIG(mpmont-exp)
 409 CTESTRIG(mpmont-mexp)
 410 CTESTRIG(mpreduce)
 411 CTESTRIG(mpcrt)
 412 CTESTRIG(mpmul)
 413 CTESTRIG(rsa-test)
 414 CTESTRIG(gfx)
 415 CTESTRIG(gfx-sqr)
 416 CTESTRIG(gfx-kmul)
 417 CTESTRIG(gf-arith)
 418 CTESTRIG(gf-gcd)
 419 CTESTRIG(gfreduce)
 420 CTESTRIG(gfn)
 421 CTESTRIG(ec-prime)
 422 CTESTRIG(ec-bin)
 423 CTESTRIG(ec-test)
 424 CTESTRIG(ec-info)
 425 CTESTRIG(dh-param)
 426 CTESTRIG(group-test)
 427 CTESTRIG(gdsa)
 428 CTESTRIG(gkcdsa)
 429 CTESTRIG(pgen)
 430 CTESTRIG(dsa-gen)
 431 CTESTRIG(dsa-sign)
 432 CTESTRIG(dsa-verify)
 433 CTESTRIG(bbs-rand)
 434 CTESTRIG(bbs-jump)
 435 CTESTRIG(gfshare)
 436 CTESTRIG(share)
 437 CTESTRIG(rho)
 438
 439 TESTS = serpent-check bittest testprogs
 440
 441 CLEANFILES = \
 442         *.t$(EXEEXT) *.to *.kr.old \
 443         mptypes.h primetab.c primetab.h ectab.c ptab.c bintab.c \
 444         addsuffix(`gen_tables', `-tab.h')
 445
 446 ## --- Makefile building (haha!) ---
 447
 448 $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4
 449         m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am.new
 450         mv $(srcdir)/Makefile.am.new $(srcdir)/Makefile.am
 451
 452 DISTCLEANFILES = libtool
 453
 454 MAINTAINERCLEANFILES = \
 455         $(srcdir)/Makefile.am \
 456         $(srcdir)/getdate.c getdate.c \
 457         $(srcdir)/pgroups.kr \
 458         $(MODES) modes-stamp $(srcdir)/modes-stamp
 459
 460 ##----- That's all, folks ---------------------------------------------------