mdw@git.distorted.org.uk Git - sgt/putty/blob - unix/configure.ac

   1 # To compile this into a configure script, you need:
   2 # * Autoconf 2.50 or newer
   3 # * Gtk (for $prefix/share/aclocal/gtk.m4)
   4 # * Automake (for aclocal)
   5 # If you've got them, running "autoreconf" should work.
   6
   7 AC_INIT
   8 AC_CONFIG_FILES([Makefile])
   9 AC_CONFIG_HEADERS([uxconfig.h:uxconfig.in])
  10
  11 AC_PROG_INSTALL
  12 AC_PROG_CC
  13 if test "X$GCC" = Xyes; then
  14     CFLAGS="$CFLAGS -Wall -Werror"
  15 fi
  16
  17 AC_CHECK_HEADERS([sys/sockio.h],,,[ ])
  18 AC_CHECK_HEADERS([utmpx.h],,,[
  19 #include <sys/types.h>
  20 #include <utmp.h>])
  21
  22 AM_PATH_GTK([1.2.0], [all_targets="all-cli all-gtk"], [all_targets="all-cli"])
  23 AC_SUBST([all_targets])
  24
  25 AC_SEARCH_LIBS([socket], [xnet])
  26
  27 AC_CHECK_FUNCS([getaddrinfo ptsname setresuid strsignal])
  28
  29 AC_OUTPUT
  30
  31 AH_BOTTOM([
  32 /* Convert autoconf definitions to ones that PuTTY wants. */
  33
  34 #ifndef HAVE_GETADDRINFO
  35 # define NO_IPV6
  36 #endif
  37 #ifndef HAVE_SETRESUID
  38 # define HAVE_NO_SETRESUID
  39 #endif
  40 #ifndef HAVE_STRSIGNAL
  41 # define HAVE_NO_STRSIGNAL
  42 #endif
  43 #ifndef HAVE_UTMPX_H
  44 # define OMIT_UTMP
  45 #endif
  46 #ifndef HAVE_PTSNAME
  47 # define BSD_PTYS
  48 #endif
  49 ])