mdw@git.distorted.org.uk Git - zone/blob - frontend.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Zone generator frontend
   4 ;;;
   5 ;;; (c) 2005 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 2 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software Foundation,
  22 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23
  24 (defpackage #:zone.frontend
  25   (:use #:common-lisp #:mdw.sys-base #:optparse #:net #:zone
  26         #+cmu #:mop
  27         #+sbcl #:sb-mop)
  28   (:export #:main))
  29 (in-package #:zone.frontend)
  30
  31 (defvar opt-zones nil
  32   "Which zones to be emitted.")
  33 (defvar opt-format :bind
  34   "Which format to use on output.")
  35 (defvar opt-debug nil
  36   "Whether to emit stack backtraces on error.")
  37
  38 (defun directory-exists-p (name)
  39
  40   ;; Make a pathname for NAME which has the right form for a directory.
  41   (let ((dirpath
  42          (let ((path (pathname name)))
  43            (if (null (pathname-name path))
  44                path
  45                (make-pathname :directory
  46                               (append (or (pathname-directory path)
  47                                           (list :relative))
  48                                       (list (pathname-name path)))
  49                               :name nil
  50                               :type nil
  51                               :defaults path)))))
  52
  53     ;; Now check that it exists.
  54     #+clisp (and (ext:probe-directory dirpath) (truename dirpath))
  55     #-clisp (probe-file dirpath)))
  56
  57 (eval-when (:compile-toplevel :load-toplevel)
  58   (defopthandler dir (var arg) ()
  59     (let ((path (directory-exists-p arg)))
  60       (if (and path
  61                (not (pathname-name path)))
  62           (setf var path)
  63           (option-parse-error "path `~A' doesn't name a directory." arg)))))
  64
  65 (define-program
  66     :version "1.0.0" :usage "ZONEDEF..."
  67     :help "Generates BIND zone files from Lisp descriptions."
  68     :options (options help-options
  69                       "Parsing options"
  70                       (#\f "feature" (:arg "KEYWORD")
  71                            (list *features* 'keyword)
  72                            "Insert KEYWORD in *features* list.")
  73                       (#\s "subnet" (:arg "NET")
  74                            (list zone:*preferred-subnets*)
  75                            "Designate NET as a preferred subnet.")
  76                       (#\D "debug" (set opt-debug)
  77                            "Produce stack backtrace on error.")
  78                       "Output options"
  79                       (#\d "directory" (:arg "DIRECTORY")
  80                            (dir *zone-output-path*)
  81                            "Write zone and serial files to DIRECTORY.")
  82                       (#\F "format" (:arg "FORMAT")
  83                            (keyword opt-format
  84                                     (delete-duplicates
  85                                      (loop for method in
  86                                            (generic-function-methods
  87                                             #'zone:zone-write)
  88                                            for specs =
  89                                            (method-specializers method)
  90                                            if (typep (car specs)
  91                                                      'eql-specializer)
  92                                            collect
  93                                            (eql-specializer-object
  94                                             (car specs)))))
  95                            "Format to use for output.")
  96                       (#\z "zone" (:arg "NAME") (list opt-zones)
  97                            "Write information about zone NAME.")))
  98
  99 (defun main ()
 100   (set-command-line-arguments)
 101   (let ((files nil))
 102     (flet ((run ()
 103              (dolist (f files)
 104                (let ((*package* (make-package "ZONE.SCRATCH"
 105                                               :use '(#:common-lisp
 106                                                      #:net #:zone))))
 107                  (load f :verbose nil :print nil :if-does-not-exist :error)
 108                  (delete-package *package*)))
 109              (zone-save opt-zones :format opt-format)))
 110       (with-unix-error-reporting ()
 111         (unless (option-parse-try
 112                   (do-options ()
 113                     (nil (rest)
 114                          (when (zerop (length rest))
 115                            (option-parse-error "no files to read"))
 116                          (setf files rest))))
 117           (die-usage)))
 118       (if opt-debug
 119           (run)
 120           (with-unix-error-reporting () (run))))))
 121
 122 ;;;----- That's all, folks --------------------------------------------------