mdw@git.distorted.org.uk Git - sw-tools/blob - configure.in

   1 dnl -*-fundamental-*-
   2 dnl
   3 dnl $Id: configure.in,v 1.4 1999/06/24 15:53:11 mdw Exp $
   4 dnl
   5 dnl Configuration for sw-tools
   6 dnl
   7 dnl (c) 1999 EBI
   8 dnl
   9
  10 dnl ----- Licensing notice --------------------------------------------------
  11 dnl
  12 dnl This file is part of sw-tools.
  13 dnl
  14 dnl sw-tools is free software; you can redistribute it and/or modify
  15 dnl it under the terms of the GNU General Public License as published by
  16 dnl the Free Software Foundation; either version 2 of the License, or
  17 dnl (at your option) any later version.
  18 dnl
  19 dnl sw-tools is distributed in the hope that it will be useful,
  20 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 dnl GNU General Public License for more details.
  23 dnl
  24 dnl You should have received a copy of the GNU General Public License
  25 dnl along with sw-tools; if not, write to the Free Software Foundation,
  26 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  27
  28 dnl ----- Revision history --------------------------------------------------
  29 dnl
  30 dnl $Log: configure.in,v $
  31 dnl Revision 1.4  1999/06/24 15:53:11  mdw
  32 dnl Bump the version number again.
  33 dnl
  34 dnl Revision 1.3  1999/06/18 18:59:39  mdw
  35 dnl Preliminary work for Perl scripts.
  36 dnl
  37 dnl Revision 1.2  1999/06/04 13:56:36  mdw
  38 dnl Bump version.
  39 dnl
  40 dnl Revision 1.1.1.1  1999/06/02 16:53:33  mdw
  41 dnl Initial import.
  42 dnl
  43
  44 dnl --- Boring boilerplate ---
  45
  46 AC_INIT(src/sw.c)
  47 AM_INIT_AUTOMAKE(sw-tools, 1.0.0pre6)
  48 AM_CONFIG_HEADER(config.h)
  49
  50 dnl --- Work out the architecture name ---
  51
  52 AC_MSG_CHECKING([architecture name])
  53 arch=`$srcdir/sw.in --archname`
  54 AC_MSG_RESULT($arch)
  55 AC_DEFINE_UNQUOTED(ARCH, "$arch")
  56 AC_SUBST(arch)
  57
  58 dnl --- Set up the C compiler ---
  59
  60 AC_PROG_CC
  61 mdw_GCC_FLAGS
  62
  63 dnl --- Find a Perl ---
  64
  65 mdw_PROG_PERL(5.003)
  66 mdw_CHECK_PERL(5.003)
  67
  68 dnl --- Check for <unistd.h> ---
  69
  70 AC_CHECK_HEADERS(unistd.h)
  71
  72 dnl --- Find an appropriate remote shell program ---
  73
  74 AC_ARG_WITH(rsh,
  75 [  --with-rsh=PROGRAM      use PROGRAM to start remote shells],
  76 [RSH=$withval])
  77 AC_PATH_PROGS(RSH, $RSH remsh rsh ssh, rsh)
  78 AC_DEFINE_UNQUOTED(RSH, "$RSH")
  79
  80 dnl --- Find out whether I have `strsignal' or `sys_siglist' ---
  81
  82 AC_CHECK_FUNCS(strsignal _sys_siglist, break)
  83
  84 dnl --- Decide whether to declare `environ' ---
  85
  86 AC_CACHE_CHECK([for declaration of \`environ'], sw_cv_environ,
  87 [AC_EGREP_CPP(environ,
  88 [#include <sys/types.h>
  89 #if HAVE_UNISTD_H
  90 #include <unistd.h>
  91 #endif
  92 #if STDC_HEADERS
  93 #include <stdlib.h>
  94 #include <stddef.h>
  95 #endif], [sw_cv_environ=yes], [sw_cv_environ=no])])
  96 if test $sw_cv_environ = yes; then
  97   AC_DEFINE(DECL_ENVIRON)
  98 fi
  99
 100 dnl --- Find a curses library ---
 101 dnl
 102 dnl Try to find one which knows how to resize a terminal.
 103
 104 mdw_CHECK_MANYLIBS(newwin, ncurses curses, AC_DEFINE(HAVE_CURSES))
 105
 106 if test $mdw_cv_lib_newwin != no; then
 107 AC_CHECK_HEADERS([ncurses.h ncurses/ncurses.h curses.h], [break])
 108
 109 if test "$ac_cv_header_ncurses_h" = "no" &&
 110    test "$ac_cv_header_ncurses_ncurses_h" = "no" &&
 111    test "$ac_cv_header_curses_h" = "no"; then
 112      AC_MSG_WARN([couldn't find a \`curses' header.  Assuming \`curses.h'.])
 113      AC_DEFINE(HAVE_CURSES_H)
 114 fi
 115
 116 AC_CHECK_FUNCS(wresize)
 117 fi
 118
 119
 120 dnl --- Other handy libraries ---
 121
 122 mdw_CHECK_MANYLIBS(socketpair, socket)
 123
 124 dnl --- Various standard types ---
 125
 126 AC_TYPE_PID_T
 127 AC_TYPE_SIZE_T
 128 AC_TYPE_UID_T
 129
 130 AC_CACHE_CHECK(for ssize_t, sw_cv_ssize_t,
 131 [AC_EGREP_CPP(ssize_t,
 132 [#include <sys/types.h>
 133 #if HAVE_UNISTD_H
 134 #include <unistd.h>
 135 #endif
 136 #if STDC_HEADERS
 137 #include <stdlib.h>
 138 #include <stddef.h>
 139 #endif],
 140 [sw_cv_ssize_t=yes], [sw_cv_ssize_t=no])])
 141
 142 if test $sw_cv_ssize_t = no; then
 143   AC_DEFINE(ssize_t, int)
 144 fi
 145
 146 dnl --- Write in some useful paths ---
 147
 148 mdw_prefix=$prefix mdw_exec_prefix=$exec_prefix
 149 transform=`echo "$program_transform_name"|sed 's,\\\\\\\\,\\\\,g; s,\\$\\$,$,g'`
 150 test "$prefix" = "NONE" && prefix=$ac_default_prefix
 151 test "$exec_prefix" = "NONE" && exec_prefix=$prefix
 152 SW=`echo sw|sed "$transform"`
 153 AC_SUBST(SW)
 154 AC_DEFINE_UNQUOTED(PREFIX, "$mdw_prefix")
 155 AC_DEFINE_UNQUOTED(BINDIR, "`eval echo $bindir`")
 156 AC_DEFINE_UNQUOTED(DATADIR, "`eval echo $datadir`")
 157 AC_DEFINE_UNQUOTED(SW, "$SW")
 158 pkgdatadir="`eval echo $datadir/sw`"
 159 AC_SUBST(pkgdatadir)
 160 prefix=$mdw_prefix exec_prefix=$mdw_exec_prefix
 161
 162 dnl --- Output the configuration ---
 163
 164 AC_CONFIG_SUBDIRS(mLib)
 165 AC_OUTPUT(Makefile src/Makefile sw sw-share)
 166
 167 dnl ----- That's all, folks -------------------------------------------------