git.distorted.org.uk Git - u/mdw/catacomb/blob - Makefile.m4

   1 ## -*-makefile-*-
   2 ##
   3 ## $Id: Makefile.m4,v 1.38 2000/07/29 10:54:55 mdw Exp $
   4 ##
   5 ## Makefile for Catacomb
   6 ##
   7 ## (c) 1999 Straylight/Edgeware
   8 ##
   9
  10 ##----- Licensing notice ----------------------------------------------------
  11 ##
  12 ## This file is part of Catacomb.
  13 ##
  14 ## Catacomb is free software; you can redistribute it and/or modify
  15 ## it under the terms of the GNU Library General Public License as
  16 ## published by the Free Software Foundation; either version 2 of the
  17 ## License, or (at your option) any later version.
  18 ##
  19 ## Catacomb is distributed in the hope that it will be useful,
  20 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ## GNU Library General Public License for more details.
  23 ##
  24 ## You should have received a copy of the GNU Library General Public
  25 ## License along with Catacomb; if not, write to the Free
  26 ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  27 ## MA 02111-1307, USA.
  28
  29 ##----- Revision history ----------------------------------------------------
  30 ##
  31 ## $Log: Makefile.m4,v $
  32 ## Revision 1.38  2000/07/29 10:54:55  mdw
  33 ## Further fixing to support building using normal `make' again. ;-)  I
  34 ## think we're there now.
  35 ##
  36 ## Revision 1.37  2000/07/29 10:02:36  mdw
  37 ## Lots of fixing to support `make -j' building.
  38 ##
  39 ## Revision 1.36  2000/07/20 20:13:38  mdw
  40 ## Added Bellare and Rogaway's PSS encoding for RSA signatures.
  41 ##
  42 ## Revision 1.35  2000/07/16 20:00:46  mdw
  43 ## Bug fixes to distribution.
  44 ##
  45 ## Revision 1.34  2000/07/15 20:55:32  mdw
  46 ## More hashes and ciphers.  An extra tool.
  47 ##
  48 ## Revision 1.33  2000/07/09 21:34:15  mdw
  49 ## New hash functions and other stuff.
  50 ##
  51 ## Revision 1.32  2000/07/01 11:27:32  mdw
  52 ## Name changes and new files.
  53 ##
  54 ## Revision 1.31  2000/06/25 13:02:07  mdw
  55 ## Fix cleaning of generated files.
  56 ##
  57 ## Revision 1.30  2000/06/22 19:10:33  mdw
  58 ## Fix Makefile to test mp-sqrt.c.
  59 ##
  60 ## Revision 1.29  2000/06/22 19:04:19  mdw
  61 ## More new functions to be added.
  62 ##
  63 ## Revision 1.28  2000/06/18 23:31:18  mdw
  64 ## Rearrange build order to ensure that `mptypes.h' exists by the time it's
  65 ## needed.
  66 ##
  67 ## Revision 1.27  2000/06/17 13:28:50  mdw
  68 ## Minor tidying and fixing.
  69 ##
  70 ## Revision 1.26  2000/06/17 10:33:43  mdw
  71 ## Lots of new ciphers and other files.
  72 ##
  73 ## Revision 1.25  2000/02/12 18:55:40  mdw
  74 ## Make it all compile properly.
  75 ##
  76 ## Revision 1.24  2000/02/12 18:22:26  mdw
  77 ## Missed a file.  Whoops.
  78 ##
  79 ## Revision 1.23  2000/02/12 18:21:01  mdw
  80 ## Overhaul of key management (again).
  81 ##
  82 ## Revision 1.22  1999/12/22 16:04:06  mdw
  83 ## Lots of new files.
  84 ##
  85 ## Revision 1.21  1999/12/13 15:47:58  mdw
  86 ## Fix a couple of minor bugs in the distribution set.
  87 ##
  88 ## Revision 1.19  1999/12/11 10:58:24  mdw
  89 ## Fix bug in test rig link flags.  Add Karatsuba squaring.
  90 ##
  91 ## Revision 1.18  1999/12/10 23:30:01  mdw
  92 ## Lots of new files.
  93 ##
  94 ## Revision 1.17  1999/11/25 11:38:31  mdw
  95 ## Support for conversions between MPs and C integers.
  96 ##
  97 ## Revision 1.16  1999/11/22 20:51:33  mdw
  98 ## Add yet more source files.
  99 ##
 100 ## Revision 1.15  1999/11/22 14:08:30  mdw
 101 ## Improve dependencies for test programs.
 102 ##
 103 ## Revision 1.14  1999/11/22 00:17:09  mdw
 104 ## Create object files for test programs so that rebuilding doesn't take so
 105 ## long.
 106 ##
 107 ## Revision 1.12  1999/11/20 22:36:26  mdw
 108 ## Improve dependencies.  Move mpx testing into mpx.c.
 109 ##
 110 ## Revision 1.11  1999/11/20 22:24:53  mdw
 111 ## Add Diffie-Hellman support.
 112 ##
 113 ## Revision 1.10  1999/11/19 19:28:24  mdw
 114 ## Add DSA files and tests.
 115 ##
 116 ## Revision 1.9  1999/11/17 18:05:35  mdw
 117 ## Many new files and test cases for multiprecision arithmetic.
 118 ##
 119 ## Revision 1.8  1999/11/13 01:56:07  mdw
 120 ## Include multiprecision maths stuff.
 121 ##
 122 ## Revision 1.7  1999/11/11 19:01:02  mdw
 123 ## Use `libtool' to generate a shared library.
 124 ##
 125 ## Revision 1.6  1999/11/11 17:47:34  mdw
 126 ## Updates for new configuration system, and `mptypes' generator.
 127 ##
 128 ## Revision 1.5  1999/11/11 00:59:17  mdw
 129 ## Minor reformatting.
 130 ##
 131 ## Revision 1.4  1999/10/24 10:20:36  mdw
 132 ## Modify for standalone distribution.  The library's getting far too large
 133 ## to be sensibly embedded in other programs.
 134 ##
 135 ## Revision 1.3  1999/10/24 10:04:26  mdw
 136 ## Install headers in the right directory.
 137 ##
 138 ## Revision 1.2  1999/10/23 12:55:35  mdw
 139 ## The `CVS' directory can't be hardlinked.  Don't worry about this
 140 ## overmuch.
 141 ##
 142 ## Revision 1.1  1999/09/03 08:41:11  mdw
 143 ## Initial import.
 144 ##
 145
 146 AUTOMAKE_OPTIONS = foreign
 147
 148 SUBDIRS = tests
 149
 150 archincludedir = $(libdir)/catacomb/include
 151
 152 ## --- List handling macros ---
 153 ##
 154 ## List handling is nice, usually.  Unfortunately, I based this design on
 155 ## TeX list macros rather than anything sensible...
 156
 157 define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'')
 158 define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')')
 159 define(`join',
 160 `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')')
 161 define(`addsuffix', `adorn(`', `$1', `$2')')
 162 define(`lit', `adorn(`', `$1', `')')
 163 define(`nl', `
 164 ')
 165
 166 define(`allwithsuffix',
 167 `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl
 168 addsuffix(join(`$1', `-', `$2'), `$3')')
 169
 170 ## --- Autogenerated source files ---
 171
 172 define(`ciphers', `dnl
 173 _(des) _(des3) dnl
 174 _(idea) dnl
 175 _(blowfish) _(twofish) dnl
 176 _(tea) _(xtea) dnl
 177 _(rc2) _(rc5) dnl
 178 _(skipjack) dnl
 179 _(cast128) _(cast256) dnl
 180 _(square) _(rijndael) dnl
 181 _(serpent)')
 182 define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)')
 183
 184 define(`hashes', `dnl
 185 _(md5) _(md4) _(sha) _(tiger) dnl
 186 _(rmd128) _(rmd160) _(rmd256) _(rmd320)')
 187 define(`hash_modes', `_(mgf) _(hmac)')
 188
 189 MODES = \
 190         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \
 191         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \
 192         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \
 193         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h')
 194
 195 $(MODES): modes-stamp
 196 modes-stamp: genmodes
 197         cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')"
 198         cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')"
 199         echo datestamp >modes-stamp
 200
 201 define(`gen_tables', `dnl
 202 _(des) _(blowfish) _(twofish) _(square) _(rijndael) _(tiger) dnl
 203 _(gfshare)')
 204
 205 autoheaders: addsuffix(`gen_tables', `-tab.h') primetab.h mptypes.h
 206 define(`emit', `
 207 _item`'-tab.h: _item`'-mktab
 208         ./_item`'-mktab >_item`'-tab.h')dnl
 209 gen_tables
 210
 211 primetab.h: primetab.c
 212 primetab.c: genprimes
 213         ./genprimes -h primetab.h -c primetab.c -m 255 \
 214                 -t "unsigned char" -i primetab
 215 archinclude_HEADERS = mptypes.h
 216 mptypes.h: mptypes
 217         ./mptypes >mptypes.h
 218
 219 BUILT_SOURCES = \
 220         getdate.c \
 221         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 222         addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \
 223         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 224         addsuffix(join(`hashes', `-', `hash_modes'), `.h')
 225
 226 ## --- Building the main library ---
 227
 228 lib_LTLIBRARIES = libcatacomb.la
 229
 230 libcatacomb_la_LDFLAGS = -version-info 2:0:0
 231 ## Middle number is the patchlevel.  Final number is the minor version.  The
 232 ## difference between the first and last numbers is major version.
 233
 234 pkginclude_HEADERS = \
 235         arena.h paranoia.h \
 236         blkc.h hash.h gcipher.h ghash.h gmac.h grand.h ghash-def.h \
 237         lcrand.h fibrand.h rc4.h seal.h rand.h noise.h fipstest.h maurer.h \
 238         key.h key-data.h passphrase.h pixie.h lmem.h \
 239         mpx.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \
 240         mpbarrett.h mpmont.h mpcrt.h mprand.h mpmul.h \
 241         primetab.h pfilt.h primorial.h rabin.h \
 242         pgen.h prim.h strongprime.h limlee.h \
 243         bbs.h rsa.h dh.h dsarand.h dsa.h \
 244         oaep.h pkcs1.h pss.h \
 245         gfshare.h share.h \
 246         rho.h \
 247         allwithsuffix(`ciphers', `cipher_modes', `.h') \
 248         allwithsuffix(`hashes', `hash_modes', `.h') \
 249         addsuffix(`cipher_modes', `-def.h') \
 250         addsuffix(`hash_modes', `-def.h')
 251
 252 libcatacomb_la_SOURCES = \
 253         grand.c keysz.c \
 254         des-base.c des-base.h \
 255         cast-s.c cast-sk.c cast-base.h cast-tab.h \
 256         serpent-sbox.h skipjack-tab.h tiger-base.h \
 257         daftstory.h \
 258         lcrand.c fibrand.c rc4.c seal.c rand.c noise.c fipstest.c maurer.c \
 259         arena.c \
 260         passphrase.c pixie-client.c pixie-common.c lmem.c \
 261         mpx.c mpx-kmul.c mpx-ksqr.c mpx-kmac.h mpscan.c mparena.c \
 262         mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \
 263         mp-sqrt.c mp-gcd.c mp-jacobi.c mp-modsqrt.c \
 264         mpint.c mptext.c mptext-file.c mptext-string.c mptext-dstr.c \
 265         mpbarrett.c mpmont.c mpmont-mexp.c mpcrt.c mpmul.c mprand.c \
 266         pfilt.c rabin.c primorial.c \
 267         pgen.c pgen-stdev.c pgen-safe.c pgen-gcd.c prim.c strongprime.c \
 268         limlee.c \
 269         bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \
 270         rsa-priv.c rsa-pub.c rsa-gen.c rsa-recover.c rsa-fetch.c \
 271         oaep.c pkcs1.c pss.c \
 272         dh-gen.c dh-limlee.c dh-fetch.c \
 273         dsarand.c dsa-sign.c dsa-verify.c dsa-gen.c \
 274         gfshare.c share.c \
 275         rho.c \
 276         key-data.c key-flags.c key-text.c key-binary.c key-pass.c \
 277         key-pack.c key-misc.c key-file.c key-attr.c key-io.c key-moan.c \
 278         key-error.c key-fetch.c \
 279         primetab.c \
 280         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 281         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 282         addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c')
 283
 284 des-base.lo: des-tab.h
 285 blowfish.lo: blowfish-tab.h
 286 twofish.lo: twofish-tab.h
 287 square.lo: square-tab.h
 288 rijndael.lo: rijndael-tab.h
 289 tiger.lo: tiger-tab.h
 290 gfshare.lo: gfshare-tab.h
 291 $(libcatacomb_la_OBJECTS) dsig.o keyutil.o rspit.o: mptypes.h primetab.h
 292
 293 ## --- Utility programs ---
 294
 295 bin_PROGRAMS = dsig key pixie rspit factorial hashsum
 296 bin_SCRIPTS = catacomb-config xpixie
 297 noinst_PROGRAMS = \
 298         genprimes mptypes \
 299         des-mktab blowfish-mktab twofish-mktab square-mktab rijndael-mktab \
 300         tiger-mktab serpent-check \
 301         gfshare-mktab
 302 LDADD = libcatacomb.la
 303
 304 dsig_SOURCES = dsig.c getdate.y getdate.h
 305 key_SOURCES = keyutil.c getdate.y getdate.h
 306 hashsum_SOURCES = hashsum.c
 307 rspit_SOURCES = rspit.c
 308 factorial_SOURCES = factorial.c
 309 pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c
 310 pixie_LDADD =
 311
 312 des_mktab_SOURCES = des-mktab.c
 313 des_mktab_LDADD =
 314 blowfish_mktab_SOURCES = blowfish-mktab.c
 315 blowfish_mktab_LDADD =
 316 twofish_mktab_SOURCES = twofish-mktab.c
 317 twofish_mktab_LDADD =
 318 square_mktab_SOURCES = square-mktab.c
 319 square_mktab_LDADD =
 320 rijndael_mktab_SOURCES = rijndael-mktab.c
 321 rijndael_mktab_LDADD =
 322 serpent_check_SOURCES = serpent-check.c
 323 serpent_check_LDADD =
 324 gfshare_mktab_SOURCES = gfshare-mktab.c
 325 gfshare_mktab_LDADD =
 326 tiger_mktab_SOURCES = tiger-mktab.c
 327 tiger_mktab_LDADD =
 328
 329 genprimes_SOURCES = genprimes.c
 330 genprimes_LDADD =
 331
 332 mptypes_SOURCES = mptypes.c
 333 mptypes_LDADD =
 334
 335 ## --- Install the pixie setuid-root if we can ---
 336
 337 changequote(<, >)
 338 install-exec-hook:
 339         @pixie="$(bindir)/`echo pixie|sed $(transform)`"; \
 340         if chown root $$pixie && chmod 4755 $$pixie; then \
 341           echo "chown root $$pixie"; \
 342           echo "chmod 4755 $$pixie"; \
 343         else \
 344           echo "***"; \
 345           echo "*** You should probably install $$pixie setuid-root."; \
 346           echo "***"; \
 347         fi
 348 changequote(`, ')
 349
 350 ## --- Documentation ---
 351
 352 man_MANS = key.1 keyring.5
 353
 354 ## --- Other handy definitions ---
 355
 356 EXTRA_DIST = \
 357         Makefile.m4 genmodes $(man_MANS) xpixie \
 358         README.cipher README.hash README.random README.mp
 359
 360 dist-hook:
 361         @ln getdate.c $(distdir) || ln $(srcdir)/getdate.c $(distdir) || true
 362         @echo datestamp >$(distdir)/modes-stamp || true
 363         @mkdir $(distdir)/tests || true
 364         @ln $(srcdir)/tests/* $(distdir)/tests || true
 365         @rm -f $(distdir)/tests/*~
 366 #       kr=$$HOME/.catacomb/dsig-keyring; \
 367 #       if [ -r $$kr ]; then \
 368 #         cd $(distdir); \
 369 #         ../key -k $$kr extract -f -secret KEYRING; \
 370 #         find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \
 371 #       fi
 372
 373 ## --- Testing ---
 374
 375 define(`testprogs', `')
 376
 377 define(`CTESTRIG',
 378 `define(`testprogs', testprogs \
 379         $1.t)dnl
 380 $1.to: $1.c
 381         $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to
 382 $1.t: $1.to $1.o libcatacomb.la
 383         $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t')
 384
 385 CTESTRIG(rc4)
 386 CTESTRIG(seal)
 387 adorn(`nl`'CTESTRIG(', `ciphers', `)')
 388 adorn(`nl`'CTESTRIG(', `hashes', `)')
 389 adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)')
 390 adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)')
 391 CTESTRIG(lcrand)
 392 CTESTRIG(oaep)
 393 CTESTRIG(mpx)
 394 CTESTRIG(mpx-kmul)
 395 CTESTRIG(mpx-ksqr)
 396 CTESTRIG(mp-arith)
 397 CTESTRIG(mp-modsqrt)
 398 CTESTRIG(mp-gcd)
 399 CTESTRIG(mp-jacobi)
 400 CTESTRIG(mp-sqrt)
 401 CTESTRIG(mptext)
 402 CTESTRIG(mpint)
 403 CTESTRIG(mpbarrett)
 404 CTESTRIG(mpmont)
 405 CTESTRIG(mpmont-mexp)
 406 CTESTRIG(mpcrt)
 407 CTESTRIG(mpmul)
 408 CTESTRIG(pgen)
 409 CTESTRIG(dsa-gen)
 410 CTESTRIG(dsa-sign)
 411 CTESTRIG(dsa-verify)
 412 CTESTRIG(bbs-rand)
 413 CTESTRIG(bbs-jump)
 414 CTESTRIG(gfshare)
 415 CTESTRIG(share)
 416 CTESTRIG(rho)
 417
 418 TESTS = serpent-check testprogs
 419
 420 CLEANFILES = \
 421         *.t *.to \
 422         mptypes.h primetab.c primetab.h \
 423         addsuffix(`gen_tables', `-tab.h')
 424
 425 ## --- Makefile building (haha!) ---
 426
 427 $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4
 428         m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am
 429
 430 MAINTAINERCLEANFILES = \
 431         $(srcdir)/Makefile.am \
 432         $(srcdir)/getdate.c getdate.c \
 433         $(MODES) modes-stamp $(srcdir)/modes-stamp
 434
 435 ##----- That's all, folks ---------------------------------------------------