src/parser/parser-expr-proto.lisp: Get `expr' to cache operators.

[sod] / src / pset-parse.lisp

;;; -*-lisp-*-
;;;
;;; Parsing property sets
;;;
;;; (c) 2012 Straylight/Edgeware
;;;

;;;----- Licensing notice ---------------------------------------------------
;;;
;;; This file is part of the Sensible Object Design, an object system for C.
;;;
;;; SOD is free software; you can redistribute it and/or modify
;;; it under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 2 of the License, or
;;; (at your option) any later version.
;;;
;;; SOD is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with SOD; if not, write to the Free Software Foundation,
;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

(in-package #:sod)

;;;--------------------------------------------------------------------------
;;; The expression parser.

(flet ((dispatch (name args &rest spec)
	 (acond ((find :invalid args :key #'car)
		 (cons :invalid nil))
		((find-if (lambda (item)
			    (every (lambda (type arg)
				     (eql type (car arg)))
				   (cddr item)
				   args))
			  spec)
		 (cons (car it) (apply (cadr it)
				       (mapcar #'cdr args))))
		(t
		 (cerror* "Type mismatch: operator `~A' applied to ~
			       types ~{~(~A~)~#[~; and ~;, ~]~}"
			  name
			  (mapcar #'car args))
		 (cons :invalid nil)))))

  (defun parse-expression (scanner)
    "Parse and evaluate a simple expression.

   The result is a pair (TYPE . VALUE).  Currently, type types are `:id',
   `:int', `:string', `:char', `:fragment', `:type'.  If an error prevented a
   sane value from being produced, the type `:invalid' is returned.

   The syntax of expressions is rather limited at the moment, but more may be
   added later.

   expression: term | expression `+' term | expression `-' term
   term: factor | term `*' factor | term `/' factor
   factor: primary | `+' factor | `-' factor
   primary: int | id | string | `(' expression `)' | `{' fragment `}'
     | `<' declspec+ declarator[empty] `>' | `?' lisp-expression

   Only operators for dealing with integers are provided."
    (with-parser-context (token-scanner-context :scanner scanner)
      (parse (expr (:nestedp nestedp)
	       (lisp (flet ((prop (type value)
			      (scanner-step scanner)
			      (values (cons type value) t t)))
		       (case (token-type scanner)
			 ((:int :id :char :string)
			  (prop (token-type scanner)
				(token-value scanner)))
			 (#\?
			  (let* ((stream (make-scanner-stream scanner))
				 (sexp (read stream t)))
			    (scanner-step scanner)
			    (multiple-value-bind (type value)
				(restart-case (decode-property (eval sexp))
				  (continue () (values :invalid nil)))
			      (values (cons type value) t t))))
			 (#\{
			  (values (cons :fragment
					(parse-delimited-fragment scanner
								  #\{ #\}))
					t t))
			 (#\<
			  (parse (seq (#\<
				       (ds (parse-c-type scanner))
				       (dc (parse-declarator
					    scanner ds
					    :kernel (lambda ()
						      (values nil t nil))
					    :abstractp t))
				       #\>)
				   (values (cons :type (car dc))
					   t t))))
			 (t
			  (values (list :int :id :char :string #\? #\{ #\<)
				  nil nil)))))

	       ((:op #\* binop "*" (x y 7)
		     (dispatch "*" (list x y) (list :int #'* :int :int)))
		(:op #\/ binop "/" (x y 7)
		     (dispatch "/" (list x y)
			       (list :int
				     (lambda (x y)
				       (cond ((zerop y)
					      (cerror*
					       "Division by zero")
					      (cons :invalid nil))
					     (t
					      (floor x y))))
				     :int :int)))
		(:op #\+ binop "+" (x y 5)
		     (dispatch "+" (list x y) (list :int #'+ :int :int)))
		(:op #\- binop "-" (x y 5)
		     (dispatch "-" (list x y) (list :int #'- :int :int))))

	       ((:op #\+ preop "+" (x 9)
		     (dispatch "+" (list x) (list :int #'+ :int)))
		(:op #\- preop "-" (x 9)
		     (dispatch "-" (list x) (list :int #'- :int)))
		(:op #\( lparen #\)))

	       ((:op (when nestedp #\)) rparen #\))))))))

;;;--------------------------------------------------------------------------
;;; Parsing property sets.

(export 'parse-property)
(defun parse-property (scanner pset)
  "Parse a single property using the SCANNER; add it to the PSET."
  ;; property ::= id `=' expression
  (with-parser-context (token-scanner-context :scanner scanner)
    (parse (seq ((name :id) #\= (result (parse-expression scanner)))
	     (let ((type (car result))
		   (value (cdr result)))
	       (unless (eq type :invalid)
		 (add-property pset name value
			       :type type
			       :location scanner)))))))

(export 'parse-property-set)
(defun parse-property-set (scanner)
  "Parse an optional property set from the SCANNER and return it."
  ;; property-set ::= [`[' property-list `]']
  (with-parser-context (token-scanner-context :scanner scanner)
    (parse (? (seq (#\[
		    (pset (many (pset (make-property-set) pset)
			    (error ()
			      (parse-property scanner pset)
			      (skip-until () #\, #\]))
			    #\,))
		    #\])
		pset)))))

;;;----- That's all, folks --------------------------------------------------