src/pset-parse.lisp: Add a little vertical space and commentary.

[sod] / src / pset-parse.lisp

;;; -*-lisp-*-
;;;
;;; Parsing property sets
;;;
;;; (c) 2012 Straylight/Edgeware
;;;

;;;----- Licensing notice ---------------------------------------------------
;;;
;;; This file is part of the Sensible Object Design, an object system for C.
;;;
;;; SOD is free software; you can redistribute it and/or modify
;;; it under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 2 of the License, or
;;; (at your option) any later version.
;;;
;;; SOD is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with SOD; if not, write to the Free Software Foundation,
;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

(in-package #:sod)

;;;--------------------------------------------------------------------------
;;; The expression parser.

(defun parse-expression (scanner)
  "Parse and evaluate a simple expression.

   The result is a pair (TYPE . VALUE).  Currently, type types are `:id',
   `:int', `:string', `:char', `:fragment', `:type'.  If an error prevented a
   sane value from being produced, the type `:invalid' is returned.

   The syntax of expressions is rather limited at the moment, but more may be
   added later.

   expression: term | expression `+' term | expression `-' term
   term: factor | term `*' factor | term `/' factor
   factor: primary | `+' factor | `-' factor
   primary: int | id | string | `(' expression `)' | `{' fragment `}'
     | `<' declspec+ declarator[empty] `>' | `?' lisp-expression

   Only operators for dealing with integers are provided."

  ;; The expression parser works in two stages.  First, the parser proper
  ;; builds a thunk as its `value'.  If this is successful, then the thunk is
  ;; invoked to return a property type and value.  Primitive expressions
  ;; produce thunks which just return their values; operators combine their
  ;; argument thunks together, evaluating them (or not) on demand.

  (macrolet ((oplambda (&body body)
	       ;; Like `lambda', but (a) always produces a function with no
	       ;; arguments, and (b) captures the current location so that
	       ;; errors are attributed correctly.

	       (with-gensyms (floc)
		 `(let ((,floc (file-location scanner)))
		    (lambda ()
		      (with-default-error-location (,floc)
			,@body))))))

    (flet ((dispatch (name args &rest spec)
	     ;; Evaluate the ARGS to determine their types and values.  Find
	     ;; the first SPEC, of the form (RETTY OP ARGTY*), where the
	     ;; ARGTYs match the argument types, in order, and apply OP to
	     ;; the argument values, return this as a result of type RETTY.
	     ;; If no SPEC matches, then report an error.

	     (oplambda
	       (let ((args (mapcar (compose #'funcall #'cons) args)))
		 (aif (find-if (lambda (item)
				 (every (lambda (type arg)
					  (eql type (car arg)))
					(cddr item) args))
			       spec)
		      (values (car it) (apply (cadr it) (mapcar #'cdr args)))
		      (error "Type mismatch: operator `~A' applied to ~
			      types ~{~(~A~)~#[~; and ~;, ~]~}"
			     name (mapcar #'car args)))))))

      (with-parser-context (token-scanner-context :scanner scanner)
	(when-parse ()

	    ;; Parse the expression, producing a thunk.
	    (expr (:nestedp nestedp)

	      (lisp (case (token-type scanner)

		      ((:int :id :char :string)
		       ;; A simple literal.
		       (let ((type (token-type scanner))
			     (value (token-value scanner)))
			 (scanner-step scanner)
			 (values (lambda () (values type value)) t t)))

		      (#\?
		       ;; A Lisp s-expression.  Catch and report reader-
		       ;; errors (though the main parser will probably
		       ;; end up /very/ confused); delay evaluation for
		       ;; later.
		       (handler-case
			   (let* ((stream (make-scanner-stream scanner))
				  (sexp (read stream t)))
			     (scanner-step scanner)
			     (values (oplambda (decode-property (eval sexp)))
				     t t))
			 (error (cond)
			   (scanner-step scanner)
			   (cerror*-with-location scanner
						  "Lisp `read' error: ~A"
						  cond)
			   (values #'continue t t))))

		      (#\{
		       ;; A code fragment.
		       (let ((fragment (parse-delimited-fragment scanner
								 #\{ #\})))
			 (values (lambda () (values :fragment fragment))
				 t t)))

		      (#\<
		       ;; A C type.
		       (parse (seq (#\<
				    (ds (parse-c-type scanner))
				    (dc (parse-declarator
					 scanner ds
					 :kernel (lambda ()
						   (values nil t nil))
					 :abstractp t))
				    #\>)
				(values (lambda () (values :type (car dc)))
					t t))))

		      (t
		       ;; Anything else is an error.
		       (values (list :int :id :char :string #\? #\{ #\<)
			       nil nil))))

	      ;; Binary operators.
	      ((:op #\* binop "*" (x y 7)
		    (dispatch "*" (list x y) (list :int #'* :int :int)))
	       (:op #\/ binop "/" (x y 7)
		    (dispatch "/" (list x y)
			      (list :int
				    (lambda (x y)
				      (cond ((zerop y)
					     (cerror*
					      "Division by zero")
					     (cons :invalid nil))
					    (t
					     (floor x y))))
				    :int :int)))
	       (:op #\+ binop "+" (x y 5)
		    (dispatch "+" (list x y) (list :int #'+ :int :int)))
	       (:op #\- binop "-" (x y 5)
		    (dispatch "-" (list x y) (list :int #'- :int :int))))

	      ;; Prefix operators.
	      ((:op #\+ preop "+" (x 9)
		    (dispatch "+" (list x) (list :int #'+ :int)))
	       (:op #\- preop "-" (x 9)
		    (dispatch "-" (list x) (list :int #'- :int)))
	       (:op #\( lparen #\)))

	      ;; Postfix operators.
	      ((:op (when nestedp #\)) rparen #\))))

	  ;; Do the delayed evaluation.  Establish a restart so that we can
	  ;; continue if evaluation fails for some reason.  (The value thunk
	  ;; is expected to report the correct error locations, if it signals
	  ;; conditions.)
	  (restart-case (multiple-value-bind (type value) (funcall it)
			  (values (cons type value) t t))
	    (continue () (values (cons :invalid nil) t t))))))))

;;;--------------------------------------------------------------------------
;;; Parsing property sets.

(export 'parse-property)
(defun parse-property (scanner pset)
  "Parse a single property using the SCANNER; add it to the PSET."
  ;; property ::= id `=' expression
  (with-parser-context (token-scanner-context :scanner scanner)
    (parse (seq ((name :id) #\= (result (parse-expression scanner)))
	     (let ((type (car result))
		   (value (cdr result)))
	       (unless (eq type :invalid)
		 (add-property pset name value
			       :type type
			       :location scanner)))))))

(export 'parse-property-set)
(defun parse-property-set (scanner)
  "Parse an optional property set from the SCANNER and return it."
  ;; property-set ::= [`[' property-list `]']
  (with-parser-context (token-scanner-context :scanner scanner)
    (parse (? (seq (#\[
		    (pset (many (pset (make-property-set) pset)
			    (error ()
			      (parse-property scanner pset)
			      (skip-until () #\, #\]))
			    #\,))
		    #\])
		pset)))))

;;;----- That's all, folks --------------------------------------------------