mdw@git.distorted.org.uk Git - sw-tools/blob - configure.in

   1 dnl -*-fundamental-*-
   2 dnl
   3 dnl $Id: configure.in,v 1.2 1999/06/04 13:56:36 mdw Exp $
   4 dnl
   5 dnl Configuration for sw-tools
   6 dnl
   7 dnl (c) 1999 EBI
   8 dnl
   9
  10 dnl ----- Licensing notice --------------------------------------------------
  11 dnl
  12 dnl This file is part of sw-tools.
  13 dnl
  14 dnl sw-tools is free software; you can redistribute it and/or modify
  15 dnl it under the terms of the GNU General Public License as published by
  16 dnl the Free Software Foundation; either version 2 of the License, or
  17 dnl (at your option) any later version.
  18 dnl
  19 dnl sw-tools is distributed in the hope that it will be useful,
  20 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 dnl GNU General Public License for more details.
  23 dnl
  24 dnl You should have received a copy of the GNU General Public License
  25 dnl along with sw-tools; if not, write to the Free Software Foundation,
  26 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  27
  28 dnl ----- Revision history --------------------------------------------------
  29 dnl
  30 dnl $Log: configure.in,v $
  31 dnl Revision 1.2  1999/06/04 13:56:36  mdw
  32 dnl Bump version.
  33 dnl
  34 dnl Revision 1.1.1.1  1999/06/02 16:53:33  mdw
  35 dnl Initial import.
  36 dnl
  37
  38 dnl --- Boring boilerplate ---
  39
  40 AC_INIT(src/sw.c)
  41 AM_INIT_AUTOMAKE(sw-tools, 1.0.0pre4)
  42 AM_CONFIG_HEADER(config.h)
  43
  44 dnl --- Work out the architecture name ---
  45
  46 AC_MSG_CHECKING([architecture name])
  47 arch=`$srcdir/sw.in --archname`
  48 AC_MSG_RESULT($arch)
  49 AC_DEFINE_UNQUOTED(ARCH, "$arch")
  50 AC_SUBST(arch)
  51
  52 dnl --- Set up the C compiler ---
  53
  54 AC_PROG_CC
  55 mdw_GCC_FLAGS
  56
  57 dnl --- Check for <unistd.h> ---
  58
  59 AC_CHECK_HEADERS(unistd.h)
  60
  61 dnl --- Find an appropriate remote shell program ---
  62
  63 AC_ARG_WITH(rsh,
  64 [  --with-rsh=PROGRAM      use PROGRAM to start remote shells],
  65 [RSH=$withval])
  66 AC_PATH_PROGS(RSH, $RSH remsh rsh ssh, rsh)
  67 AC_DEFINE_UNQUOTED(RSH, "$RSH")
  68
  69 dnl --- Find out whether I have `strsignal' or `sys_siglist' ---
  70
  71 AC_CHECK_FUNCS(strsignal _sys_siglist, break)
  72
  73 dnl --- Decide whether to declare `environ' ---
  74
  75 AC_CACHE_CHECK([for declaration of \`environ'], sw_cv_environ,
  76 [AC_EGREP_CPP(environ,
  77 [#include <sys/types.h>
  78 #if HAVE_UNISTD_H
  79 #include <unistd.h>
  80 #endif
  81 #if STDC_HEADERS
  82 #include <stdlib.h>
  83 #include <stddef.h>
  84 #endif], [sw_cv_environ=yes], [sw_cv_environ=no])])
  85 if test $sw_cv_environ = yes; then
  86   AC_DEFINE(DECL_ENVIRON)
  87 fi
  88
  89 dnl --- Find a curses library ---
  90 dnl
  91 dnl Try to find one which knows how to resize a terminal.
  92
  93 mdw_CHECK_MANYLIBS(newwin, ncurses curses, AC_DEFINE(HAVE_CURSES))
  94
  95 if test $mdw_cv_lib_newwin != no; then
  96 AC_CHECK_HEADERS([ncurses.h ncurses/ncurses.h curses.h], [break])
  97
  98 if test "$ac_cv_header_ncurses_h" = "no" &&
  99    test "$ac_cv_header_ncurses_ncurses_h" = "no" &&
 100    test "$ac_cv_header_curses_h" = "no"; then
 101      AC_MSG_WARN([couldn't find a \`curses' header.  Assuming \`curses.h'.])
 102      AC_DEFINE(HAVE_CURSES_H)
 103 fi
 104
 105 AC_CHECK_FUNCS(wresize)
 106 fi
 107
 108
 109 dnl --- Other handy libraries ---
 110
 111 mdw_CHECK_MANYLIBS(socketpair, socket)
 112
 113 dnl --- Various standard types ---
 114
 115 AC_TYPE_PID_T
 116 AC_TYPE_SIZE_T
 117 AC_TYPE_UID_T
 118
 119 AC_CACHE_CHECK(for ssize_t, sw_cv_ssize_t,
 120 [AC_EGREP_CPP(ssize_t,
 121 [#include <sys/types.h>
 122 #if HAVE_UNISTD_H
 123 #include <unistd.h>
 124 #endif
 125 #if STDC_HEADERS
 126 #include <stdlib.h>
 127 #include <stddef.h>
 128 #endif],
 129 [sw_cv_ssize_t=yes], [sw_cv_ssize_t=no])])
 130
 131 if test $sw_cv_ssize_t = no; then
 132   AC_DEFINE(ssize_t, int)
 133 fi
 134
 135 dnl --- Write in some useful paths ---
 136
 137 mdw_prefix=$prefix mdw_exec_prefix=$exec_prefix
 138 transform=`echo "$program_transform_name"|sed 's,\\\\\\\\,\\\\,g; s,\\$\\$,$,g'`
 139 test "$prefix" = "NONE" && prefix=$ac_default_prefix
 140 test "$exec_prefix" = "NONE" && exec_prefix=$prefix
 141 SW=`echo sw|sed "$transform"`
 142 AC_SUBST(SW)
 143 AC_DEFINE_UNQUOTED(PREFIX, "$mdw_prefix")
 144 AC_DEFINE_UNQUOTED(BINDIR, "`eval echo $bindir`")
 145 AC_DEFINE_UNQUOTED(DATADIR, "`eval echo $datadir`")
 146 AC_DEFINE_UNQUOTED(SW, "$SW")
 147 prefix=$mdw_prefix exec_prefix=$mdw_exec_prefix
 148
 149 dnl --- Output the configuration ---
 150
 151 AC_CONFIG_SUBDIRS(mLib)
 152 AC_OUTPUT(Makefile src/Makefile sw)
 153
 154 dnl ----- That's all, folks -------------------------------------------------