mdw@git.distorted.org.uk Git - yaid/blob - configure.ac

   1 dnl -*-autoconf-*-
   2 dnl
   3 dnl Configuration script for YAID
   4 dnl
   5 dnl (c) 2012 Straylight/Edgeware
   6 dnl
   7
   8 dnl----- Licensing notice ---------------------------------------------------
   9 dnl
  10 dnl This file is part of Yet Another Ident Daemon (YAID).
  11 dnl
  12 dnl YAID is free software; you can redistribute it and/or modify
  13 dnl it under the terms of the GNU General Public License as published by
  14 dnl the Free Software Foundation; either version 2 of the License, or
  15 dnl (at your option) any later version.
  16 dnl
  17 dnl YAID is distributed in the hope that it will be useful,
  18 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 dnl GNU General Public License for more details.
  21 dnl
  22 dnl You should have received a copy of the GNU General Public License
  23 dnl along with YAID; if not, write to the Free Software Foundation,
  24 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 dnl--------------------------------------------------------------------------
  27 dnl Initialization.
  28
  29 mdw_AUTO_VERSION
  30 AC_INIT([yaid], AUTO_VERSION, [mdw@distorted.org.uk])
  31 AC_CONFIG_SRCDIR([yaid.c])
  32 AC_CONFIG_AUX_DIR([config])
  33 AM_INIT_AUTOMAKE([foreign])
  34 AC_CANONICAL_HOST
  35 mdw_SILENT_RULES
  36
  37 dnl--------------------------------------------------------------------------
  38 dnl C programming environment.
  39
  40 AC_PROG_CC
  41 AM_PROG_CC_C_O
  42 AX_CFLAGS_WARN_ALL
  43
  44 AC_CHECK_HEADERS([stdarg.h])
  45
  46 AX_TYPE_SOCKLEN_T
  47
  48 AC_SEARCH_LIBS([socket], [socket])
  49
  50 PKG_CHECK_MODULES([mLib], [mLib >= 2.2.1])
  51 AM_CFLAGS="$AM_CFLAGS $mLib_CFLAGS"
  52
  53 dnl--------------------------------------------------------------------------
  54 dnl System-specific code.
  55
  56 case "$host_os" in
  57   linux*) SYS=linux ;;
  58   *) AC_MSG_ERROR([no support for system `$host_os': patches welcome]) ;;
  59 esac
  60 AC_SUBST([SYS])
  61
  62 dnl--------------------------------------------------------------------------
  63 dnl Paths for interesting files.
  64
  65 mdw_DEFINE_PATHS([
  66   mdw_DEFINE_PATH([POLICYFILE], [${sysconfdir}/yaid.policy],
  67         [read global policy from this file.])
  68 ])
  69
  70 dnl--------------------------------------------------------------------------
  71 dnl Produce output.
  72
  73 AC_CONFIG_HEADER([config/config.h])
  74 AC_CONFIG_FILES([Makefile])
  75 AC_OUTPUT
  76
  77 dnl----- That's all, folks --------------------------------------------------