mdw@git.distorted.org.uk Git - sgt/putty/blob - windows/putty.iss

   1 ; -*- no -*-
   2 ; $Id$
   3 ;
   4 ; -- Inno Setup installer script for PuTTY and its related tools.
   5 ;
   6 ; TODO for future releases:
   7 ;
   8 ;  - It might be nice to have an option to add PSCP, Plink and PSFTP to
   9 ;    the PATH. See wish `installer-addpath'.
  10 ;
  11 ;  - Maybe a "custom" installation might be useful? Hassle with
  12 ;    UninstallDisplayIcon, though.
  13
  14 [Setup]
  15 AppName=PuTTY
  16 AppVerName=PuTTY version 0.58
  17 VersionInfoTextVersion=Release 0.58
  18 AppVersion=0.58
  19 VersionInfoVersion=0.58.0.0
  20 AppPublisher=Simon Tatham
  21 AppPublisherURL=http://www.chiark.greenend.org.uk/~sgtatham/putty/
  22 AppReadmeFile={app}\README.txt
  23 DefaultDirName={pf}\PuTTY
  24 DefaultGroupName=PuTTY
  25 UninstallDisplayIcon={app}\putty.exe
  26 ChangesAssociations=yes
  27 ;ChangesEnvironment=yes -- when PATH munging is sorted (probably)
  28 Compression=zip/9
  29 AllowNoIcons=yes
  30
  31 [Files]
  32 ; We flag all files with "restartreplace" et al primarily for the benefit
  33 ; of unattended un/installations/upgrades, when the user is running one
  34 ; of the apps at a time. Without it, the operation will fail noisily in
  35 ; this situation.
  36 ; This does mean that the user will be prompted to restart their machine
  37 ; if any of the files _were_ open during installation (or, if /VERYSILENT
  38 ; is used, the machine will be restarted automatically!). The /NORESTART
  39 ; flag avoids this.
  40 ; It might be nicer to have a "no worries, replace the file next time you
  41 ; reboot" option, but the developers have no interest in adding one.
  42 ; NB: apparently, using long (non-8.3) filenames with restartreplace is a
  43 ; bad idea. (Not that we do.)
  44 Source: "putty.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  45 Source: "pageant.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  46 Source: "puttygen.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  47 Source: "pscp.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  48 Source: "psftp.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  49 Source: "plink.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  50 Source: "website.url"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  51 Source: "..\doc\putty.chm"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  52 Source: "..\doc\putty.hlp"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  53 Source: "..\doc\putty.cnt"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  54 Source: "..\LICENCE"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  55 Source: "..\README.txt"; DestDir: "{app}"; Flags: isreadme restartreplace uninsrestartdelete
  56
  57 [Icons]
  58 Name: "{group}\PuTTY"; Filename: "{app}\putty.exe"
  59 ; We have to fall back from the .chm to the older .hlp file on some Windows
  60 ; versions.
  61 Name: "{group}\PuTTY Manual"; Filename: "{app}\putty.chm"; MinVersion: 4.1,5.0
  62 Name: "{group}\PuTTY Manual"; Filename: "{app}\putty.hlp"; OnlyBelowVersion: 4.1,5.0
  63 Name: "{group}\PuTTY Web Site"; Filename: "{app}\website.url"
  64 Name: "{group}\PSFTP"; Filename: "{app}\psftp.exe"
  65 Name: "{group}\PuTTYgen"; Filename: "{app}\puttygen.exe"
  66 Name: "{group}\Pageant"; Filename: "{app}\pageant.exe"
  67 Name: "{commondesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon\common
  68 Name: "{userdesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon\user
  69 ; Putting this in {commonappdata} doesn't seem to work, on 98SE at least.
  70 Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\PuTTY"; Filename: "{app}\putty.exe"; Tasks: quicklaunchicon
  71
  72 [Tasks]
  73 Name: desktopicon; Description: "Create a &desktop icon for PuTTY"; GroupDescription: "Additional icons:"; Flags: unchecked
  74 Name: desktopicon\common; Description: "For all users"; GroupDescription: "Additional icons:"; Flags: exclusive unchecked
  75 Name: desktopicon\user; Description: "For the current user only"; GroupDescription: "Additional icons:"; Flags: exclusive unchecked
  76 Name: quicklaunchicon; Description: "Create a &Quick Launch icon for PuTTY (current user only)"; GroupDescription: "Additional icons:"; Flags: unchecked
  77 Name: associate; Description: "&Associate .PPK files (PuTTY Private Key) with Pageant and PuTTYgen"; GroupDescription: "Other tasks:"
  78
  79 [Registry]
  80 Root: HKCR; Subkey: ".ppk"; ValueType: string; ValueName: ""; ValueData: "PuTTYPrivateKey"; Flags: uninsdeletevalue; Tasks: associate
  81 Root: HKCR; Subkey: "PuTTYPrivateKey"; ValueType: string; ValueName: ""; ValueData: "PuTTY Private Key File"; Flags: uninsdeletekey; Tasks: associate
  82 Root: HKCR; Subkey: "PuTTYPrivateKey\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\pageant.exe,0"; Tasks: associate
  83 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\pageant.exe"" ""%1"""; Tasks: associate
  84 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit"; ValueType: string; ValueName: ""; ValueData: "&Edit"; Tasks: associate
  85 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit\command"; ValueType: string; ValueName: ""; ValueData: """{app}\puttygen.exe"" ""%1"""; Tasks: associate
  86 ; Add to PATH on NT-class OS?
  87
  88 [UninstallRun]
  89 ; -cleanup-during-uninstall is an undocumented option that tailors the
  90 ; message displayed.
  91 ; XXX: it would be nice if this task weren't run if a silent uninstall is
  92 ;      requested, but "skipifsilent" is disallowed.
  93 Filename: "{app}\putty.exe"; Parameters: "-cleanup-during-uninstall"; RunOnceId: "PuTTYCleanup"; StatusMsg: "Cleaning up saved sessions etc (optional)..."