mdw@git.distorted.org.uk Git - sod/blob - src/module-output.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Output for modules
   4 ;;;
   5 ;;; (c) 2013 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (cl:in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Utilities.
  30
  31 (export 'banner)
  32 (defun banner (title output &key (blank-line-p t))
  33   "Write a banner to the OUTPUT stream, starting a new section called TITLE.
  34
  35    If BLANK-LINE-P is false, then leave a blank line after the banner.  (This
  36    is useful for a final banner at the end of a file.)"
  37   (format output "~&/*----- ~A ~A*/~%"
  38           title
  39           (make-string (- 77 2 5 1 (length title) 1 2)
  40                        :initial-element #\-))
  41   (when blank-line-p
  42     (terpri output)))
  43
  44 (export 'guard-name)
  45 (defun guard-name (filename)
  46   "Return a sensible inclusion guard name for FILENAME."
  47   (with-output-to-string (guard)
  48     (let* ((pathname (make-pathname :name (pathname-name filename)
  49                                     :type (pathname-type filename)))
  50            (name (namestring pathname))
  51            (uscore t))
  52       (dotimes (i (length name))
  53         (let ((ch (char name i)))
  54           (cond ((alphanumericp ch)
  55                  (write-char (char-upcase ch) guard)
  56                  (setf uscore nil))
  57                 ((not uscore)
  58                  (write-char #\_ guard)
  59                  (setf uscore t))))))))
  60
  61 (defun guess-output-file (module type)
  62   "Guess the filename to use for a file TYPE, generated from MODULE.
  63
  64    Here, TYPE is a filetype string.  The result is returned as a pathname."
  65   (merge-pathnames (make-pathname :type type :case :common)
  66                    (module-name module)))
  67
  68 (defvar *done-one-off-output* nil
  69   "A list of tokens for things which should appear at most once in output.")
  70
  71 (export 'one-off-output)
  72 (defun one-off-output (token sequencer item-name function)
  73   "Arrange to output a thing at most once.
  74
  75    If there has been no previous call to `one-off-output' with the given
  76    TOKEN during this output run, then arrange to call FUNCTION when the item
  77    called ITEM-NAME is traversed.  Otherwise do nothing."
  78   (unless (member token *done-one-off-output*)
  79     (push token *done-one-off-output*)
  80     (add-sequencer-item-function sequencer item-name function)))
  81
  82 ;;;--------------------------------------------------------------------------
  83 ;;; Main output interface.
  84
  85 (export 'output-module)
  86 (defun output-module (module reason stream)
  87   "Write the MODULE to STREAM, giving the output machinery the REASON.
  88
  89    This is the top-level interface for producing output."
  90   (let ((*print-right-margin* 77)
  91         (*done-one-off-output* nil)
  92         (sequencer (make-instance 'sequencer))
  93         (stream (if (typep stream 'position-aware-output-stream)
  94                     stream
  95                     (make-instance 'position-aware-output-stream
  96                                    :stream stream
  97                                    :file (stream-pathname stream)))))
  98     (with-module-environment (module)
  99       (hook-output module reason sequencer)
 100       (invoke-sequencer-items sequencer stream))))
 101
 102 ;;;--------------------------------------------------------------------------
 103 ;;; Output implementation.
 104
 105 (defmethod hook-output :after ((module module) reason sequencer)
 106
 107   ;; Ask the module's items to sequence themselves.
 108   (dolist (item (module-items module))
 109     (hook-output item reason sequencer)))
 110
 111 (defmethod hook-output ((frag code-fragment-item) reason sequencer)
 112
 113   ;; Output fragments when their reasons are called up.
 114   (when (eq reason (code-fragment-reason frag))
 115     (dolist (constraint (code-fragment-constraints frag))
 116       (add-sequencer-constraint sequencer constraint))
 117     (awhen (code-fragment-name frag)
 118       (add-sequencer-item-function sequencer it
 119                                    (lambda (stream)
 120                                      (write (code-fragment frag)
 121                                             :stream stream
 122                                             :pretty nil
 123                                             :escape nil))))))
 124
 125 (defmethod hook-output ((module module) (reason (eql :h)) sequencer)
 126   (sequence-output (stream sequencer)
 127
 128     :constraint
 129     (:prologue
 130      (:guard :start)
 131      (:typedefs :start) :typedefs (:typedefs :end)
 132      (:includes :start) :includes :early-decls (:includes :end)
 133      (:early-user :start) :early-user (:early-user :end)
 134      (:classes :start) (:classes :end)
 135      (:user :start) :user (:user :end)
 136      (:guard :end)
 137      :epilogue)
 138
 139     (:prologue
 140      (format stream "~
 141 /* -*- mode: c; indent-tabs-mode: nil -*-
 142  *
 143  * Header file generated by SOD for ~A
 144  */~2%"
 145              (namestring (module-name module))))
 146
 147     ((:guard :start)
 148      (format stream "~
 149 #ifndef ~A
 150 #define ~:*~A
 151
 152 #ifdef __cplusplus
 153   extern \"C\" {
 154 #endif~2%"
 155              (or (get-property (module-pset module) :guard :id)
 156                  (guard-name (or (stream-pathname stream)
 157                                  (guess-output-file module "H"))))))
 158     ((:guard :end)
 159      (banner "That's all, folks" stream)
 160      (format stream "~
 161 #ifdef __cplusplus
 162   }
 163 #endif
 164
 165 #endif~%"))
 166
 167     ((:typedefs :start)
 168      (banner "Forward type declarations" stream))
 169     ((:typedefs :end)
 170      (terpri stream))
 171
 172     ((:includes :start)
 173      (banner "External header files" stream))
 174     ((:includes :end)
 175      (terpri stream))))
 176
 177 (defmethod hook-output ((module module) (reason (eql :c)) sequencer)
 178   (sequence-output (stream sequencer)
 179
 180     :constraint
 181     (:prologue
 182      (:includes :start) :includes (:includes :end)
 183      (:early-user :start) :early-user (:early-user :end)
 184      (:classes :start) (:classes :end)
 185      (:user :start) :user (:user :end)
 186      :epilogue)
 187
 188     (:prologue
 189      (format stream "~
 190 /* -*- mode: c; indent-tabs-mode: nil -*-
 191  *
 192  * Implementation file generated by SOD for ~A
 193  */~2%"
 194              (namestring (module-name module))))
 195
 196     (:epilogue
 197      (banner "That's all, folks" stream :blank-line-p nil))
 198
 199     ((:includes :start)
 200      (banner "External header files" stream))
 201     ((:includes :end)
 202      (terpri stream))))
 203
 204 ;;;--------------------------------------------------------------------------
 205 ;;; Output types.
 206
 207 (defvar *output-types* nil
 208   "List of known output types.")
 209
 210 (export 'declare-output-type)
 211 (defun declare-output-type (reason pathname)
 212   "Record that REASON is a valid user-level output type.
 213
 214    The output file name will be constructed by merging the module's pathname
 215    with PATHNAME."
 216   (pushnew reason *output-types*)
 217   (setf (get reason 'output-type) pathname))
 218
 219 (export 'output-type-pathname)
 220 (defun output-type-pathname (reason)
 221   "Return the PATHNAME template for the output type REASON.
 222
 223    Report an error if there is no such output type."
 224   (or (get reason 'output-type)
 225       (error "Unknown output type `~(~A~)'" reason)))
 226
 227 (export 'module-output-file)
 228 (defgeneric module-output-file (module output-type output-dir)
 229   (:documentation
 230    "Return a pathname to which the output should be written.
 231
 232    Specifically, if we're processing a MODULE for a particular OUTPUT-TYPE,
 233    and the user has requested that output be written to OUTPUT-DIR (a
 234    pathname), then return the pathname to which the output should be
 235    written.
 236
 237    The OUTPUT-TYPE can be an `reason' symbol or a raw pathname.  (Or
 238    something else, of course.)"))
 239
 240 (defmethod module-output-file
 241     ((module module) (output-type symbol) output-dir)
 242   (module-output-file module (output-type-pathname output-type) output-dir))
 243
 244 (defmethod module-output-file
 245     ((module module) (output-type pathname) output-dir)
 246   (reduce #'merge-pathnames
 247           (list output-dir output-type
 248                 (make-pathname :directory nil
 249                                :defaults (module-name module)))))
 250
 251 (export 'write-dependency-file)
 252 (defgeneric write-dependency-file (module reason output-dir)
 253   (:documentation
 254    "Write a dependency-tracking make(1) fragment.
 255
 256    Specifically, we've processed a MODULE for a particular REASON (a
 257    symbol), and the user has requested that output be written to OUTPUT-DIR
 258    (a pathname): determine a suitable output pathname and write a make(1)
 259    fragment explaining that the output file we've made depends on all of the
 260    files we had to read to load the module."))
 261
 262 (defmethod write-dependency-file ((module module) reason output-dir)
 263   (let* ((common-case
 264           ;; Bletch.  We want to derive the filetype from the one we're
 265           ;; given, but we need to determine the environment's preferred
 266           ;; filetype case to do that.  Make a pathname and inspect it to
 267           ;; find out how to do this.
 268
 269           (if (upper-case-p
 270                            (char (pathname-type (make-pathname
 271                                                  :type "TEST"
 272                                                  :case :common))
 273                                  0))
 274                           #'string-upcase
 275                           #'string-downcase))
 276
 277          (outpath (output-type-pathname reason))
 278          (deppath (make-pathname :type (concatenate 'string
 279                                                     (pathname-type outpath)
 280                                                     (funcall common-case
 281                                                              "-DEP"))
 282                                  :defaults outpath))
 283          (outfile (module-output-file module reason output-dir))
 284          (depfile (module-output-file module deppath output-dir)))
 285
 286     (with-open-file (dep depfile
 287                      :direction :output
 288                      :if-exists :supersede
 289                      :if-does-not-exist :create)
 290       (format dep "### -*-makefile-*-~%~
 291                    ~A:~{ \\~%   ~A~}~%"
 292               outfile
 293               (cons (module-name module)
 294                     (module-files module))))))
 295
 296 (define-clear-the-decks reset-output-types
 297   "Clear out the registered output types."
 298   (dolist (reason *output-types*) (remprop reason 'output-type))
 299   (setf *output-types* nil)
 300   (declare-output-type :c (make-pathname :type "C" :case :common))
 301   (declare-output-type :h (make-pathname :type "H" :case :common)))
 302
 303 ;;;----- That's all, folks --------------------------------------------------