git.distorted.org.uk Git - u/mdw/catacomb/blob - Makefile.m4

   1 ## -*-m4-*-
   2 ##
   3 ## $Id$
   4 ##
   5 ## Makefile for Catacomb
   6 ##
   7 ## (c) 1999 Straylight/Edgeware
   8 ##
   9
  10 ##----- Licensing notice ----------------------------------------------------
  11 ##
  12 ## This file is part of Catacomb.
  13 ##
  14 ## Catacomb is free software; you can redistribute it and/or modify
  15 ## it under the terms of the GNU Library General Public License as
  16 ## published by the Free Software Foundation; either version 2 of the
  17 ## License, or (at your option) any later version.
  18 ##
  19 ## Catacomb is distributed in the hope that it will be useful,
  20 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ## GNU Library General Public License for more details.
  23 ##
  24 ## You should have received a copy of the GNU Library General Public
  25 ## License along with Catacomb; if not, write to the Free
  26 ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  27 ## MA 02111-1307, USA.
  28
  29 AUTOMAKE_OPTIONS = foreign
  30
  31 SUBDIRS = tests
  32
  33 archincludedir = $(libdir)/catacomb/include
  34
  35 ## --- List handling macros ---
  36 ##
  37 ## List handling is nice, usually.  Unfortunately, I based this design on
  38 ## TeX list macros rather than anything sensible...
  39
  40 define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'')
  41 define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')')
  42 define(`join',
  43 `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')')
  44 define(`addsuffix', `adorn(`', `$1', `$2')')
  45 define(`lit', `adorn(`', `$1', `')')
  46 define(`nl', `
  47 ')
  48
  49 define(`allwithsuffix',
  50 `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl
  51 addsuffix(join(`$1', `-', `$2'), `$3')')
  52
  53 ## --- Autogenerated source files ---
  54
  55 define(`ciphers', `dnl
  56 _(des) _(desx) _(des3) _(mars) dnl
  57 _(idea) _(safer) _(safersk) dnl
  58 _(blowfish) _(twofish) dnl
  59 _(tea) _(xtea) dnl
  60 _(rc2) _(rc5) dnl
  61 _(skipjack) dnl
  62 _(cast128) _(cast256) dnl
  63 _(square) _(rijndael) _(rijndael192) _(rijndael256) dnl
  64 _(serpent) _(noekeon)')
  65 define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)')
  66
  67 define(`hashes', `dnl
  68 _(md5) _(md4) _(md2) _(tiger) _(has160) dnl
  69 _(sha) _(sha224) _(sha256) _(sha384) _(sha512) dnl
  70 _(whirlpool) _(whirlpool256) dnl
  71 _(rmd128) _(rmd160) _(rmd256) _(rmd320)')
  72 define(`hash_modes', `_(mgf) _(hmac)')
  73
  74 MODES = \
  75         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \
  76         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \
  77         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \
  78         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h')
  79
  80 $(MODES): modes-stamp
  81 modes-stamp: genmodes
  82         cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')"
  83         cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')"
  84         echo datestamp >modes-stamp
  85
  86 define(`gen_tables', `dnl
  87 _(des) _(blowfish) _(twofish) dnl
  88 _(square) _(rijndael) _(whirlpool) dnl
  89 _(safer) _(mars) _(tiger) dnl
  90 _(gfshare) _(gfx-sqr)')
  91
  92 autoheaders: addsuffix(`gen_tables', `-tab.h') primetab.h mptypes.h
  93 define(`emit', `
  94 _item`'-tab.h: _item`'-mktab
  95         ./_item`'-mktab >_item`'-tab.h.new
  96         mv _item`'-tab.h.new _item`'-tab.h')dnl
  97 gen_tables
  98
  99 primetab.h: primetab.c
 100 primetab.c: genprimes
 101         ./genprimes -h primetab.h -c primetab.c \
 102                 -s CATACOMB_PRIMETAB_H -n 256 \
 103                 -t "unsigned short" -i primetab
 104 archinclude_HEADERS = mptypes.h
 105 mptypes.h: mptypes
 106         ./mptypes >mptypes.h.new
 107         mv mptypes.h.new mptypes.h
 108
 109 ectab.c: ectab.in ec-gentab.awk mpdump
 110         $(srcdir)/ec-gentab.awk <$(srcdir)/ectab.in >ectab.c.new
 111         mv ectab.c.new ectab.c
 112
 113 ptab.c: ptab.in p-gentab.awk mpdump
 114         $(srcdir)/p-gentab.awk <$(srcdir)/ptab.in >ptab.c.new
 115         mv ptab.c.new ptab.c
 116
 117 bintab.c: bintab.in bin-gentab.awk mpdump
 118         $(srcdir)/bin-gentab.awk <$(srcdir)/bintab.in >bintab.c.new
 119         mv bintab.c.new bintab.c
 120
 121 gciphertab.c: gengctab
 122         $(srcdir)/gengctab gccipher gcipher >gciphertab.c.new \
 123                 "lit(join(`ciphers', `-', `cipher_modes')) \
 124                 lit(join(`hashes', `-', `_(mgf)')) \
 125                 rc4 seal"
 126         mv gciphertab.c.new gciphertab.c
 127
 128 gmactab.c: gengctab
 129         $(srcdir)/gengctab gcmac gmac >gmactab.c.new \
 130                 "lit(join(`hashes', `-', `_(hmac)'))"
 131         mv gmactab.c.new gmactab.c
 132
 133 ghashtab.c: gengctab
 134         $(srcdir)/gengctab gchash ghash >ghashtab.c.new \
 135                 "lit(`hashes') \
 136                 crc32=gcrc32"
 137         mv ghashtab.c.new ghashtab.c
 138
 139 BUILT_SOURCES = \
 140         getdate.c modes-stamp gciphertab.c gmactab.c ghashtab.c \
 141         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 142         addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \
 143         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 144         addsuffix(join(`hashes', `-', `hash_modes'), `.h')
 145
 146 ## --- Building the main library ---
 147
 148 lib_LTLIBRARIES = libcatacomb.la
 149
 150 libcatacomb_la_LDFLAGS = -version-info 3:0:1
 151 ## Middle number is the patchlevel.  Final number is the minor version.  The
 152 ## difference between the first and last numbers is major version.
 153
 154 pkginclude_HEADERS = \
 155         arena.h paranoia.h buf.h qdparse.h \
 156         blkc.h hash.h gcipher.h ghash.h gmac.h grand.h ghash-def.h \
 157         lcrand.h fibrand.h rc4.h seal.h rand.h noise.h fipstest.h maurer.h \
 158         key.h key-error.h key-data.h passphrase.h pixie.h lmem.h \
 159         mpx.h bitops.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \
 160         exp.h mpbarrett.h mpmont.h mpreduce.h mp-exp.h \
 161         mpcrt.h mprand.h mpmul.h \
 162         gfx.h gf.h gfreduce.h gfn.h gf-exp.h \
 163         primetab.h pfilt.h rabin.h \
 164         pgen.h prim.h strongprime.h limlee.h keycheck.h \
 165         bbs.h rsa.h dh.h dsarand.h dsa.h gdsa.h gkcdsa.h \
 166         tlsprf.h sslprf.h \
 167         gfshare.h share.h \
 168         rho.h \
 169         field.h field-guts.h field-exp.h \
 170         ec.h ec-guts.h ec-exp.h ec-test.h ectab.h ec-keys.h ec-raw.h \
 171         ptab.h bintab.h group.h group-guts.h \
 172         allwithsuffix(`ciphers', `cipher_modes', `.h') \
 173         allwithsuffix(`hashes', `hash_modes', `.h') \
 174         addsuffix(`cipher_modes', `-def.h') \
 175         addsuffix(`hash_modes', `-def.h') crc32.h
 176
 177 define(`MP_SOURCES',
 178         `mpx.c mpx-kmul.c mpx-ksqr.c mpscan.c mparena.c qdparse.c \
 179         mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \
 180         mp-sqrt.c mp-gcd.c mp-jacobi.c mp-modsqrt.c mp-exp.c \
 181         mpint.c mptext.c mptext-file.c mptext-string.c mptext-dstr.c \
 182         mptext-len.c \
 183         exp.c mpcrt.c mpmul.c mprand.c \
 184         mpbarrett.c mpbarrett-exp.c mpbarrett-mexp.c mpbarrett-exp.h \
 185         mpmont.c mpmont-exp.c mpmont-mexp.c mpmont-exp.h \
 186         mpreduce.c mpreduce-exp.h \
 187         group-stdops.c group-exp.c group-exp.h g-prime.c g-bin.c \
 188           group-parse.c \
 189         group-string.c group-file.c group-dstr.c \
 190         rho.c buf.c ptab.c bintab.c \
 191         GF_SOURCES PGEN_SOURCES EC_SOURCES')
 192
 193 define(`GF_SOURCES',
 194         `gfx.c gfx-kmul.c gfx-sqr.c gf-arith.c gf-exp.c gf-gcd.c \
 195         gfreduce.c gfreduce-exp.h gfn.c')
 196
 197 define(`EC_SOURCES',
 198         `field.c field-parse.c field-exp.c \
 199         f-prime.c f-niceprime.c f-binpoly.c \
 200         ec.c ec-exp.c ec-prime.c ec-bin.c ec-test.c ec-info.c ectab.c \
 201         ec-fetch.c ec-raw.c g-ec.c')
 202
 203 define(`PGEN_SOURCES',
 204         `pfilt.c rabin.c \
 205         pgen.c pgen-stdev.c pgen-safe.c pgen-gcd.c prim.c strongprime.c \
 206         limlee.c \
 207         keycheck.c keycheck-mp.c keycheck-report.c \
 208         bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \
 209         rsa-priv.c rsa-pub.c rsa-gen.c rsa-recover.c rsa-fetch.c \
 210         oaep.c pkcs1.c pss.c \
 211         dh-gen.c dh-limlee.c dh-check.c dh-fetch.c dh-param.c \
 212         dsarand.c dsa-sign.c dsa-verify.c dsa-gen.c dsa-check.c \
 213         gdsa.c gkcdsa.c \
 214         key-data.c key-flags.c key-text.c key-binary.c key-pass.c \
 215         key-pack.c key-misc.c key-file.c key-attr.c key-io.c key-moan.c \
 216         key-error.c key-fetch.c \
 217         primetab.c share.c')
 218
 219 libcatacomb_la_SOURCES = \
 220         grand.c keysz.c \
 221         lcrand.c fibrand.c rc4.c seal.c rand.c noise.c fipstest.c maurer.c \
 222         arena.c \
 223         passphrase.c pixie-client.c pixie-common.c lmem.c \
 224         tlsprf.c sslprf.c \
 225         gfshare.c \
 226         MP_SOURCES karatsuba.h \
 227         gciphertab.c ghashtab.c gmactab.c \
 228         des-base.c des-base.h \
 229         desx-tab.h \
 230         rc2-tab.h \
 231         skipjack-tab.h \
 232         cast-s.c cast-sk.c cast-base.h cast-tab.h \
 233         rijndael-base.c rijndael-base.h \
 234         md2-tab.h \
 235         serpent-sbox.h skipjack-tab.h tiger-base.h \
 236         daftstory.h \
 237         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 238         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 239         addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c') crc32.c
 240
 241 des-base.lo: des-tab.h
 242 blowfish.lo: blowfish-tab.h
 243 twofish.lo: twofish-tab.h
 244 square.lo: square-tab.h
 245 rijndael-base.lo: rijndael-tab.h
 246 whirlpool.lo: whirlpool-tab.h
 247 safer.lo: safer-tab.h
 248 mars.lo: mars-tab.h
 249 tiger.lo: tiger-tab.h
 250 gfshare.lo: gfshare-tab.h
 251 gfx-sqr.lo: gfx-sqr-tab.h
 252
 253 ## --- Utility programs ---
 254
 255 bin_PROGRAMS = \
 256         dsig key pixie cookie rspit factorial hashsum mkphrase catcrypt
 257 noinst_LIBRARIES = libcatcrypt.a
 258 bin_SCRIPTS = catacomb-config xpixie
 259 noinst_PROGRAMS = \
 260         genprimes mptypes serpent-check bittest mpdump \
 261         perftest \
 262         addsuffix(`gen_tables', `-mktab')
 263 LDADD = libcatacomb.la libcatcrypt.a
 264
 265 define(`LIBCAT_SRC', `cc.h getdate.h dnl
 266         cc-sig.c cc-subcmd.c cc-enc.c cc-kem.c cc-list.c')
 267 libcatcrypt_a_SOURCES = LIBCAT_SRC getdate.y
 268
 269 patsubst(MP_SOURCES, `\.c\>', `.lo') dsig.o keyutil.o rspit.o \
 270         patsubst(LIBCAT_SRC, `\.c\>', `.o'): \
 271         mptypes.h primetab.h
 272
 273 dsig_SOURCES = dsig.c
 274 cookie_SOURCES = cookie.c
 275 catcrypt_SOURCES = catcrypt.c
 276 key_SOURCES = keyutil.c
 277 hashsum_SOURCES = hashsum.c
 278 rspit_SOURCES = rspit.c
 279 factorial_SOURCES = factorial.c
 280 perftest_SOURCES = perftest.c
 281 pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c
 282 pixie_LDADD =
 283 mkphrase_SOURCES = mkphrase.c
 284 bittest_SOURCES = bittest.c
 285 bittest_LDADD =
 286
 287 define(`emit', `
 288 patsubst(_item, `[^a-zA-Z0-9]', `_')_mktab_SOURCES = _item`'-mktab.c
 289 patsubst(_item, `[^a-zA-Z0-9]', `_')_mktab_LDADD =')dnl
 290 gen_tables
 291
 292 serpent_check_SOURCES = serpent-check.c
 293 serpent_check_LDADD =
 294
 295 genprimes_SOURCES = genprimes.c
 296 genprimes_LDADD =
 297
 298 mptypes_SOURCES = mptypes.c
 299 mptypes_LDADD =
 300
 301 mpdump_SOURCES = \
 302         mpdump.c \
 303         mpx.c mpx-kmul.c mpx-ksqr.c mpscan.c mparena.c \
 304         mp-misc.c mp-mem.c mp-const.c mp-arith.c mp-io.c \
 305         mptext.c mptext-string.c
 306 mpdump_LDADD =
 307
 308 ## --- Install the pixie setuid-root if we can ---
 309 ##
 310 ## Bodge around a bug in Automake: it doesn't call `install-exec-hook' from
 311 ## `install' if there are subdirectories.
 312
 313 changequote(<, >)
 314 install: install-exec-hook
 315 install-exec-hook:
 316         @pixie="$(DESTDIR)$(bindir)/`echo pixie|sed $(transform)`"; \
 317         if chown root $$pixie && chmod 4755 $$pixie; then \
 318           echo "chown root $$pixie"; \
 319           echo "chmod 4755 $$pixie"; \
 320         else \
 321           echo "***"; \
 322           echo "*** You should probably install $$pixie setuid-root."; \
 323           echo "***"; \
 324         fi
 325 changequote(`, ')
 326
 327 ## --- Documentation ---
 328
 329 man_MANS = key.1 dsig.1 cookie.1 catcrypt.1 hashsum.1 keyring.5 pixie.1
 330
 331 ## --- Other handy definitions ---
 332
 333 EXTRA_DIST = \
 334         Makefile.m4 genmodes gengctab $(man_MANS) xpixie \
 335         group-test.c rsa-test.c \
 336         ectab.in ec-gentab.awk ptab.in p-gentab.awk bintab.in bin-gentab.awk \
 337         README.cipher README.hash README.random README.mp \
 338         debian/rules debian/copyright debian/control debian/changelog \
 339         debian/catacomb-bin.postinst debian/catacomb-bin.config \
 340         debian/catacomb-bin.prerm debian/catacomb-bin.templates
 341
 342 dist-hook:
 343         @for i in getdate.c gciphertab.c ghashtab.c gmactab.c; do \
 344           ln $$i $(distdir) || ln $(srcdir)/$$i $(distdir) || true; \
 345         done
 346         @echo datestamp >$(distdir)/modes-stamp || true
 347         @for i in calc tests; do \
 348           mkdir $(distdir)/$$i; \
 349           ln $(srcdir)/$$i/*[!~] $(distdir)/$$i; \
 350         done || true
 351 #       kr=$$HOME/.catacomb/dsig-keyring; \
 352 #       if [ -r $$kr ]; then \
 353 #         cd $(distdir); \
 354 #         ../key -k $$kr extract -f -secret KEYRING; \
 355 #         find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \
 356 #       fi
 357
 358 ## --- Testing ---
 359
 360 define(`testprogs', `')
 361
 362 define(`CTESTRIG',
 363 `define(`testprogs', testprogs \
 364         $1.t)dnl
 365 $1.to: $1.c
 366         $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to
 367 $1.t: $1.to libcatacomb.la
 368         $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t')
 369
 370 CTESTRIG(rc4)
 371 CTESTRIG(seal)
 372 adorn(`nl`'CTESTRIG(', `ciphers', `)')
 373 adorn(`nl`'CTESTRIG(', `hashes', `)')
 374 adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)')
 375 adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)')
 376 CTESTRIG(lcrand)
 377 CTESTRIG(tlsprf)
 378 CTESTRIG(sslprf)
 379 CTESTRIG(mpx)
 380 CTESTRIG(mpx-kmul)
 381 CTESTRIG(mpx-ksqr)
 382 CTESTRIG(mp-arith)
 383 CTESTRIG(mp-modsqrt)
 384 CTESTRIG(mp-gcd)
 385 CTESTRIG(mp-jacobi)
 386 CTESTRIG(mp-sqrt)
 387 CTESTRIG(mptext)
 388 CTESTRIG(mpint)
 389 CTESTRIG(mpbarrett)
 390 CTESTRIG(mpbarrett-exp)
 391 CTESTRIG(mpbarrett-mexp)
 392 CTESTRIG(mpmont)
 393 CTESTRIG(mpmont-exp)
 394 CTESTRIG(mpmont-mexp)
 395 CTESTRIG(mpreduce)
 396 CTESTRIG(mpcrt)
 397 CTESTRIG(mpmul)
 398 CTESTRIG(rsa-test)
 399 CTESTRIG(gfx)
 400 CTESTRIG(gfx-sqr)
 401 CTESTRIG(gfx-kmul)
 402 CTESTRIG(gf-arith)
 403 CTESTRIG(gf-gcd)
 404 CTESTRIG(gfreduce)
 405 CTESTRIG(gfn)
 406 CTESTRIG(ec-prime)
 407 CTESTRIG(ec-bin)
 408 CTESTRIG(ec-test)
 409 CTESTRIG(ec-info)
 410 CTESTRIG(dh-param)
 411 CTESTRIG(group-test)
 412 CTESTRIG(gdsa)
 413 CTESTRIG(gkcdsa)
 414 CTESTRIG(pgen)
 415 CTESTRIG(dsa-gen)
 416 CTESTRIG(dsa-sign)
 417 CTESTRIG(dsa-verify)
 418 CTESTRIG(bbs-rand)
 419 CTESTRIG(bbs-jump)
 420 CTESTRIG(gfshare)
 421 CTESTRIG(share)
 422 CTESTRIG(rho)
 423
 424 TESTS = serpent-check bittest testprogs
 425
 426 CLEANFILES = \
 427         *.t *.to \
 428         mptypes.h primetab.c primetab.h ectab.c \
 429         addsuffix(`gen_tables', `-tab.h')
 430
 431 ## --- Makefile building (haha!) ---
 432
 433 $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4
 434         m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am.new
 435         mv $(srcdir)/Makefile.am.new $(srcdir)/Makefile.am
 436
 437 DISTCLEANFILES = libtool
 438
 439 MAINTAINERCLEANFILES = \
 440         $(srcdir)/Makefile.am \
 441         $(srcdir)/getdate.c getdate.c \
 442         $(MODES) modes-stamp $(srcdir)/modes-stamp
 443
 444 ##----- That's all, folks ---------------------------------------------------