mdw@git.distorted.org.uk Git - sgt/putty/blob - windows/putty.iss

   1 ; -*- no -*-
   2 ; $Id$
   3 ;
   4 ; -- Inno Setup installer script for PuTTY and its related tools.
   5 ;
   6 ; TODO for future releases:
   7 ;
   8 ;  - It might be nice to have an option to add PSCP, Plink and PSFTP to
   9 ;    the PATH. See wish `installer-addpath'.
  10 ;
  11 ;  - Maybe a "custom" installation might be useful? Hassle with
  12 ;    UninstallDisplayIcon, though.
  13
  14 [Setup]
  15 AppName=PuTTY
  16 AppVerName=PuTTY version 0.59
  17 VersionInfoTextVersion=Release 0.59
  18 AppVersion=0.59
  19 VersionInfoVersion=0.59.0.0
  20 AppPublisher=Simon Tatham
  21 AppPublisherURL=http://www.chiark.greenend.org.uk/~sgtatham/putty/
  22 AppReadmeFile={app}\README.txt
  23 DefaultDirName={pf}\PuTTY
  24 DefaultGroupName=PuTTY
  25 SetupIconFile=installer.ico
  26 UninstallDisplayIcon={app}\putty.exe
  27 ChangesAssociations=yes
  28 ;ChangesEnvironment=yes -- when PATH munging is sorted (probably)
  29 Compression=zip/9
  30 AllowNoIcons=yes
  31
  32 [Files]
  33 ; We flag all files with "restartreplace" et al primarily for the benefit
  34 ; of unattended un/installations/upgrades, when the user is running one
  35 ; of the apps at a time. Without it, the operation will fail noisily in
  36 ; this situation.
  37 ; This does mean that the user will be prompted to restart their machine
  38 ; if any of the files _were_ open during installation (or, if /VERYSILENT
  39 ; is used, the machine will be restarted automatically!). The /NORESTART
  40 ; flag avoids this.
  41 ; It might be nicer to have a "no worries, replace the file next time you
  42 ; reboot" option, but the developers have no interest in adding one.
  43 ; NB: apparently, using long (non-8.3) filenames with restartreplace is a
  44 ; bad idea. (Not that we do.)
  45 Source: "putty.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  46 Source: "pageant.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  47 Source: "puttygen.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  48 Source: "pscp.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  49 Source: "psftp.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  50 Source: "plink.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  51 Source: "website.url"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  52 Source: "..\doc\putty.chm"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  53 Source: "..\doc\putty.hlp"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  54 Source: "..\doc\putty.cnt"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  55 Source: "..\LICENCE"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  56 Source: "README.txt"; DestDir: "{app}"; Flags: isreadme restartreplace uninsrestartdelete
  57
  58 [Icons]
  59 Name: "{group}\PuTTY"; Filename: "{app}\putty.exe"
  60 ; We have to fall back from the .chm to the older .hlp file on some Windows
  61 ; versions.
  62 Name: "{group}\PuTTY Manual"; Filename: "{app}\putty.chm"; MinVersion: 4.1,5.0
  63 Name: "{group}\PuTTY Manual"; Filename: "{app}\putty.hlp"; OnlyBelowVersion: 4.1,5.0
  64 Name: "{group}\PuTTY Web Site"; Filename: "{app}\website.url"
  65 Name: "{group}\PSFTP"; Filename: "{app}\psftp.exe"
  66 Name: "{group}\PuTTYgen"; Filename: "{app}\puttygen.exe"
  67 Name: "{group}\Pageant"; Filename: "{app}\pageant.exe"
  68 Name: "{commondesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon\common
  69 Name: "{userdesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon\user
  70 ; Putting this in {commonappdata} doesn't seem to work, on 98SE at least.
  71 Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\PuTTY"; Filename: "{app}\putty.exe"; Tasks: quicklaunchicon
  72
  73 [Tasks]
  74 Name: desktopicon; Description: "Create a &desktop icon for PuTTY"; GroupDescription: "Additional icons:"; Flags: unchecked
  75 Name: desktopicon\common; Description: "For all users"; GroupDescription: "Additional icons:"; Flags: exclusive unchecked
  76 Name: desktopicon\user; Description: "For the current user only"; GroupDescription: "Additional icons:"; Flags: exclusive unchecked
  77 Name: quicklaunchicon; Description: "Create a &Quick Launch icon for PuTTY (current user only)"; GroupDescription: "Additional icons:"; Flags: unchecked
  78 Name: associate; Description: "&Associate .PPK files (PuTTY Private Key) with Pageant and PuTTYgen"; GroupDescription: "Other tasks:"
  79
  80 [Registry]
  81 Root: HKCR; Subkey: ".ppk"; ValueType: string; ValueName: ""; ValueData: "PuTTYPrivateKey"; Flags: uninsdeletevalue; Tasks: associate
  82 Root: HKCR; Subkey: "PuTTYPrivateKey"; ValueType: string; ValueName: ""; ValueData: "PuTTY Private Key File"; Flags: uninsdeletekey; Tasks: associate
  83 Root: HKCR; Subkey: "PuTTYPrivateKey\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\pageant.exe,0"; Tasks: associate
  84 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\pageant.exe"" ""%1"""; Tasks: associate
  85 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit"; ValueType: string; ValueName: ""; ValueData: "&Edit"; Tasks: associate
  86 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit\command"; ValueType: string; ValueName: ""; ValueData: """{app}\puttygen.exe"" ""%1"""; Tasks: associate
  87 ; Add to PATH on NT-class OS?
  88
  89 [UninstallRun]
  90 ; -cleanup-during-uninstall is an undocumented option that tailors the
  91 ; message displayed.
  92 ; XXX: it would be nice if this task weren't run if a silent uninstall is
  93 ;      requested, but "skipifsilent" is disallowed.
  94 Filename: "{app}\putty.exe"; Parameters: "-cleanup-during-uninstall"; RunOnceId: "PuTTYCleanup"; StatusMsg: "Cleaning up saved sessions etc (optional)..."