src/builtin.lisp: Bind `me' around slot initializers, and define the order.

[sod] / src / module-parse.lisp

;;; -*-lisp-*-
;;;
;;; Top-level parser for module syntax
;;;
;;; (c) 2010 Straylight/Edgeware
;;;

;;;----- Licensing notice ---------------------------------------------------
;;;
;;; This file is part of the Sensible Object Design, an object system for C.
;;;
;;; SOD is free software; you can redistribute it and/or modify
;;; it under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 2 of the License, or
;;; (at your option) any later version.
;;;
;;; SOD is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with SOD; if not, write to the Free Software Foundation,
;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

(in-package #:sod)

;;;--------------------------------------------------------------------------
;;; Toplevel syntax.

;;; Type names.

(define-pluggable-parser module typename (scanner pset)
  ;; `typename' id ( `,' id )* `;'
  (declare (ignore pset))
  (with-parser-context (token-scanner-context :scanner scanner)
    (parse (and "typename"
                (skip-many (:min 1)
                  (seq ((id :id))
                    (if (gethash id *module-type-map*)
                        (cerror* "Type `~A' already defined" id)
                        (add-to-module *module*
                                       (make-instance 'type-item
                                                      :name id))))
                  #\,)
                #\;))))

;;; Fragments.

(define-pluggable-parser module code (scanner pset)
  ;; `code' id `:' item-name [constraints] `{' c-fragment `}'
  ;;
  ;; constrains ::= `[' constraint-list `]'
  ;; constraint ::= item-name+
  ;; item-name ::= id | `(' id+ `)'
  (declare (ignore pset))
  (with-parser-context (token-scanner-context :scanner scanner)
    (labels ((kw ()
               (parse (seq ((kw :id))
                        (intern (frob-identifier kw) 'keyword))))
             (item ()
               (parse (or (kw)
                          (seq (#\( (names (list (:min 1) (kw))) #\))
                            names)))))
      (parse (seq ("code"
                   (reason (kw))
                   #\:
                   (name (item))
                   (constraints (? (seq (#\[
                                         (constraints (list (:min 1)
                                                        (list (:min 1)
                                                          (item))
                                                        #\,))
                                         #\])
                                     constraints)))
                   (fragment (parse-delimited-fragment scanner #\{ #\})))
               (add-to-module *module*
                              (make-instance 'code-fragment-item
                                             :fragment fragment
                                             :constraints constraints
                                             :reason reason
                                             :name name)))))))

;;; External files.

(export 'read-module)
(defun read-module (pathname &key (truename nil truep) location)
  "Parse the file at PATHNAME as a module, returning it.

   This is the main entry point for parsing module files.  You may well know
   the file's TRUENAME already (e.g., because `probe-file' dropped it into
   your lap) so you can avoid repeating the search by providing it.

   The LOCATION is the thing which wanted the module imported -- usually a
   `file-location' object, though it might be anything other than `t' which
   can be printed in the event of circular imports."

  (setf pathname (merge-pathnames pathname
                                  (make-pathname :type "SOD" :case :common)))
  (unless truep (setf truename (truename pathname)))
  (define-module (pathname :location location :truename truename)
    (with-open-file (f-stream pathname :direction :input)
      (let* ((*readtable* (copy-readtable))
             (char-scanner (make-instance 'charbuf-scanner
                                          :stream f-stream))
             (scanner (make-instance 'sod-token-scanner
                                     :char-scanner char-scanner)))
        (with-default-error-location (scanner)
          (with-parser-context (token-scanner-context :scanner scanner)
            (parse (skip-many ()
                     (seq ((pset (parse-property-set scanner))
                           (nil (error ()
                                  (plug module scanner pset))))
                       (check-unused-properties pset))))))))))

(define-pluggable-parser module test (scanner pset)
  ;; `demo' string `;'
  (declare (ignore pset))
  (with-parser-context (token-scanner-context :scanner scanner)
    (parse (seq ("demo" (string :string) #\;)
             (format t ";; DEMO ~S~%" string)))))

(define-pluggable-parser module file (scanner pset)
  ;; `import' string `;'
  ;; `load' string `;'
  (declare (ignore pset))
  (flet ((common (name type what thunk)
           (find-file scanner
                      (merge-pathnames name
                                       (make-pathname :type type
                                                      :case :common))
                      what
                      thunk)))
    (with-parser-context (token-scanner-context :scanner scanner)
      (parse (or (seq ("import" (name :string) #\;)
                   (common name "SOD" "module"
                           (lambda (path true)
                             (handler-case
                                 (let ((module (read-module path
                                                            :truename true)))
                                   (when module
                                     (module-import module)
                                     (pushnew module
                                              (module-dependencies
                                               *module*))))
                               (file-error (error)
                                 (cerror* "Error reading module ~S: ~A"
                                          path error))))))
                 (seq ("load" (name :string) #\;)
                   (common name "LISP" "Lisp file"
                           (lambda (path true)
                             (handler-case
                                 (load true :verbose nil :print nil)
                               (error (error)
                                 (cerror* "Error loading Lisp file ~S: ~A"
                                          path error)))))))))))

;;; Setting properties.

(define-pluggable-parser module set (scanner pset)
  ;; `set' property-list `;'
  (with-parser-context (token-scanner-context :scanner scanner)
    (parse (and "set"
                (lisp (let ((module-pset (module-pset *module*)))
                        (when pset
                          (pset-map (lambda (prop)
                                      (add-property module-pset
                                                    (p-name prop)
                                                    (p-value prop)
                                                    :type (p-type prop)
                                                    :location (p-location prop))
                                      (setf (p-seenp prop) t))
                                    pset))
                        (parse (skip-many (:min 0)
                                 (error (:ignore-unconsumed t)
                                   (parse-property scanner module-pset)
                                   (skip-until (:keep-end t) #\, #\;))
                                 #\,))))
                #\;))))

;;; Lisp escape.

(define-pluggable-parser module lisp (scanner pset)
  ;; `lisp' s-expression `;'
  (declare (ignore pset))
  (with-parser-context (token-scanner-context :scanner scanner)
    (parse (seq ((sexp (if (and (eql (token-type scanner) :id)
                                (string= (token-value scanner) "lisp"))
                           (let* ((stream (make-scanner-stream scanner))
                                  (sexp (read stream t)))
                             (scanner-step scanner)
                             (values sexp t t))
                           (values '((:id "lisp")) nil nil)))
                 #\;)
             (eval sexp)))))

;;;--------------------------------------------------------------------------
;;; Class declarations.

(export 'class-item)

(defun parse-class-body (scanner pset name supers)
  ;; class-body ::= `{' class-item* `}'
  ;;
  ;; class-item ::= property-set raw-class-item
  (with-parser-context (token-scanner-context :scanner scanner)
    (make-class-type name)
    (let* ((class (make-sod-class name (mapcar #'find-sod-class supers)
                                  pset scanner))
           (nick (sod-class-nickname class)))

      (labels ((parse-maybe-dotted-declarator (base-type)
                 ;; Parse a declarator or dotted-declarator, i.e., one whose
                 ;; centre is
                 ;;
                 ;; maybe-dotted-identifier ::= [id `.'] id
                 ;;
                 ;; A plain identifier is returned as a string, as usual; a
                 ;; dotted identifier is returned as a cons cell of the two
                 ;; names.
                 (parse-declarator
                  scanner base-type
                  :keywordp t
                  :kernel (parser ()
                            (seq ((name-a :id)
                                  (name-b (? (seq (#\. (id :id)) id))))
                              (if name-b (cons name-a name-b)
                                  name-a)))))

               (parse-message-item (sub-pset type name)
                 ;; message-item ::=
                 ;;     declspec+ declarator -!- (method-body | `;')
                 ;;
                 ;; Don't allow a method-body here if the message takes a
                 ;; varargs list, because we don't have a name for the
                 ;; `va_list' parameter.
                 (let ((message (make-sod-message class name type
                                                  sub-pset scanner)))
                   (if (varargs-message-p message)
                       (parse #\;)
                       (parse (or #\; (parse-method-item sub-pset
                                                         type nick name))))))

               (parse-method-item (sub-pset type sub-nick name)
                 ;; method-item ::=
                 ;;     declspec+ dotted-declarator -!- method-body
                 ;;
                 ;; method-body ::= `{' c-fragment `}' | `extern' `;'
                 (parse (seq ((body (or (seq ("extern" #\;) nil)
                                        (parse-delimited-fragment
                                         scanner #\{ #\}))))
                          (make-sod-method class sub-nick name type
                                           body sub-pset scanner))))

               (parse-initializer ()
                 ;; initializer ::= `=' c-fragment
                 ;;
                 ;; Return a VALUE, ready for passing to a `sod-initializer'
                 ;; constructor.
                 (parse-delimited-fragment scanner #\= (list #\, #\;)
                                           :keep-end t))

               (parse-slot-item (sub-pset base-type type name)
                 ;; slot-item ::=
                 ;;     declspec+ declarator -!- [initializer]
                 ;;             [`,' init-declarator-list] `;'
                 ;;
                 ;; init-declarator-list ::=
                 ;;     declarator [initializer] [`,' init-declarator-list]
                 (parse (and (seq ((init (? (parse-initializer))))
                               (make-sod-slot class name type
                                              sub-pset scanner)
                               (when init
                                 (make-sod-instance-initializer
                                  class nick name init sub-pset scanner)))
                             (skip-many ()
                               (seq (#\,
                                     (ds (parse-declarator scanner
                                                           base-type))
                                     (init (? (parse-initializer))))
                                 (make-sod-slot class (cdr ds) (car ds)
                                                sub-pset scanner)
                                 (when init
                                   (make-sod-instance-initializer
                                    class nick (cdr ds) init
                                    sub-pset scanner))))
                             #\;)))

               (parse-initializer-item (sub-pset constructor)
                 ;; initializer-item ::=
                 ;;     [`class'] -!- slot-initializer-list `;'
                 ;;
                 ;; slot-initializer ::= id `.' id initializer
                 (parse (and (skip-many ()
                               (seq ((name-a :id) #\. (name-b :id)
                                     (init (parse-initializer)))
                                 (funcall constructor class
                                          name-a name-b init
                                          sub-pset scanner))
                               #\,)
                             #\;)))

               (class-item-dispatch (sub-pset base-type type name)
                 ;; Logically part of `parse-raw-class-item', but the
                 ;; indentation was getting crazy.  We're currently at
                 ;;
                 ;; raw-class-item ::=
                 ;;     declspec+ (declarator | dotted-declarator) -!- ...
                 ;;   | other-items
                 ;;
                 ;; If the declarator is dotted then this must be a method
                 ;; definition; otherwise it might be a message or slot.
                 (cond ((not (typep type 'c-function-type))
                        (when (consp name)
                          (cerror*-with-location
                           scanner
                           "Method declarations must have function type.")
                          (setf name (cdr name)))
                        (parse-slot-item sub-pset base-type type name))
                       ((consp name)
                        (parse-method-item sub-pset type
                                           (car name) (cdr name)))
                       (t
                        (parse-message-item sub-pset type name))))

               (parse-raw-class-item (sub-pset)
                 ;; raw-class-item ::=
                 ;;     message-item
                 ;;   | method-item
                 ;;   | slot-item
                 ;;   | initializer-item
                 ;;
                 ;; Most of the above begin with declspecs and a declarator
                 ;; (which might be dotted).  So we parse that here and
                 ;; dispatch based on what we find.
                 (parse (or (plug class-item scanner class sub-pset)
                            (peek
                             (seq ((ds (parse-c-type scanner))
                                   (dc (parse-maybe-dotted-declarator ds))
                                   (nil (class-item-dispatch sub-pset
                                                             ds
                                                             (car dc)
                                                             (cdr dc))))))
                            (and "class"
                                 (parse-initializer-item
                                  sub-pset
                                  #'make-sod-class-initializer))
                            (parse-initializer-item
                             sub-pset
                             #'make-sod-instance-initializer)))))

        (parse (seq (#\{
                     (nil (skip-many ()
                            (seq ((sub-pset (parse-property-set scanner))
                                  (nil (parse-raw-class-item sub-pset)))
                              (check-unused-properties sub-pset))))
                     (nil (error () #\})))
                 (finalize-sod-class class)
                 (add-to-module *module* class)))))))

(define-pluggable-parser module class (scanner pset)
  ;; `class' id [`:' id-list] class-body
  ;; `class' id `;'
  (with-parser-context (token-scanner-context :scanner scanner)
    (parse (seq ("class"
                 (name :id)
                 (nil (or (seq (#\;)
                            (make-class-type name))
                          (seq ((supers (? (seq (#\: (ids (list () :id #\,)))
                                             ids)))
                                (nil (parse-class-body
                                      scanner
                                      pset name supers)))))))))))

;;;----- That's all, folks --------------------------------------------------