git.distorted.org.uk Git - u/mdw/catacomb/blob - Makefile.m4

   1 ## -*-makefile-*-
   2 ##
   3 ## $Id: Makefile.m4,v 1.36 2000/07/20 20:13:38 mdw Exp $
   4 ##
   5 ## Makefile for Catacomb
   6 ##
   7 ## (c) 1999 Straylight/Edgeware
   8 ##
   9
  10 ##----- Licensing notice ----------------------------------------------------
  11 ##
  12 ## This file is part of Catacomb.
  13 ##
  14 ## Catacomb is free software; you can redistribute it and/or modify
  15 ## it under the terms of the GNU Library General Public License as
  16 ## published by the Free Software Foundation; either version 2 of the
  17 ## License, or (at your option) any later version.
  18 ##
  19 ## Catacomb is distributed in the hope that it will be useful,
  20 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ## GNU Library General Public License for more details.
  23 ##
  24 ## You should have received a copy of the GNU Library General Public
  25 ## License along with Catacomb; if not, write to the Free
  26 ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  27 ## MA 02111-1307, USA.
  28
  29 ##----- Revision history ----------------------------------------------------
  30 ##
  31 ## $Log: Makefile.m4,v $
  32 ## Revision 1.36  2000/07/20 20:13:38  mdw
  33 ## Added Bellare and Rogaway's PSS encoding for RSA signatures.
  34 ##
  35 ## Revision 1.35  2000/07/16 20:00:46  mdw
  36 ## Bug fixes to distribution.
  37 ##
  38 ## Revision 1.34  2000/07/15 20:55:32  mdw
  39 ## More hashes and ciphers.  An extra tool.
  40 ##
  41 ## Revision 1.33  2000/07/09 21:34:15  mdw
  42 ## New hash functions and other stuff.
  43 ##
  44 ## Revision 1.32  2000/07/01 11:27:32  mdw
  45 ## Name changes and new files.
  46 ##
  47 ## Revision 1.31  2000/06/25 13:02:07  mdw
  48 ## Fix cleaning of generated files.
  49 ##
  50 ## Revision 1.30  2000/06/22 19:10:33  mdw
  51 ## Fix Makefile to test mp-sqrt.c.
  52 ##
  53 ## Revision 1.29  2000/06/22 19:04:19  mdw
  54 ## More new functions to be added.
  55 ##
  56 ## Revision 1.28  2000/06/18 23:31:18  mdw
  57 ## Rearrange build order to ensure that `mptypes.h' exists by the time it's
  58 ## needed.
  59 ##
  60 ## Revision 1.27  2000/06/17 13:28:50  mdw
  61 ## Minor tidying and fixing.
  62 ##
  63 ## Revision 1.26  2000/06/17 10:33:43  mdw
  64 ## Lots of new ciphers and other files.
  65 ##
  66 ## Revision 1.25  2000/02/12 18:55:40  mdw
  67 ## Make it all compile properly.
  68 ##
  69 ## Revision 1.24  2000/02/12 18:22:26  mdw
  70 ## Missed a file.  Whoops.
  71 ##
  72 ## Revision 1.23  2000/02/12 18:21:01  mdw
  73 ## Overhaul of key management (again).
  74 ##
  75 ## Revision 1.22  1999/12/22 16:04:06  mdw
  76 ## Lots of new files.
  77 ##
  78 ## Revision 1.21  1999/12/13 15:47:58  mdw
  79 ## Fix a couple of minor bugs in the distribution set.
  80 ##
  81 ## Revision 1.19  1999/12/11 10:58:24  mdw
  82 ## Fix bug in test rig link flags.  Add Karatsuba squaring.
  83 ##
  84 ## Revision 1.18  1999/12/10 23:30:01  mdw
  85 ## Lots of new files.
  86 ##
  87 ## Revision 1.17  1999/11/25 11:38:31  mdw
  88 ## Support for conversions between MPs and C integers.
  89 ##
  90 ## Revision 1.16  1999/11/22 20:51:33  mdw
  91 ## Add yet more source files.
  92 ##
  93 ## Revision 1.15  1999/11/22 14:08:30  mdw
  94 ## Improve dependencies for test programs.
  95 ##
  96 ## Revision 1.14  1999/11/22 00:17:09  mdw
  97 ## Create object files for test programs so that rebuilding doesn't take so
  98 ## long.
  99 ##
 100 ## Revision 1.12  1999/11/20 22:36:26  mdw
 101 ## Improve dependencies.  Move mpx testing into mpx.c.
 102 ##
 103 ## Revision 1.11  1999/11/20 22:24:53  mdw
 104 ## Add Diffie-Hellman support.
 105 ##
 106 ## Revision 1.10  1999/11/19 19:28:24  mdw
 107 ## Add DSA files and tests.
 108 ##
 109 ## Revision 1.9  1999/11/17 18:05:35  mdw
 110 ## Many new files and test cases for multiprecision arithmetic.
 111 ##
 112 ## Revision 1.8  1999/11/13 01:56:07  mdw
 113 ## Include multiprecision maths stuff.
 114 ##
 115 ## Revision 1.7  1999/11/11 19:01:02  mdw
 116 ## Use `libtool' to generate a shared library.
 117 ##
 118 ## Revision 1.6  1999/11/11 17:47:34  mdw
 119 ## Updates for new configuration system, and `mptypes' generator.
 120 ##
 121 ## Revision 1.5  1999/11/11 00:59:17  mdw
 122 ## Minor reformatting.
 123 ##
 124 ## Revision 1.4  1999/10/24 10:20:36  mdw
 125 ## Modify for standalone distribution.  The library's getting far too large
 126 ## to be sensibly embedded in other programs.
 127 ##
 128 ## Revision 1.3  1999/10/24 10:04:26  mdw
 129 ## Install headers in the right directory.
 130 ##
 131 ## Revision 1.2  1999/10/23 12:55:35  mdw
 132 ## The `CVS' directory can't be hardlinked.  Don't worry about this
 133 ## overmuch.
 134 ##
 135 ## Revision 1.1  1999/09/03 08:41:11  mdw
 136 ## Initial import.
 137 ##
 138
 139 AUTOMAKE_OPTIONS = foreign
 140
 141 SUBDIRS = tests
 142
 143 archincludedir = $(libdir)/catacomb/include
 144
 145 ## --- List handling macros ---
 146 ##
 147 ## List handling is nice, usually.  Unfortunately, I based this design on
 148 ## TeX list macros rather than anything sensible...
 149
 150 define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'')
 151 define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')')
 152 define(`join',
 153 `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')')
 154 define(`addsuffix', `adorn(`', `$1', `$2')')
 155 define(`lit', `adorn(`', `$1', `')')
 156 define(`nl', `
 157 ')
 158
 159 define(`allwithsuffix',
 160 `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl
 161 addsuffix(join(`$1', `-', `$2'), `$3')')
 162
 163 ## --- Autogenerated source files ---
 164
 165 define(`ciphers', `dnl
 166 _(des) _(des3) dnl
 167 _(idea) dnl
 168 _(blowfish) _(twofish) dnl
 169 _(tea) _(xtea) dnl
 170 _(rc2) _(rc5) dnl
 171 _(skipjack) dnl
 172 _(cast128) _(cast256) dnl
 173 _(square) _(rijndael) dnl
 174 _(serpent)')
 175 define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)')
 176
 177 define(`hashes', `dnl
 178 _(md5) _(md4) _(sha) _(tiger) dnl
 179 _(rmd128) _(rmd160) _(rmd256) _(rmd320)')
 180 define(`hash_modes', `_(mgf) _(hmac)')
 181
 182 MODES = \
 183         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \
 184         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \
 185         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \
 186         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h')
 187
 188 $(MODES):
 189         cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')"
 190         cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')"
 191
 192 des-tab.h: des-mktab
 193         ./des-mktab >des-tab.h
 194 blowfish-tab.h: blowfish-mktab
 195         ./blowfish-mktab >blowfish-tab.h
 196 twofish-tab.h: twofish-mktab
 197         ./twofish-mktab >twofish-tab.h
 198 square-tab.h: square-mktab
 199         ./square-mktab >square-tab.h
 200 rijndael-tab.h: rijndael-mktab
 201         ./rijndael-mktab >rijndael-tab.h
 202 tiger-tab.h: tiger-mktab
 203         ./tiger-mktab >tiger-tab.h
 204 gfshare-tab.h: gfshare-mktab
 205         ./gfshare-mktab >gfshare-tab.h
 206
 207 primetab.c primetab.h: genprimes
 208         ./genprimes -h primetab.h -c primetab.c -m 255 \
 209                 -t "unsigned char" -i primetab
 210
 211 archinclude_HEADERS = mptypes.h
 212
 213 mptypes.h: mptypes
 214         ./mptypes >mptypes.h
 215
 216 BUILT_SOURCES = \
 217         getdate.c \
 218         des-tab.h blowfish-tab.h twofish-tab.h rijndael-tab.h \
 219         gfshare-tab.h \
 220         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 221         addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \
 222         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 223         addsuffix(join(`hashes', `-', `hash_modes'), `.h')
 224
 225 ## --- Building the main library ---
 226
 227 lib_LTLIBRARIES = libcatacomb.la
 228
 229 libcatacomb_la_LDFLAGS = -version-info 2:0:0
 230 ## Middle number is the patchlevel.  Final number is the minor version.  The
 231 ## difference between the first and last numbers is major version.
 232
 233 pkginclude_HEADERS = \
 234         arena.h paranoia.h \
 235         blkc.h hash.h \
 236         gcipher.h ghash.h gmac.h grand.h \
 237         ghash-def.h \
 238         rc4.h seal.h \
 239         rand.h noise.h fipstest.h maurer.h \
 240         key.h key-data.h passphrase.h pixie.h lmem.h \
 241         lcrand.h fibrand.h \
 242         mpx.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \
 243         mpbarrett.h mpmont.h mpcrt.h \
 244         mprand.h mpmul.h \
 245         primetab.h pfilt.h primorial.h rabin.h \
 246         pgen.h prim.h strongprime.h limlee.h \
 247         bbs.h rsa.h dh.h dsarand.h dsa.h \
 248         oaep.h pkcs1.h pss.h \
 249         gfshare.h share.h \
 250         rho.h \
 251         allwithsuffix(`ciphers', `cipher_modes', `.h') \
 252         allwithsuffix(`hashes', `hash_modes', `.h') \
 253         addsuffix(`cipher_modes', `-def.h') \
 254         addsuffix(`hash_modes', `-def.h')
 255
 256 libcatacomb_la_SOURCES = \
 257         grand.c keysz.c \
 258         des-base.c des-base.h \
 259         cast-s.c cast-sk.c cast-base.h cast-tab.h \
 260         serpent-sbox.h \
 261         skipjack-tab.h \
 262         tiger-base.h \
 263         daftstory.h \
 264         rc4.c seal.c \
 265         rand.c noise.c fipstest.c maurer.c \
 266         arena.c \
 267         passphrase.c pixie-client.c pixie-common.c lmem.c \
 268         lcrand.c fibrand.c \
 269         mpx.c mpx-kmul.c mpx-ksqr.c mpx-kmac.h mpscan.c mparena.c \
 270         mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \
 271         mp-sqrt.c mp-gcd.c mp-jacobi.c mp-modsqrt.c \
 272         mpint.c \
 273         mptext.c mptext-file.c mptext-string.c mptext-dstr.c \
 274         mpbarrett.c mpmont.c mpmont-mexp.c \
 275         mpcrt.c mpmul.c \
 276         mprand.c \
 277         primetab.c pfilt.c rabin.c primorial.c \
 278         pgen.c pgen-stdev.c pgen-safe.c pgen-gcd.c prim.c strongprime.c \
 279         limlee.c \
 280         bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \
 281         rsa-priv.c rsa-pub.c rsa-gen.c rsa-recover.c rsa-fetch.c \
 282         oaep.c pkcs1.c pss.c \
 283         dh-gen.c dh-fetch.c \
 284         dsarand.c dsa-sign.c dsa-verify.c dsa-gen.c dsa-fetch.c \
 285         gfshare.c share.c \
 286         rho.c \
 287         key-data.c key-flags.c key-text.c key-binary.c key-pass.c \
 288                 key-pack.c \
 289         key-misc.c key-file.c key-attr.c key-io.c key-moan.c key-error.c \
 290                 key-fetch.c \
 291         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 292         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 293         addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c')
 294
 295 des-base.lo: des-tab.h
 296 blowfish.lo: blowfish-tab.h
 297 twofish.lo: twofish-tab.h
 298 square.lo: square-tab.h
 299 rijndael.lo: rijndael-tab.h
 300 tiger.lo: tiger-tab.h
 301 mpx.lo: mptypes.h
 302
 303 ## --- Utility programs ---
 304
 305 bin_PROGRAMS = dsig key pixie rspit factorial hashsum
 306 bin_SCRIPTS = catacomb-config xpixie
 307 noinst_PROGRAMS = \
 308         genprimes mptypes \
 309         des-mktab blowfish-mktab twofish-mktab square-mktab rijndael-mktab \
 310         tiger-mktab serpent-check \
 311         gfshare-mktab
 312 LDADD = libcatacomb.la
 313
 314 dsig_SOURCES = dsig.c getdate.y getdate.h
 315 key_SOURCES = keyutil.c getdate.y getdate.h
 316 hashsum_SOURCES = hashsum.c
 317 rspit_SOURCES = rspit.c
 318 factorial_SOURCES = factorial.c
 319 pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c
 320 pixie_LDADD =
 321
 322 des_mktab_SOURCES = des-mktab.c
 323 des_mktab_LDADD =
 324 blowfish_mktab_SOURCES = blowfish-mktab.c
 325 blowfish_mktab_LDADD =
 326 twofish_mktab_SOURCES = twofish-mktab.c
 327 twofish_mktab_LDADD =
 328 square_mktab_SOURCES = square-mktab.c
 329 square_mktab_LDADD =
 330 rijndael_mktab_SOURCES = rijndael-mktab.c
 331 rijndael_mktab_LDADD =
 332 serpent_check_SOURCES = serpent-check.c
 333 serpent_check_LDADD =
 334 gfshare_mktab_SOURCES = gfshare-mktab.c
 335 gfshare_mktab_LDADD =
 336 tiger_mktab_SOURCES = tiger-mktab.c
 337 tiger_mktab_LDADD =
 338
 339 genprimes_SOURCES = genprimes.c
 340 genprimes_LDADD =
 341
 342 mptypes_SOURCES = mptypes.c
 343 mptypes_LDADD =
 344
 345 ## --- Install the pixie setuid-root if we can ---
 346
 347 changequote(<, >)
 348 install-exec-hook:
 349         @pixie="$(bindir)/`echo pixie|sed $(transform)`"; \
 350         if chown root $$pixie && chmod 4755 $$pixie; then \
 351           echo "chown root $$pixie"; \
 352           echo "chmod 4755 $$pixie"; \
 353         else \
 354           echo "***"; \
 355           echo "*** You should probably install $$pixie setuid-root."; \
 356           echo "***"; \
 357         fi
 358 changequote(`, ')
 359
 360 ## --- Documentation ---
 361
 362 man_MANS = key.1 keyring.5
 363
 364 ## --- Other handy definitions ---
 365
 366 EXTRA_DIST = \
 367         Makefile.m4 genmodes $(man_MANS) xpixie \
 368         README.cipher README.hash README.random README.mp
 369
 370 dist-hook:
 371         @ln getdate.c $(distdir) || ln $(srcdir)/getdate.c $(distdir) || true
 372         @mkdir $(distdir)/tests || true
 373         @ln $(srcdir)/tests/* $(distdir)/tests || true
 374         @rm -f $(distdir)/tests/*~
 375 #       kr=$$HOME/.catacomb/dsig-keyring; \
 376 #       if [ -r $$kr ]; then \
 377 #         cd $(distdir); \
 378 #         ../key -k $$kr extract -f -secret KEYRING; \
 379 #         find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \
 380 #       fi
 381
 382 ## --- Testing ---
 383
 384 define(`testprogs', `')
 385
 386 define(`CTESTRIG',
 387 `define(`testprogs', testprogs \
 388         $1.t)dnl
 389 $1.to: $1.c
 390         $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to
 391 $1.t: $1.to $1.o libcatacomb.la
 392         $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t')
 393
 394 CTESTRIG(rc4)
 395 CTESTRIG(seal)
 396 adorn(`nl`'CTESTRIG(', `ciphers', `)')
 397 adorn(`nl`'CTESTRIG(', `hashes', `)')
 398 adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)')
 399 adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)')
 400 CTESTRIG(lcrand)
 401 CTESTRIG(oaep)
 402 CTESTRIG(mpx)
 403 CTESTRIG(mpx-kmul)
 404 CTESTRIG(mpx-ksqr)
 405 CTESTRIG(mp-arith)
 406 CTESTRIG(mp-modsqrt)
 407 CTESTRIG(mp-gcd)
 408 CTESTRIG(mp-jacobi)
 409 CTESTRIG(mp-sqrt)
 410 CTESTRIG(mptext)
 411 CTESTRIG(mpint)
 412 CTESTRIG(mpbarrett)
 413 CTESTRIG(mpmont)
 414 CTESTRIG(mpmont-mexp)
 415 CTESTRIG(mpcrt)
 416 CTESTRIG(mpmul)
 417 CTESTRIG(pgen)
 418 CTESTRIG(dsa-gen)
 419 CTESTRIG(dsa-sign)
 420 CTESTRIG(dsa-verify)
 421 CTESTRIG(bbs-rand)
 422 CTESTRIG(bbs-jump)
 423 CTESTRIG(gfshare)
 424 CTESTRIG(share)
 425 CTESTRIG(rho)
 426
 427 TESTS = serpent-check testprogs
 428
 429 CLEANFILES = \
 430         *.t *.to \
 431         mptypes.h primetab.c primetab.h \
 432         des-tab.h twofish-tab.h blowfish-tab.h gfshare-tab.h rijndael-tab.h
 433
 434 ## --- Makefile building (haha!) ---
 435
 436 $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4
 437         m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am
 438
 439 MAINTAINERCLEANFILES = \
 440         $(srcdir)/Makefile.am \
 441         $(srcdir)/getdate.c getdate.c \
 442         $(MODES)
 443
 444 ##----- That's all, folks ---------------------------------------------------