mdw@git.distorted.org.uk Git - sod/blob - src/class-output.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Output for classes
   4 ;;;
   5 ;;; (c) 2009 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensble Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (cl:in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Classes.
  30
  31 (defmethod hook-output progn ((class sod-class) (reason (eql :h)) sequencer)
  32
  33   ;; Main output sequencing.
  34   (sequence-output (stream sequencer)
  35
  36     :constraint
  37     ((:classes :start)
  38      (class :banner)
  39      (class :islots :start) (class :islots :slots) (class :islots :end)
  40      (class :vtmsgs :start) (class :vtmsgs :end)
  41      (class :vtables :start) (class :vtables :end)
  42      (class :vtable-externs) (class :vtable-externs-after)
  43      (class :methods :start) (class :methods) (class :methods :end)
  44      (class :ichains :start) (class :ichains :end)
  45      (class :ilayout :start) (class :ilayout :slots) (class :ilayout :end)
  46      (class :conversions)
  47      (class :object)
  48      (:classes :end))
  49
  50     (:typedefs
  51      (format stream "typedef struct ~A ~A;~%"
  52              (ichain-struct-tag class (sod-class-chain-head class)) class))
  53
  54     ((class :banner)
  55      (banner (format nil "Class ~A" class) stream))
  56     ((class :vtable-externs-after)
  57      (terpri stream))
  58
  59     ((class :vtable-externs)
  60      (format stream "/* Vtable structures. */~%"))
  61
  62     ((class :object)
  63      (let ((metaclass (sod-class-metaclass class))
  64            (metaroot (find-root-metaclass class)))
  65        (format stream "/* The class object. */~@
  66                        extern const struct ~A ~A__classobj;~@
  67                        #define ~:*~A__class (&~:*~A__classobj.~A.~A)~2%"
  68                (ilayout-struct-tag metaclass) class
  69                (sod-class-nickname (sod-class-chain-head metaroot))
  70                (sod-class-nickname metaroot)))))
  71
  72   ;; Maybe generate an islots structure.
  73   (when (sod-class-slots class)
  74     (dolist (slot (sod-class-slots class))
  75       (hook-output slot 'islots sequencer))
  76     (sequence-output (stream sequencer)
  77       ((class :islots :start)
  78        (format stream "/* Instance slots. */~@
  79                        struct ~A {~%"
  80                (islots-struct-tag class)))
  81       ((class :islots :end)
  82        (format stream "};~2%"))))
  83
  84   ;; Declare the direct methods.
  85   (when (sod-class-methods class)
  86     (sequence-output (stream sequencer)
  87       ((class :methods :start)
  88        (format stream "/* Direct methods. */~%"))
  89       ((class :methods :end)
  90        (terpri stream))))
  91
  92   ;; Provide upcast macros which do the right thing.
  93   (when (sod-class-direct-superclasses class)
  94     (sequence-output (stream sequencer)
  95       ((class :conversions)
  96        (let ((chain-head (sod-class-chain-head class)))
  97          (format stream "/* Conversion macros. */~%")
  98          (dolist (super (cdr (sod-class-precedence-list class)))
  99            (let ((super-head (sod-class-chain-head super)))
 100              (format stream "#define ~:@(~A__CONV_~A~)(p) ((~A *)~
 101                                      ~:[SOD_XCHAIN(~A, (p))~;(p)~])~%"
 102                      class (sod-class-nickname super) super
 103                      (eq chain-head super-head)
 104                      (sod-class-nickname super-head))))
 105          (terpri stream)))))
 106
 107   ;; Generate vtmsgs structure for all superclasses.
 108   (hook-output (car (sod-class-vtables class))
 109                     'vtmsgs
 110                     sequencer))
 111
 112 (defmethod hook-output progn ((class sod-class) reason sequencer)
 113   (with-slots (ilayout vtables methods effective-methods) class
 114     (hook-output ilayout reason sequencer)
 115     (dolist (method methods) (hook-output method reason sequencer))
 116     (dolist (method effective-methods) (hook-output method reason sequencer))
 117     (dolist (vtable vtables) (hook-output vtable reason sequencer))))
 118
 119 ;;;--------------------------------------------------------------------------
 120 ;;; Instance structure.
 121
 122 (defmethod hook-output progn ((slot sod-slot)
 123                               (reason (eql 'islots))
 124                               sequencer)
 125   (sequence-output (stream sequencer)
 126     (((sod-slot-class slot) :islots :slots)
 127      (pprint-logical-block (stream nil :prefix "  " :suffix ";")
 128        (pprint-c-type (sod-slot-type slot) stream (sod-slot-name slot)))
 129      (terpri stream))))
 130
 131 (defmethod hook-output progn ((ilayout ilayout) reason sequencer)
 132   (with-slots (ichains) ilayout
 133     (dolist (ichain ichains) (hook-output ichain reason sequencer))))
 134
 135 (defmethod hook-output progn ((ichain ichain) reason sequencer)
 136   (dolist (item (ichain-body ichain))
 137     (hook-output item reason sequencer)))
 138
 139 (defmethod hook-output progn ((ilayout ilayout) (reason (eql :h)) sequencer)
 140   (with-slots (class ichains) ilayout
 141     (sequence-output (stream sequencer)
 142       ((class :ilayout :start)
 143        (format stream "/* Instance layout. */~@
 144                        struct ~A {~%"
 145                (ilayout-struct-tag class)))
 146       ((class :ilayout :end)
 147        (format stream "};~2%")))
 148     (dolist (ichain ichains)
 149       (hook-output ichain 'ilayout sequencer))))
 150
 151 (defmethod hook-output progn ((ichain ichain) (reason (eql :h)) sequencer)
 152   (with-slots (class chain-head chain-tail) ichain
 153     (when (eq class chain-tail)
 154       (sequence-output (stream sequencer)
 155         :constraint ((class :ichains :start)
 156                      (class :ichain chain-head :start)
 157                      (class :ichain chain-head :slots)
 158                      (class :ichain chain-head :end)
 159                      (class :ichains :end))
 160         ((class :ichain chain-head :start)
 161          (format stream "/* Instance chain structure. */~@
 162                          struct ~A {~%"
 163                  (ichain-struct-tag chain-tail chain-head)))
 164         ((class :ichain chain-head :end)
 165          (format stream "};~2%")
 166          (format stream "/* Union of equivalent superclass chains. */~@
 167                          union ~A {~@
 168                          ~:{  struct ~A ~A;~%~}~
 169                          };~2%"
 170                  (ichain-union-tag chain-tail chain-head)
 171
 172                  ;; Make sure the most specific class is first: only the
 173                  ;; first element of a union can be statically initialized in
 174                  ;; C90.
 175                  (mapcar (lambda (super)
 176                            (list (ichain-struct-tag super chain-head)
 177                                  (sod-class-nickname super)))
 178                          (sod-class-chain chain-tail))))))))
 179
 180 (defmethod hook-output progn ((ichain ichain)
 181                               (reason (eql 'ilayout))
 182                               sequencer)
 183   (with-slots (class chain-head chain-tail) ichain
 184     (sequence-output (stream sequencer)
 185       ((class :ilayout :slots)
 186        (format stream "  union ~A ~A;~%"
 187                (ichain-union-tag chain-tail chain-head)
 188                (sod-class-nickname chain-head))))))
 189
 190 (defmethod hook-output progn ((vtptr vtable-pointer)
 191                               (reason (eql :h))
 192                               sequencer)
 193   (with-slots (class chain-head chain-tail) vtptr
 194     (sequence-output (stream sequencer)
 195       ((class :ichain chain-head :slots)
 196        (format stream "  const struct ~A *_vt;~%"
 197                (vtable-struct-tag chain-tail chain-head))))))
 198
 199 (defmethod hook-output progn ((islots islots) reason sequencer)
 200   (dolist (slot (islots-slots islots))
 201     (hook-output slot reason sequencer)))
 202
 203 (defmethod hook-output progn ((islots islots) (reason (eql :h)) sequencer)
 204   (with-slots (class subclass slots) islots
 205     (sequence-output (stream sequencer)
 206       ((subclass :ichain (sod-class-chain-head class) :slots)
 207        (format stream "  struct ~A ~A;~%"
 208                (islots-struct-tag class)
 209                (sod-class-nickname class))))))
 210
 211 ;;;--------------------------------------------------------------------------
 212 ;;; Vtable structure.
 213
 214 (defmethod hook-output progn ((vtable vtable) reason sequencer)
 215   (with-slots (body) vtable
 216     (dolist (item body) (hook-output item reason sequencer))))
 217
 218 (defmethod hook-output progn ((method sod-method)
 219                               (reason (eql :h))
 220                               sequencer)
 221   (with-slots (class) method
 222     (sequence-output (stream sequencer)
 223       ((class :methods)
 224        (let ((type (sod-method-function-type method)))
 225          (princ "extern " stream)
 226          (pprint-c-type (commentify-function-type type) stream
 227                         (sod-method-function-name method))
 228          (format stream ";~%"))))))
 229
 230 (defmethod hook-output progn ((vtable vtable) (reason (eql :h)) sequencer)
 231   (with-slots (class chain-head chain-tail) vtable
 232     (when (eq class chain-tail)
 233       (sequence-output (stream sequencer)
 234         :constraint ((class :vtables :start)
 235                      (class :vtable chain-head :start)
 236                      (class :vtable chain-head :slots)
 237                      (class :vtable chain-head :end)
 238                      (class :vtables :end))
 239         ((class :vtable chain-head :start)
 240          (format stream "/* Vtable structure. */~@
 241                          struct ~A {~%"
 242                  (vtable-struct-tag chain-tail chain-head)))
 243         ((class :vtable chain-head :end)
 244          (format stream "};~2%"))))
 245     (sequence-output (stream sequencer)
 246       ((class :vtable-externs)
 247        (format stream "~@<extern const struct ~A ~2I~_~A__vtable_~A;~:>~%"
 248                (vtable-struct-tag chain-tail chain-head)
 249                class (sod-class-nickname chain-head))))))
 250
 251 (defmethod hook-output progn ((vtmsgs vtmsgs) (reason (eql :h)) sequencer)
 252   (with-slots (class subclass chain-head chain-tail) vtmsgs
 253     (sequence-output (stream sequencer)
 254       ((subclass :vtable chain-head :slots)
 255        (format stream "  struct ~A ~A;~%"
 256                (vtmsgs-struct-tag subclass class)
 257                (sod-class-nickname class))))))
 258
 259 (defmethod hook-output progn ((vtmsgs vtmsgs)
 260                               (reason (eql 'vtmsgs))
 261                               sequencer)
 262   (when (vtmsgs-entries vtmsgs)
 263     (with-slots (class subclass) vtmsgs
 264       (sequence-output (stream sequencer)
 265         :constraint ((subclass :vtmsgs :start)
 266                      (subclass :vtmsgs class :start)
 267                      (subclass :vtmsgs class :slots)
 268                      (subclass :vtmsgs class :end)
 269                      (subclass :vtmsgs :end))
 270         ((subclass :vtmsgs class :start)
 271          (format stream "/* Messages protocol from class ~A */~@
 272                          struct ~A {~%"
 273                  class
 274                  (vtmsgs-struct-tag subclass class)))
 275         ((subclass :vtmsgs class :end)
 276          (format stream "};~2%"))))))
 277
 278 (defmethod hook-output progn ((vtmsgs vtmsgs) reason sequencer)
 279   (with-slots (entries) vtmsgs
 280     (dolist (entry entries) (hook-output entry reason sequencer))))
 281
 282 (defmethod hook-output progn ((entry method-entry)
 283                               (reason (eql 'vtmsgs))
 284                               sequencer)
 285   (let* ((method (method-entry-effective-method entry))
 286          (message (effective-method-message method))
 287          (class (effective-method-class method))
 288          (function-type (method-entry-function-type entry))
 289          (commented-type (commentify-function-type function-type))
 290          (pointer-type (make-pointer-type commented-type)))
 291     (sequence-output (stream sequencer)
 292       ((class :vtmsgs (sod-message-class message) :slots)
 293        (pprint-logical-block (stream nil :prefix "  " :suffix ";")
 294          (pprint-c-type pointer-type stream (sod-message-name message)))
 295        (terpri stream)))))
 296
 297 (defmethod hook-output progn ((cptr class-pointer)
 298                               (reason (eql :h))
 299                               sequencer)
 300   (with-slots (class chain-head metaclass meta-chain-head) cptr
 301     (sequence-output (stream sequencer)
 302       ((class :vtable chain-head :slots)
 303        (format stream "  const ~A *~:[_class~;~:*_cls_~A~];~%"
 304                metaclass
 305                (and (sod-class-direct-superclasses meta-chain-head)
 306                     (sod-class-nickname meta-chain-head)))))))
 307
 308 (defmethod hook-output progn ((boff base-offset) (reason (eql :h)) sequencer)
 309   (with-slots (class chain-head) boff
 310     (sequence-output (stream sequencer)
 311       ((class :vtable chain-head :slots)
 312        (write-line "  size_t _base;" stream)))))
 313
 314 (defmethod hook-output progn ((choff chain-offset)
 315                               (reason (eql :h))
 316                               sequencer)
 317   (with-slots (class chain-head target-head) choff
 318     (sequence-output (stream sequencer)
 319       ((class :vtable chain-head :slots)
 320        (format stream "  ptrdiff_t _off_~A;~%"
 321                (sod-class-nickname target-head))))))
 322
 323 ;;;--------------------------------------------------------------------------
 324 ;;; Implementation output.
 325
 326 (defvar *instance-class*)
 327
 328 (defmethod hook-output progn ((class sod-class) (reason (eql :c)) sequencer)
 329   (sequence-output (stream sequencer)
 330
 331     :constraint
 332     ((:classes :start)
 333      (class :banner)
 334      (class :direct-methods :start) (class :direct-methods :end)
 335      (class :effective-methods)
 336      (class :vtables :start) (class :vtables :end)
 337      (class :object :prepare) (class :object :start) (class :object :end)
 338      (:classes :end))
 339
 340     ((class :banner)
 341      (banner (format nil "Class ~A" class) stream))
 342
 343     ((class :object :start)
 344      (format stream "~
 345 /* The class object. */
 346 const struct ~A ~A__classobj = {~%"
 347              (ilayout-struct-tag (sod-class-metaclass class))
 348              class))
 349     ((class :object :end)
 350      (format stream "};~2%")))
 351
 352   (let ((*instance-class* class))
 353     (hook-output (sod-class-ilayout (sod-class-metaclass class))
 354                       'class
 355                       sequencer)))
 356
 357 ;;;--------------------------------------------------------------------------
 358 ;;; Direct and effective methods.
 359
 360 (defmethod hook-output progn ((method delegating-direct-method)
 361                               (reason (eql :c))
 362                               sequencer)
 363   (with-slots (class body) method
 364     (unless body
 365       (return-from hook-output))
 366     (sequence-output (stream sequencer)
 367       ((class :direct-method method :start)
 368        (format stream "#define CALL_NEXT_METHOD (next_method(~{~A~^, ~}))~%"
 369                (mapcar #'argument-name
 370                        (c-function-arguments (sod-method-next-method-type
 371                                               method)))))
 372       ((class :direct-method method :end)
 373        (format stream "#undef CALL_NEXT_METHOD~%")))))
 374
 375 (defmethod hook-output progn ((method sod-method)
 376                               (reason (eql :c))
 377                               sequencer)
 378   (with-slots (class body) method
 379     (unless body
 380       (return-from hook-output))
 381     (sequence-output (stream sequencer)
 382       :constraint ((class :direct-methods :start)
 383                    (class :direct-method method :start)
 384                    (class :direct-method method :body)
 385                    (class :direct-method method :end)
 386                    (class :direct-methods :end))
 387       ((class :direct-method method :body)
 388        (pprint-c-type (sod-method-function-type method)
 389                       stream
 390                       (sod-method-function-name method))
 391        (format stream "~&{~%")
 392        (write body :stream stream :pretty nil :escape nil)
 393        (format stream "~&}~%"))
 394       ((class :direct-method method :end)
 395        (terpri stream)))))
 396
 397 (defmethod hook-output progn ((method basic-effective-method)
 398                               (reason (eql :c))
 399                               sequencer)
 400   (with-slots (class functions) method
 401     (sequence-output (stream sequencer)
 402       ((class :effective-methods)
 403        (dolist (func functions)
 404          (write func :stream stream :escape nil :circle nil))))))
 405
 406 ;;;--------------------------------------------------------------------------
 407 ;;; Vtables.
 408
 409 (defmethod hook-output progn ((vtable vtable) (reason (eql :c)) sequencer)
 410   (with-slots (class chain-head chain-tail) vtable
 411     (sequence-output (stream sequencer)
 412       :constraint ((class :vtables :start)
 413                    (class :vtable chain-head :start)
 414                    (class :vtable chain-head :end)
 415                    (class :vtables :end))
 416       ((class :vtable chain-head :start)
 417        (format stream "/* Vtable for ~A chain. */~@
 418                        const struct ~A ~A = {~%"
 419                chain-head
 420                (vtable-struct-tag chain-tail chain-head)
 421                (vtable-name class chain-head)))
 422       ((class :vtable chain-head :end)
 423        (format stream "};~2%")))))
 424
 425 (defmethod hook-output progn ((cptr class-pointer)
 426                               (reason (eql :c))
 427                               sequencer)
 428   (with-slots (class chain-head metaclass meta-chain-head) cptr
 429     (sequence-output (stream sequencer)
 430       :constraint ((class :vtable chain-head :start)
 431                    (class :vtable chain-head :class-pointer metaclass)
 432                    (class :vtable chain-head :end))
 433       ((class :vtable chain-head :class-pointer metaclass)
 434        (format stream "  /* ~21@A = */ &~A__classobj.~A.~A,~%"
 435                (if (sod-class-direct-superclasses meta-chain-head)
 436                    (format nil "_cls_~A"
 437                            (sod-class-nickname meta-chain-head))
 438                    "_class")
 439                (sod-class-metaclass class)
 440                (sod-class-nickname meta-chain-head)
 441                (sod-class-nickname metaclass))))))
 442
 443 (defmethod hook-output progn ((boff base-offset) (reason (eql :c)) sequencer)
 444   (with-slots (class chain-head) boff
 445     (sequence-output (stream sequencer)
 446       :constraint ((class :vtable chain-head :start)
 447                    (class :vtable chain-head :base-offset)
 448                    (class :vtable chain-head :end))
 449       ((class :vtable chain-head :base-offset)
 450        (format stream "  /* ~21@A = */ offsetof(struct ~A, ~A),~%"
 451                "_base"
 452                (ilayout-struct-tag class)
 453                (sod-class-nickname chain-head))))))
 454
 455 (defmethod hook-output progn ((choff chain-offset)
 456                               (reason (eql :c))
 457                               sequencer)
 458   (with-slots (class chain-head target-head) choff
 459     (sequence-output (stream sequencer)
 460       :constraint ((class :vtable chain-head :start)
 461                    (class :vtable chain-head :chain-offset target-head)
 462                    (class :vtable chain-head :end))
 463       ((class :vtable chain-head :chain-offset target-head)
 464        (format stream "  /* ~21@A = */ SOD_OFFSETDIFF(struct ~A, ~A, ~A),~%"
 465                (format nil "_off_~A" (sod-class-nickname target-head))
 466                (ilayout-struct-tag class)
 467                (sod-class-nickname chain-head)
 468                (sod-class-nickname target-head))))))
 469
 470 (defmethod hook-output progn ((vtmsgs vtmsgs) (reason (eql :c)) sequencer)
 471   (with-slots (class subclass chain-head) vtmsgs
 472     (sequence-output (stream sequencer)
 473       :constraint ((subclass :vtable chain-head :start)
 474                    (subclass :vtable chain-head :vtmsgs class :start)
 475                    (subclass :vtable chain-head :vtmsgs class :slots)
 476                    (subclass :vtable chain-head :vtmsgs class :end)
 477                    (subclass :vtable chain-head :end))
 478       ((subclass :vtable chain-head :vtmsgs class :start)
 479        (format stream "  { /* Method entries for ~A messages. */~%"
 480                class))
 481       ((subclass :vtable chain-head :vtmsgs class :end)
 482        (format stream "  },~%")))))
 483
 484 (defmethod hook-output progn ((entry method-entry)
 485                               (reason (eql :c))
 486                               sequencer)
 487   (with-slots (method chain-head chain-tail) entry
 488     (let* ((message (effective-method-message method))
 489            (class (effective-method-class method))
 490            (super (sod-message-class message)))
 491       (sequence-output (stream sequencer)
 492         ((class :vtable chain-head :vtmsgs super :slots)
 493          (format stream "    /* ~19@A = */ ~A,~%"
 494                  (sod-message-name message)
 495                  (method-entry-function-name method chain-head)))))))
 496
 497 ;;;--------------------------------------------------------------------------
 498 ;;; Filling in the class object.
 499
 500 (defmethod hook-output progn ((ichain ichain)
 501                               (reason (eql 'class))
 502                               sequencer)
 503   (with-slots (class chain-head) ichain
 504     (sequence-output (stream sequencer)
 505       :constraint ((*instance-class* :object :start)
 506                    (*instance-class* :object chain-head :ichain :start)
 507                    (*instance-class* :object chain-head :ichain :end)
 508                    (*instance-class* :object :end))
 509       ((*instance-class* :object chain-head :ichain :start)
 510        (format stream "  { { /* ~A ichain */~%"
 511                (sod-class-nickname chain-head)))
 512       ((*instance-class* :object chain-head :ichain :end)
 513        (format stream "  } },~%")))))
 514
 515 (defmethod hook-output progn ((islots islots)
 516                               (reason (eql 'class))
 517                               sequencer)
 518   (with-slots (class) islots
 519     (let ((chain-head (sod-class-chain-head class)))
 520       (sequence-output (stream sequencer)
 521         :constraint ((*instance-class* :object chain-head :ichain :start)
 522                      (*instance-class* :object class :slots :start)
 523                      (*instance-class* :object class :slots)
 524                      (*instance-class* :object class :slots :end)
 525                      (*instance-class* :object chain-head :ichain :end))
 526         ((*instance-class* :object class :slots :start)
 527          (format stream "      { /* Class ~A */~%" class))
 528         ((*instance-class* :object class :slots :end)
 529          (format stream "      },~%"))))))
 530
 531 (defmethod hook-output progn ((vtptr vtable-pointer)
 532                               (reason (eql 'class))
 533                               sequencer)
 534   (with-slots (class chain-head chain-tail) vtptr
 535     (sequence-output (stream sequencer)
 536       :constraint ((*instance-class* :object chain-head :ichain :start)
 537                    (*instance-class* :object chain-head :vtable)
 538                    (*instance-class* :object chain-head :ichain :end))
 539       ((*instance-class* :object chain-head :vtable)
 540        (format stream "      &~A__vtable_~A,~%"
 541                class (sod-class-nickname chain-head))))))
 542
 543 (defgeneric find-class-initializer (slot class)
 544   (:method ((slot effective-slot) (class sod-class))
 545     (let ((dslot (effective-slot-direct-slot slot)))
 546       (or (some (lambda (super)
 547                   (find dslot (sod-class-class-initializers super)
 548                         :test #'sod-initializer-slot))
 549                 (sod-class-precedence-list class))
 550           (effective-slot-initializer slot)))))
 551
 552 (defgeneric output-class-initializer (slot instance stream)
 553   (:method ((slot sod-class-effective-slot) (instance sod-class) stream)
 554     (let ((func (effective-slot-initializer-function slot))
 555           (direct-slot (effective-slot-direct-slot slot)))
 556       (if func
 557           (format stream "        /* ~15@A = */ ~A,~%"
 558                   (sod-slot-name direct-slot)
 559                   (funcall func instance))
 560           (call-next-method))))
 561   (:method ((slot effective-slot) (instance sod-class) stream)
 562     (let ((init (find-class-initializer slot instance))
 563           (direct-slot (effective-slot-direct-slot slot)))
 564       (ecase (sod-initializer-value-kind init)
 565         (:simple (format stream "        /* ~15@A = */ ~A,~%"
 566                          (sod-slot-name direct-slot)
 567                          (sod-initializer-value-form init)))
 568         (:compound (format stream "        /* ~15@A = */ ~@<{ ~;~A~; },~:>~%"
 569                            (sod-slot-name direct-slot)
 570                            (sod-initializer-value-form init)))))))
 571
 572 (defmethod hook-output progn ((slot sod-class-effective-slot)
 573                               (reason (eql 'class))
 574                               sequencer)
 575   (let ((instance *instance-class*)
 576         (func (effective-slot-prepare-function slot)))
 577     (when func
 578       (sequence-output (stream sequencer)
 579         ((instance :object :prepare)
 580          (funcall func instance stream))))))
 581
 582 (defmethod hook-output progn ((slot effective-slot)
 583                               (reason (eql 'class))
 584                               sequencer)
 585   (with-slots (class (dslot slot)) slot
 586     (let ((instance *instance-class*)
 587           (super (sod-slot-class dslot)))
 588       (sequence-output (stream sequencer)
 589         ((instance :object super :slots)
 590          (output-class-initializer slot instance stream))))))
 591
 592 ;;;----- That's all, folks --------------------------------------------------