mdw@git.distorted.org.uk Git - sw-tools/blob - configure.in

   1 dnl -*-fundamental-*-
   2 dnl
   3 dnl $Id: configure.in,v 1.3 1999/06/18 18:59:39 mdw Exp $
   4 dnl
   5 dnl Configuration for sw-tools
   6 dnl
   7 dnl (c) 1999 EBI
   8 dnl
   9
  10 dnl ----- Licensing notice --------------------------------------------------
  11 dnl
  12 dnl This file is part of sw-tools.
  13 dnl
  14 dnl sw-tools is free software; you can redistribute it and/or modify
  15 dnl it under the terms of the GNU General Public License as published by
  16 dnl the Free Software Foundation; either version 2 of the License, or
  17 dnl (at your option) any later version.
  18 dnl
  19 dnl sw-tools is distributed in the hope that it will be useful,
  20 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 dnl GNU General Public License for more details.
  23 dnl
  24 dnl You should have received a copy of the GNU General Public License
  25 dnl along with sw-tools; if not, write to the Free Software Foundation,
  26 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  27
  28 dnl ----- Revision history --------------------------------------------------
  29 dnl
  30 dnl $Log: configure.in,v $
  31 dnl Revision 1.3  1999/06/18 18:59:39  mdw
  32 dnl Preliminary work for Perl scripts.
  33 dnl
  34 dnl Revision 1.2  1999/06/04 13:56:36  mdw
  35 dnl Bump version.
  36 dnl
  37 dnl Revision 1.1.1.1  1999/06/02 16:53:33  mdw
  38 dnl Initial import.
  39 dnl
  40
  41 dnl --- Boring boilerplate ---
  42
  43 AC_INIT(src/sw.c)
  44 AM_INIT_AUTOMAKE(sw-tools, 1.0.0pre5)
  45 AM_CONFIG_HEADER(config.h)
  46
  47 dnl --- Work out the architecture name ---
  48
  49 AC_MSG_CHECKING([architecture name])
  50 arch=`$srcdir/sw.in --archname`
  51 AC_MSG_RESULT($arch)
  52 AC_DEFINE_UNQUOTED(ARCH, "$arch")
  53 AC_SUBST(arch)
  54
  55 dnl --- Set up the C compiler ---
  56
  57 AC_PROG_CC
  58 mdw_GCC_FLAGS
  59
  60 dnl --- Find a Perl ---
  61
  62 mdw_PROG_PERL(5.003)
  63 mdw_CHECK_PERL(5.003)
  64
  65 dnl --- Check for <unistd.h> ---
  66
  67 AC_CHECK_HEADERS(unistd.h)
  68
  69 dnl --- Find an appropriate remote shell program ---
  70
  71 AC_ARG_WITH(rsh,
  72 [  --with-rsh=PROGRAM      use PROGRAM to start remote shells],
  73 [RSH=$withval])
  74 AC_PATH_PROGS(RSH, $RSH remsh rsh ssh, rsh)
  75 AC_DEFINE_UNQUOTED(RSH, "$RSH")
  76
  77 dnl --- Find out whether I have `strsignal' or `sys_siglist' ---
  78
  79 AC_CHECK_FUNCS(strsignal _sys_siglist, break)
  80
  81 dnl --- Decide whether to declare `environ' ---
  82
  83 AC_CACHE_CHECK([for declaration of \`environ'], sw_cv_environ,
  84 [AC_EGREP_CPP(environ,
  85 [#include <sys/types.h>
  86 #if HAVE_UNISTD_H
  87 #include <unistd.h>
  88 #endif
  89 #if STDC_HEADERS
  90 #include <stdlib.h>
  91 #include <stddef.h>
  92 #endif], [sw_cv_environ=yes], [sw_cv_environ=no])])
  93 if test $sw_cv_environ = yes; then
  94   AC_DEFINE(DECL_ENVIRON)
  95 fi
  96
  97 dnl --- Find a curses library ---
  98 dnl
  99 dnl Try to find one which knows how to resize a terminal.
 100
 101 mdw_CHECK_MANYLIBS(newwin, ncurses curses, AC_DEFINE(HAVE_CURSES))
 102
 103 if test $mdw_cv_lib_newwin != no; then
 104 AC_CHECK_HEADERS([ncurses.h ncurses/ncurses.h curses.h], [break])
 105
 106 if test "$ac_cv_header_ncurses_h" = "no" &&
 107    test "$ac_cv_header_ncurses_ncurses_h" = "no" &&
 108    test "$ac_cv_header_curses_h" = "no"; then
 109      AC_MSG_WARN([couldn't find a \`curses' header.  Assuming \`curses.h'.])
 110      AC_DEFINE(HAVE_CURSES_H)
 111 fi
 112
 113 AC_CHECK_FUNCS(wresize)
 114 fi
 115
 116
 117 dnl --- Other handy libraries ---
 118
 119 mdw_CHECK_MANYLIBS(socketpair, socket)
 120
 121 dnl --- Various standard types ---
 122
 123 AC_TYPE_PID_T
 124 AC_TYPE_SIZE_T
 125 AC_TYPE_UID_T
 126
 127 AC_CACHE_CHECK(for ssize_t, sw_cv_ssize_t,
 128 [AC_EGREP_CPP(ssize_t,
 129 [#include <sys/types.h>
 130 #if HAVE_UNISTD_H
 131 #include <unistd.h>
 132 #endif
 133 #if STDC_HEADERS
 134 #include <stdlib.h>
 135 #include <stddef.h>
 136 #endif],
 137 [sw_cv_ssize_t=yes], [sw_cv_ssize_t=no])])
 138
 139 if test $sw_cv_ssize_t = no; then
 140   AC_DEFINE(ssize_t, int)
 141 fi
 142
 143 dnl --- Write in some useful paths ---
 144
 145 mdw_prefix=$prefix mdw_exec_prefix=$exec_prefix
 146 transform=`echo "$program_transform_name"|sed 's,\\\\\\\\,\\\\,g; s,\\$\\$,$,g'`
 147 test "$prefix" = "NONE" && prefix=$ac_default_prefix
 148 test "$exec_prefix" = "NONE" && exec_prefix=$prefix
 149 SW=`echo sw|sed "$transform"`
 150 AC_SUBST(SW)
 151 AC_DEFINE_UNQUOTED(PREFIX, "$mdw_prefix")
 152 AC_DEFINE_UNQUOTED(BINDIR, "`eval echo $bindir`")
 153 AC_DEFINE_UNQUOTED(DATADIR, "`eval echo $datadir`")
 154 AC_DEFINE_UNQUOTED(SW, "$SW")
 155 pkgdatadir="`eval echo $datadir/sw`"
 156 AC_SUBST(pkgdatadir)
 157 prefix=$mdw_prefix exec_prefix=$mdw_exec_prefix
 158
 159 dnl --- Output the configuration ---
 160
 161 AC_CONFIG_SUBDIRS(mLib)
 162 AC_OUTPUT(Makefile src/Makefile sw sw-share)
 163
 164 dnl ----- That's all, folks -------------------------------------------------