git.distorted.org.uk Git - u/mdw/catacomb/blob - Makefile.m4

   1 ## -*-m4-*-
   2 ##
   3 ## $Id$
   4 ##
   5 ## Makefile for Catacomb
   6 ##
   7 ## (c) 1999 Straylight/Edgeware
   8 ##
   9
  10 ##----- Licensing notice ----------------------------------------------------
  11 ##
  12 ## This file is part of Catacomb.
  13 ##
  14 ## Catacomb is free software; you can redistribute it and/or modify
  15 ## it under the terms of the GNU Library General Public License as
  16 ## published by the Free Software Foundation; either version 2 of the
  17 ## License, or (at your option) any later version.
  18 ##
  19 ## Catacomb is distributed in the hope that it will be useful,
  20 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ## GNU Library General Public License for more details.
  23 ##
  24 ## You should have received a copy of the GNU Library General Public
  25 ## License along with Catacomb; if not, write to the Free
  26 ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  27 ## MA 02111-1307, USA.
  28
  29 AUTOMAKE_OPTIONS = foreign
  30
  31 SUBDIRS = tests
  32
  33 archincludedir = $(libdir)/catacomb/include
  34
  35 ## --- List handling macros ---
  36 ##
  37 ## List handling is nice, usually.  Unfortunately, I based this design on
  38 ## TeX list macros rather than anything sensible...
  39
  40 define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'')
  41 define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')')
  42 define(`join',
  43 `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')')
  44 define(`addsuffix', `adorn(`', `$1', `$2')')
  45 define(`lit', `adorn(`', `$1', `')')
  46 define(`nl', `
  47 ')
  48
  49 define(`allwithsuffix',
  50 `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl
  51 addsuffix(join(`$1', `-', `$2'), `$3')')
  52
  53 ## --- Autogenerated source files ---
  54
  55 define(`ciphers', `dnl
  56 _(des) _(desx) _(des3) _(mars) dnl
  57 _(idea) _(safer) _(safersk) dnl
  58 _(blowfish) _(twofish) dnl
  59 _(tea) _(xtea) dnl
  60 _(rc2) _(rc5) dnl
  61 _(skipjack) dnl
  62 _(cast128) _(cast256) dnl
  63 _(square) _(rijndael) _(rijndael192) _(rijndael256) dnl
  64 _(serpent) _(noekeon)')
  65 define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)')
  66
  67 define(`hashes', `dnl
  68 _(md5) _(md4) _(md2) _(tiger) _(has160) dnl
  69 _(sha) _(sha224) _(sha256) _(sha384) _(sha512) dnl
  70 _(rmd128) _(rmd160) _(rmd256) _(rmd320)')
  71 define(`hash_modes', `_(mgf) _(hmac)')
  72
  73 MODES = \
  74         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \
  75         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \
  76         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \
  77         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h')
  78
  79 $(MODES): modes-stamp
  80 modes-stamp: genmodes
  81         cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')"
  82         cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')"
  83         echo datestamp >modes-stamp
  84
  85 define(`gen_tables', `dnl
  86 _(des) _(blowfish) _(twofish) dnl
  87 _(square) _(rijndael) dnl
  88 _(safer) _(mars) _(tiger) dnl
  89 _(gfshare) _(gfx-sqr)')
  90
  91 autoheaders: addsuffix(`gen_tables', `-tab.h') primetab.h mptypes.h
  92 define(`emit', `
  93 _item`'-tab.h: _item`'-mktab
  94         ./_item`'-mktab >_item`'-tab.h.new
  95         mv _item`'-tab.h.new _item`'-tab.h')dnl
  96 gen_tables
  97
  98 primetab.h: primetab.c
  99 primetab.c: genprimes
 100         ./genprimes -h primetab.h -c primetab.c \
 101                 -s CATACOMB_PRIMETAB_H -n 256 \
 102                 -t "unsigned short" -i primetab
 103 archinclude_HEADERS = mptypes.h
 104 mptypes.h: mptypes
 105         ./mptypes >mptypes.h.new
 106         mv mptypes.h.new mptypes.h
 107
 108 ectab.c: ectab.in ec-gentab.awk mpdump
 109         $(srcdir)/ec-gentab.awk <$(srcdir)/ectab.in >ectab.c.new
 110         mv ectab.c.new ectab.c
 111
 112 ptab.c: ptab.in p-gentab.awk mpdump
 113         $(srcdir)/p-gentab.awk <$(srcdir)/ptab.in >ptab.c.new
 114         mv ptab.c.new ptab.c
 115
 116 gciphertab.c: gengctab
 117         $(srcdir)/gengctab gccipher gcipher >gciphertab.c.new \
 118                 "lit(join(`ciphers', `-', `cipher_modes')) \
 119                 lit(join(`hashes', `-', `_(mgf)')) \
 120                 rc4 seal"
 121         mv gciphertab.c.new gciphertab.c
 122
 123 gmactab.c: gengctab
 124         $(srcdir)/gengctab gcmac gmac >gmactab.c.new \
 125                 "lit(join(`hashes', `-', `_(hmac)'))"
 126         mv gmactab.c.new gmactab.c
 127
 128 ghashtab.c: gengctab
 129         $(srcdir)/gengctab gchash ghash >ghashtab.c.new \
 130                 "lit(`hashes') \
 131                 crc32=gcrc32"
 132         mv ghashtab.c.new ghashtab.c
 133
 134 BUILT_SOURCES = \
 135         getdate.c modes-stamp gciphertab.c gmactab.c ghashtab.c \
 136         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 137         addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \
 138         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 139         addsuffix(join(`hashes', `-', `hash_modes'), `.h')
 140
 141 ## --- Building the main library ---
 142
 143 lib_LTLIBRARIES = libcatacomb.la
 144
 145 libcatacomb_la_LDFLAGS = -version-info 3:0:1
 146 ## Middle number is the patchlevel.  Final number is the minor version.  The
 147 ## difference between the first and last numbers is major version.
 148
 149 pkginclude_HEADERS = \
 150         arena.h paranoia.h buf.h qdparse.h \
 151         blkc.h hash.h gcipher.h ghash.h gmac.h grand.h ghash-def.h \
 152         lcrand.h fibrand.h rc4.h seal.h rand.h noise.h fipstest.h maurer.h \
 153         key.h key-data.h passphrase.h pixie.h lmem.h \
 154         mpx.h bitops.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \
 155         exp.h mpbarrett.h mpmont.h mpreduce.h \
 156         mpcrt.h mprand.h mpmul.h \
 157         gfx.h gf.h gfreduce.h gfn.h \
 158         primetab.h pfilt.h rabin.h \
 159         pgen.h prim.h strongprime.h limlee.h keycheck.h \
 160         bbs.h rsa.h dh.h dsarand.h dsa.h gdsa.h gkcdsa.h \
 161         tlsprf.h sslprf.h \
 162         gfshare.h share.h \
 163         rho.h \
 164         field.h ec.h ec-exp.h ec-test.h ectab.h ec-keys.h ec-raw.h \
 165         ptab.h group.h \
 166         allwithsuffix(`ciphers', `cipher_modes', `.h') \
 167         allwithsuffix(`hashes', `hash_modes', `.h') \
 168         addsuffix(`cipher_modes', `-def.h') \
 169         addsuffix(`hash_modes', `-def.h') crc32.h
 170
 171 define(`MP_SOURCES',
 172         `mpx.c mpx-kmul.c mpx-ksqr.c mpscan.c mparena.c qdparse.c \
 173         mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \
 174         mp-sqrt.c mp-gcd.c mp-jacobi.c mp-modsqrt.c \
 175         mpint.c mptext.c mptext-file.c mptext-string.c mptext-dstr.c \
 176         mptext-len.c \
 177         exp.c mpcrt.c mpmul.c mprand.c \
 178         mpbarrett.c mpbarrett-exp.c mpbarrett-mexp.c mpbarrett-exp.h \
 179         mpmont.c mpmont-exp.c mpmont-mexp.c mpmont-exp.h \
 180         mpreduce.c mpreduce-exp.h \
 181         group-stdops.c group-exp.c group-exp.h g-prime.c group-parse.c \
 182         group-string.c group-file.c group-dstr.c \
 183         rho.c buf.c ptab.c \
 184         GF_SOURCES PGEN_SOURCES EC_SOURCES')
 185
 186 define(`GF_SOURCES',
 187         `gfx.c gfx-kmul.c gfx-sqr.c gf-arith.c gf-gcd.c \
 188         gfreduce.c gfreduce-exp.h gfn.c')
 189
 190 define(`EC_SOURCES',
 191         `field.c field-parse.c f-prime.c f-niceprime.c f-binpoly.c \
 192         ec.c ec-exp.c ec-prime.c ec-bin.c ec-test.c ec-info.c ectab.c \
 193         ec-fetch.c ec-raw.c g-ec.c')
 194
 195 define(`PGEN_SOURCES',
 196         `pfilt.c rabin.c \
 197         pgen.c pgen-stdev.c pgen-safe.c pgen-gcd.c prim.c strongprime.c \
 198         limlee.c \
 199         keycheck.c keycheck-mp.c keycheck-report.c \
 200         bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \
 201         rsa-priv.c rsa-pub.c rsa-gen.c rsa-recover.c rsa-fetch.c \
 202         oaep.c pkcs1.c pss.c \
 203         dh-gen.c dh-limlee.c dh-check.c dh-fetch.c dh-param.c \
 204         dsarand.c dsa-sign.c dsa-verify.c dsa-gen.c dsa-check.c \
 205         gdsa.c gkcdsa.c \
 206         key-data.c key-flags.c key-text.c key-binary.c key-pass.c \
 207         key-pack.c key-misc.c key-file.c key-attr.c key-io.c key-moan.c \
 208         key-error.c key-fetch.c \
 209         primetab.c share.c')
 210
 211 libcatacomb_la_SOURCES = \
 212         grand.c keysz.c \
 213         lcrand.c fibrand.c rc4.c seal.c rand.c noise.c fipstest.c maurer.c \
 214         arena.c \
 215         passphrase.c pixie-client.c pixie-common.c lmem.c \
 216         tlsprf.c sslprf.c \
 217         gfshare.c \
 218         MP_SOURCES karatsuba.h \
 219         gciphertab.c ghashtab.c gmactab.c \
 220         des-base.c des-base.h \
 221         desx-tab.h \
 222         rc2-tab.h \
 223         skipjack-tab.h \
 224         cast-s.c cast-sk.c cast-base.h cast-tab.h \
 225         rijndael-base.c rijndael-base.h \
 226         md2-tab.h \
 227         serpent-sbox.h skipjack-tab.h tiger-base.h \
 228         daftstory.h \
 229         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 230         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 231         addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c') crc32.c
 232
 233 des-base.lo: des-tab.h
 234 blowfish.lo: blowfish-tab.h
 235 twofish.lo: twofish-tab.h
 236 square.lo: square-tab.h
 237 rijndael-base.lo: rijndael-tab.h
 238 safer.lo: safer-tab.h
 239 mars.lo: mars-tab.h
 240 tiger.lo: tiger-tab.h
 241 gfshare.lo: gfshare-tab.h
 242 gfx-sqr.lo: gfx-sqr-tab.h
 243 patsubst(MP_SOURCES, `\.c\>', `.lo') dsig.o keyutil.o rspit.o: \
 244         mptypes.h primetab.h
 245
 246 ## --- Utility programs ---
 247
 248 bin_PROGRAMS = \
 249         dsig key pixie cookie rspit factorial hashsum mkphrase catcrypt
 250 noinst_LIBRARIES = libcatcrypt.a
 251 bin_SCRIPTS = catacomb-config xpixie
 252 noinst_PROGRAMS = \
 253         genprimes mptypes serpent-check bittest mpdump \
 254         perftest \
 255         addsuffix(`gen_tables', `-mktab')
 256 LDADD = libcatacomb.la libcatcrypt.a
 257
 258 libcatcrypt_a_SOURCES = \
 259         cc.h getdate.h \
 260         cc-sig.c cc-subcmd.c cc-enc.c cc-kem.c cc-list.c \
 261         getdate.y
 262
 263 dsig_SOURCES = dsig.c
 264 cookie_SOURCES = cookie.c
 265 catcrypt_SOURCES = catcrypt.c
 266 key_SOURCES = keyutil.c
 267 hashsum_SOURCES = hashsum.c
 268 rspit_SOURCES = rspit.c
 269 factorial_SOURCES = factorial.c
 270 perftest_SOURCES = perftest.c
 271 pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c
 272 pixie_LDADD =
 273 mkphrase_SOURCES = mkphrase.c
 274 bittest_SOURCES = bittest.c
 275 bittest_LDADD =
 276
 277 define(`emit', `
 278 patsubst(_item, `[^a-zA-Z0-9]', `_')_mktab_SOURCES = _item`'-mktab.c
 279 patsubst(_item, `[^a-zA-Z0-9]', `_')_mktab_LDADD =')dnl
 280 gen_tables
 281
 282 serpent_check_SOURCES = serpent-check.c
 283 serpent_check_LDADD =
 284
 285 genprimes_SOURCES = genprimes.c
 286 genprimes_LDADD =
 287
 288 mptypes_SOURCES = mptypes.c
 289 mptypes_LDADD =
 290
 291 mpdump_SOURCES = \
 292         mpdump.c \
 293         mpx.c mpx-kmul.c mpx-ksqr.c mpscan.c mparena.c \
 294         mp-misc.c mp-mem.c mp-const.c mp-arith.c mp-io.c \
 295         mptext.c mptext-string.c
 296 mpdump_LDADD =
 297
 298 ## --- Install the pixie setuid-root if we can ---
 299 ##
 300 ## Bodge around a bug in Automake: it doesn't call `install-exec-hook' from
 301 ## `install' if there are subdirectories.
 302
 303 changequote(<, >)
 304 install: install-exec-hook
 305 install-exec-hook:
 306         @pixie="$(DESTDIR)$(bindir)/`echo pixie|sed $(transform)`"; \
 307         if chown root $$pixie && chmod 4755 $$pixie; then \
 308           echo "chown root $$pixie"; \
 309           echo "chmod 4755 $$pixie"; \
 310         else \
 311           echo "***"; \
 312           echo "*** You should probably install $$pixie setuid-root."; \
 313           echo "***"; \
 314         fi
 315 changequote(`, ')
 316
 317 ## --- Documentation ---
 318
 319 man_MANS = key.1 dsig.1 cookie.1 catcrypt.1 hashsum.1 keyring.5 pixie.1
 320
 321 ## --- Other handy definitions ---
 322
 323 EXTRA_DIST = \
 324         Makefile.m4 genmodes gengctab $(man_MANS) xpixie \
 325         group-test.c rsa-test.c \
 326         ectab.in ec-gentab.awk ptab.in p-gentab.awk \
 327         README.cipher README.hash README.random README.mp \
 328         debian/rules debian/copyright debian/control debian/changelog \
 329         debian/catacomb-bin.postinst debian/catacomb-bin.config \
 330         debian/catacomb-bin.prerm debian/catacomb-bin.templates
 331
 332 dist-hook:
 333         @for i in getdate.c gciphertab.c ghashtab.c gmactab.c; do \
 334           ln $$i $(distdir) || ln $(srcdir)/$$i $(distdir) || true; \
 335         done
 336         @echo datestamp >$(distdir)/modes-stamp || true
 337         @for i in calc tests; do \
 338           mkdir $(distdir)/$$i; \
 339           ln $(srcdir)/$$i/*[!~] $(distdir)/$$i; \
 340         done || true
 341 #       kr=$$HOME/.catacomb/dsig-keyring; \
 342 #       if [ -r $$kr ]; then \
 343 #         cd $(distdir); \
 344 #         ../key -k $$kr extract -f -secret KEYRING; \
 345 #         find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \
 346 #       fi
 347
 348 ## --- Testing ---
 349
 350 define(`testprogs', `')
 351
 352 define(`CTESTRIG',
 353 `define(`testprogs', testprogs \
 354         $1.t)dnl
 355 $1.to: $1.c
 356         $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to
 357 $1.t: $1.to libcatacomb.la
 358         $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t')
 359
 360 CTESTRIG(rc4)
 361 CTESTRIG(seal)
 362 adorn(`nl`'CTESTRIG(', `ciphers', `)')
 363 adorn(`nl`'CTESTRIG(', `hashes', `)')
 364 adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)')
 365 adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)')
 366 CTESTRIG(lcrand)
 367 CTESTRIG(tlsprf)
 368 CTESTRIG(sslprf)
 369 CTESTRIG(mpx)
 370 CTESTRIG(mpx-kmul)
 371 CTESTRIG(mpx-ksqr)
 372 CTESTRIG(mp-arith)
 373 CTESTRIG(mp-modsqrt)
 374 CTESTRIG(mp-gcd)
 375 CTESTRIG(mp-jacobi)
 376 CTESTRIG(mp-sqrt)
 377 CTESTRIG(mptext)
 378 CTESTRIG(mpint)
 379 CTESTRIG(mpbarrett)
 380 CTESTRIG(mpbarrett-exp)
 381 CTESTRIG(mpbarrett-mexp)
 382 CTESTRIG(mpmont)
 383 CTESTRIG(mpmont-exp)
 384 CTESTRIG(mpmont-mexp)
 385 CTESTRIG(mpreduce)
 386 CTESTRIG(mpcrt)
 387 CTESTRIG(mpmul)
 388 CTESTRIG(rsa-test)
 389 CTESTRIG(gfx)
 390 CTESTRIG(gfx-sqr)
 391 CTESTRIG(gfx-kmul)
 392 CTESTRIG(gf-arith)
 393 CTESTRIG(gf-gcd)
 394 CTESTRIG(gfreduce)
 395 CTESTRIG(gfn)
 396 CTESTRIG(ec-prime)
 397 CTESTRIG(ec-bin)
 398 CTESTRIG(ec-test)
 399 CTESTRIG(ec-info)
 400 CTESTRIG(dh-param)
 401 CTESTRIG(group-test)
 402 CTESTRIG(gdsa)
 403 CTESTRIG(gkcdsa)
 404 CTESTRIG(pgen)
 405 CTESTRIG(dsa-gen)
 406 CTESTRIG(dsa-sign)
 407 CTESTRIG(dsa-verify)
 408 CTESTRIG(bbs-rand)
 409 CTESTRIG(bbs-jump)
 410 CTESTRIG(gfshare)
 411 CTESTRIG(share)
 412 CTESTRIG(rho)
 413
 414 TESTS = serpent-check bittest testprogs
 415
 416 CLEANFILES = \
 417         *.t *.to \
 418         mptypes.h primetab.c primetab.h ectab.c \
 419         addsuffix(`gen_tables', `-tab.h')
 420
 421 ## --- Makefile building (haha!) ---
 422
 423 $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4
 424         m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am.new
 425         mv $(srcdir)/Makefile.am.new $(srcdir)/Makefile.am
 426
 427 DISTCLEANFILES = libtool
 428
 429 MAINTAINERCLEANFILES = \
 430         $(srcdir)/Makefile.am \
 431         $(srcdir)/getdate.c getdate.c \
 432         $(MODES) modes-stamp $(srcdir)/modes-stamp
 433
 434 ##----- That's all, folks ---------------------------------------------------