dot/gnus.el, dot/gnus-local.el.distorted: Gnus Cloud silliness.

[profile] / dot / lisp-init.lisp

;;; -*-lisp-*-

(cl:defpackage #:mdw-hacks
  (:use #:cl))
(cl:defparameter mdw-hacks::*previous-package* cl:*package*)
(cl:in-package #:mdw-hacks)

;; Shut up.
(setf *load-verbose* nil
      *compile-verbose* nil)

#+cmu
(setf ext:*gc-verbose* nil
      ext:*require-verbose* nil)

#+ecl
(let ((old-output *standard-output*)
      (old-prompt si:*tpl-prompt-hook*))
  ;; There doesn't seem to be a good way to do this, so we do it the bad
  ;; way.  Since the herald is printed to `*standard-outout*', we set (not
  ;; bind!) that to a bit bucket, and then arrange to restore it just before
  ;; the first REPL prompt is written.
  ;;
  ;; One more awful part is that, having intercepted the prompt hook, I need
  ;; to restore and invoke the old version, and there isn't a clean way to do
  ;; this.
  (when (<= (ext:argc) 1)
    (setf *standard-output* (make-broadcast-stream)
          si:*tpl-prompt-hook* (lambda ()
                                 (setf *standard-output* old-output
                                       si:*tpl-prompt-hook* old-prompt)
                                 (si::tpl-prompt)))))

#+ccl
(setf ccl::*inhibit-greeting* t)

#+abcl
(setf ext:*warn-on-redefinition* nil)

;; Obtain ASDF from somewhere.
(require "asdf")

;; Get CMU CL and CCL to quit on EOF.
#+cmu
(setf ext:*batch-mode* t)
#+ccl
(setf ccl:*quit-on-eof* t)

;; Tell SBCL where to find its source source.
#+sbcl
(let ((srcdir #p"/usr/share/sbcl-source/"))
  (when (probe-file srcdir)
    (sb-ext:set-sbcl-source-location srcdir)))

;; Get SBCL to shut up about package variance.  This is a standard result of
;; my approach to symbol exports, and I don't care.
#+sbcl
(progn
  (unless (fboundp 'real-note-package-variance)
    (setf (symbol-function 'real-note-package-variance)
            (symbol-function 'sb-impl::note-package-variance)))
  (handler-bind ((sb-ext:package-lock-violation #'continue)
                 (sb-kernel:redefinition-warning #'muffle-warning))
    (defun sb-impl::note-package-variance
        (&rest args &key package &allow-other-keys)
      (let ((ignore (getf sb-ext:*on-package-variance* :ignore)))
        (unless (or (eq ignore t)
                    (and (listp ignore)
                         (member (package-name package) ignore)))
          (apply #'real-note-package-variance args)))))
  (setf sb-ext:*on-package-variance* '(:ignore t)))

;; Tell some Lisps about my home directory.  CMU CL already has a search list
;; which does the same job, and CCL sets up a logical-pathname host.
#+(and unix (or sbcl clisp ecl abcl))
(let* ((homestring (or #+sbcl (sb-ext:posix-getenv "HOME")
                       #+(or clisp ecl abcl) (ext:getenv "HOME")
                       #+abcl (java:jstatic "getProperty"
                                            "java.lang.System"
                                            "user.home")
                       "/home/mdw"))
       (home (pathname (concatenate 'string homestring "/"))))
  (setf (logical-pathname-translations "HOME")
          `(("HOME:**;*.*.*" ,(merge-pathnames "**/*.*" home nil)))))
(when (#.(car '(#+clisp ext:probe-directory
                probe-file))
         #p"/usr/share/common-lisp/")
  (setf (logical-pathname-translations "CL")
          '(("CL:SOURCE;**;*.*.*" #p"/usr/share/common-lisp/source/**/*.*")
            ("CL:SYSTEMS;**;*.*.*" #p"/usr/share/common-lisp/systems/**/*.*"))))

;; Various fixings.
#+clisp
(setf custom:*parse-namestring-ansi* t)

;; CLisp history.
#+(and clisp readline)
(progn
  (export '(*history-file* *history-size*))
  (defvar *history-file* (format nil "~A/.clisp-history" (ext:getenv "HOME"))
    "File to preserve the REPL history.")
  (defvar *history-size* 1000)
  (unless (and (probe-file *history-file*) nil)
    (let (old-umask stream)
      ;; Ugh.  There's no proper open(2) veneer.  Play with umask(2) to avoid
      ;; a window in which an adversary can open the file.
      (unwind-protect
           (setf old-umask (os:umask #o077)
                 stream (open *history-file*
                              :direction :output
                              :if-exists :overwrite
                              :if-does-not-exist :create))
        (when stream (close stream))
        (when old-umask (os:umask old-umask)))))
  (readline:read-history *history-file*)
  (if *history-size* (readline:stifle-history *history-size*)
      (readline:unstifle-history))
  (push (lambda () (readline:write-history *history-file*))
        custom:*fini-hooks*))

;; Don't choke on shebang lines.  This isn't here so that we can run Lisp
;; scripts like proper Unix programs: `cl-launch' or `runlisp' do that.  It's
;; here so that we can `load' a script into a running Lisp without it choking
;; on the shebang.
(set-dispatch-macro-character
 #\# #\!
 (lambda (stream char arg)
   (declare (ignore char arg))
   (values (read-line stream))))

;; Use double-precision by default.
(setf *read-default-float-format* 'double-float)

;; Start up Swank.
(export 'crank-swank)
(defun crank-swank (&rest args)
  (let ((swank (find-package "SWANK")))
    (unless swank
      (load "/usr/share/common-lisp/source/slime/swank-loader.lisp")
      (funcall (find-symbol "INIT" (find-package "SWANK-LOADER")))
      (setf swank (find-package "SWANK")))
    (set (find-symbol "*GLOBAL-DEBUGGER*" swank) nil)
    (apply (find-symbol "CREATE-SERVER" swank) args)))

;; Treat warnings as, err, warnings.
#+asdf
(setf asdf:*compile-file-failure-behaviour* :warn)

;; Done.
(pushnew :mdw *features*)
;;#+(and cmu mp) (mp::startup-idle-and-top-level-loops)
(setf *package* *previous-package*)