mdw@git.distorted.org.uk Git - sod/blob - src/output-impl.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Output scheduling protocol implementation
   4 ;;;
   5 ;;; (c) 2009 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (cl:in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Sequencing machinery.
  30
  31 (defmethod print-object ((item sequencer-item) stream)
  32   (print-unreadable-object (item stream :type t)
  33     (prin1 (sequencer-item-name item) stream)))
  34
  35 (defmethod shared-initialize ((sequencer sequencer) slot-names
  36                               &key (constraints nil constraintsp))
  37   (call-next-method)
  38   (when constraintsp
  39     (setf (slot-value sequencer 'constraints)
  40           (mapcar (lambda (constraint)
  41                     (mapcar (lambda (name)
  42                               (ensure-sequencer-item sequencer name))
  43                             constraint))
  44                   (reverse constraints))))
  45   sequencer)
  46
  47 (defmethod ensure-sequencer-item ((sequencer sequencer) name)
  48   (with-slots (table) sequencer
  49     (or (gethash name table)
  50         (setf (gethash name table) (make-sequencer-item name)))))
  51
  52 (defmethod add-sequencer-constraint ((sequencer sequencer) (constraint list))
  53   (let ((converted-constraint
  54          (mapcar (lambda (name)
  55                    (ensure-sequencer-item sequencer name))
  56                  constraint)))
  57     (with-slots (constraints) sequencer
  58       (pushnew converted-constraint constraints))))
  59
  60 (defmethod add-sequencer-item-function ((sequencer sequencer) name function)
  61   (let ((item (ensure-sequencer-item sequencer name)))
  62     (pushnew function (sequencer-item-functions item))))
  63
  64 (defmethod invoke-sequencer-items ((sequencer sequencer) &rest arguments)
  65   #+debug
  66   (format *debug-io* "~@<;; ~@;Constraints: ~_~
  67                       ~<~@{~<  * ~;~@{~S~^, ~:_~}~:>~:@_~}~:>~:>"
  68           (mapcar (lambda (constraint)
  69                     (mapcar #'sequencer-item-name constraint))
  70                   (sequencer-constraints sequencer)))
  71   (let ((seen (make-hash-table)))
  72     (dolist (item (merge-lists (reverse (sequencer-constraints sequencer))))
  73       (setf (gethash item seen) t)
  74       (dolist (function (reverse (sequencer-item-functions item)))
  75         (apply function arguments)))
  76     (maphash (lambda (name item)
  77                (unless (gethash item seen)
  78                  (warn "Unused output item ~S" name)))
  79              (sequencer-table sequencer))))
  80
  81 ;;;----- That's all, folks --------------------------------------------------