mdw@git.distorted.org.uk Git - misc/blob - configure.ac

   1 dnl -*-autoconf-*-
   2 dnl
   3 dnl Configuration script for distorted-utils
   4 dnl
   5 dnl (c) 2008 Mark Wooding
   6 dnl
   7
   8 dnl ----- Licensing notice --------------------------------------------------
   9 dnl
  10 dnl This program is free software; you can redistribute it and/or modify
  11 dnl it under the terms of the GNU General Public License as published by
  12 dnl the Free Software Foundation; either version 2 of the License, or
  13 dnl (at your option) any later version.
  14 dnl
  15 dnl This program is distributed in the hope that it will be useful,
  16 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 dnl GNU General Public License for more details.
  19 dnl
  20 dnl You should have received a copy of the GNU General Public License
  21 dnl along with this program; if not, write to the Free Software Foundation,
  22 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23
  24 dnl--------------------------------------------------------------------------
  25 dnl Initialization.
  26
  27 mdw_AUTO_VERSION
  28 AC_INIT([distorted-utils], AUTO_VERSION, [mdw@distorted.org.uk])
  29 AC_CONFIG_SRCDIR([shadowfix.in])
  30 AC_CONFIG_AUX_DIR([config])
  31 AM_INIT_AUTOMAKE([foreign])
  32 mdw_SILENT_RULES
  33
  34 AC_ARG_WITH([logdir],
  35         AS_HELP_STRING([--with-logdir=DIR],
  36                        [Write log files here.]),
  37         [logdir=$withval],
  38         [logdir=/var/log
  39          for i in /var/log /var/adm; do
  40            if test -d $i; then logdir=$i; break; fi
  41          done])
  42 AC_SUBST(logdir)
  43
  44 AC_CANONICAL_HOST
  45
  46 dnl--------------------------------------------------------------------------
  47 dnl C programming environment.
  48
  49 ## Compiler.
  50 AC_PROG_CC
  51 AX_CFLAGS_WARN_ALL
  52 AC_PROG_CXX
  53 AX_CXXFLAGS_WARN_ALL
  54
  55 ## Libraries.
  56 OLIBS=$LIBS
  57 AC_SEARCH_LIBS([floor], [m])
  58 AC_SUBST([MATH_LIBS], [$LIBS])
  59 LIBS=$OLIBS
  60
  61 AC_CHECK_LIB([cdb], [cdb_seek], [have_cdb=yes], [have_cdb=no])
  62 AM_CONDITIONAL([HAVE_LIBCDB], [test $have_cdb = yes])
  63
  64 ## Packages.
  65 PKG_CHECK_MODULES([mLib], [mLib >= 2.0.4], [have_mLib=yes], [have_mLib=no])
  66 AM_CONDITIONAL([HAVE_MLIB], [test $have_mLib = yes])
  67
  68 PKG_CHECK_MODULES([catacomb], [catacomb >= 2.1.1],
  69                   [have_catacomb=yes], [have_catacomb=no])
  70 AM_CONDITIONAL([HAVE_CATACOMB], [test $have_catacomb = yes])
  71
  72 ## Functions.
  73 AC_CHECK_FUNC([prlimit], [have_prlimit=yes], [have_prlimit=no])
  74 AM_CONDITIONAL([HAVE_PRLIMIT], [test $have_prlimit = yes])
  75
  76 ## Processor type.
  77 case "$host_cpu" in i?86 | x86_64) x86=yes;; *) x86=no;; esac
  78 AM_CONDITIONAL([X86], [test $x86 = yes -a $GCC = yes])
  79
  80 dnl--------------------------------------------------------------------------
  81 dnl Python, Perl and other scripting languages.
  82
  83 ## Python.
  84 AM_PATH_PYTHON([2.4], [have_python=yes], [have_python=no])
  85 AM_CONDITIONAL([HAVE_PYTHON], [test $have_python = yes])
  86
  87 AC_PYTHON_MODULE([cdb])
  88 AM_CONDITIONAL([HAVE_PYMOD_CDB], [test $HAVE_PYMOD_CDB = yes])
  89
  90 ## Perl.
  91 AC_ARG_VAR([PERL], [Path to your favourite Perl binary.])
  92 AC_PATH_PROGS([PERL], [perl perl5], [false])
  93 AX_PROG_PERL_VERSION([5.004], [have_perl=yes], [have_perl=no])
  94 AM_CONDITIONAL([HAVE_PERL], [test $have_perl = yes])
  95
  96 AC_ARG_WITH([perlmoddir],
  97         AS_HELP_STRING([--with-perlmoddir=DIR],
  98                        [Install Perl modules here.]),
  99         [perlmoddir=$withval],
 100         [perlmoddir='${libdir}/site_perl'])
 101 AC_SUBST([perlmoddir])
 102
 103 ## Tcl.
 104 have_tcl=yes
 105 AC_ARG_VAR([TCLSH], [Path to your favourite tclsh binary.])
 106 AC_PATH_PROG([TCLSH], [tclsh], [false])
 107
 108 AC_MSG_CHECKING([Tcl version])
 109 case "$TCLSH" in false) have_tcl=no ;; esac
 110 case "$have_tcl" in
 111   yes)
 112     tclver=$(echo "puts \$tcl_version" | tclsh -)
 113     tclver_hack=$(echo "$tclver" | sed 's/\.//')
 114     if test "$tclver_hack" -ge 83; then
 115       AC_MSG_RESULT([$tclver])
 116     else
 117       have_tcl=no
 118       AC_MSG_RESULT([too old ($tclver)])
 119     fi
 120 esac
 121 AM_CONDITIONAL([HAVE_TCLSH], [test $have_tcl = yes])
 122
 123 ## Bash.
 124 case "$BASH" in /bin/sh) unset BASH ;; esac
 125 AC_ARG_VAR([BASH], [Path to the Bourne Again Shell.])
 126 AC_PATH_PROG([BASH], [bash], [false])
 127 AC_MSG_CHECKING([bash version])
 128 bashver=$("$BASH" -c 'echo $BASH_VERSION')
 129 if "$BASH" 2>/dev/null -c '[[[ ${BASH_VERSINFO[0]} -ge 3 ]]]'; then
 130   have_bash=yes
 131   AC_MSG_RESULT([$bashver])
 132 else
 133   have_bash=no
 134   AC_MSG_RESULT([too old ($bashver)])
 135 fi
 136 AM_CONDITIONAL([HAVE_BASH], [test $have_bash = yes])
 137
 138 dnl--------------------------------------------------------------------------
 139 dnl Output.
 140
 141 AC_CONFIG_FILES([Makefile])
 142 AC_OUTPUT
 143
 144 dnl ----- That's all, folks -------------------------------------------------