+dnl *@-mdw_MGLIB-@*
+dnl
+dnl Author: Mark Wooding
+dnl
+dnl Synopsis: mdw_MGLIB(VERSION, IF-FOUND, IF-NOT-FOUND
+dnl
+dnl Arguments: VERSION = version of library required
+dnl IF-FOUND = what to do if found
+dnl IF-NOT-FOUND = what to do if not found
+dnl
+dnl Use: Configures an mgLib client program. The default
+dnl version is 1.0.0pre0; the default action is to add
+dnl everything to the CFLAGS and LIBS variables, and complain
+dnl if the library couldn't be found.
+dnl
+dnl The variable MGLIB_VERSION contains the version number of
+dnl the library; MGLIB_CFLAGS is the C compiler flags required
+dnl and MGLIB_LIBS is the linker flags.
+
+AC_DEFUN([mdw_MGLIB],
+[mdw_REQUIRE([mdw_MGLIB], [1.6.0])
+AC_MSG_CHECKING([for mgLib library])
+if mgLib-config --check $1 >/dev/null 2>&1; then
+ MGLIB_VERSION=`mgLib-config --version`
+ MGLIB_CFLAGS=`mgLib-config --cflags`
+ MGLIB_LIBS=`mgLib-config --libs`
+ AC_SUBST(MGLIB_VERSION) AC_SUBST(MGLIB_CFLAGS) AC_SUBST(MGLIB_LIBS)
+ ifelse([$2], [],
+ [CFLAGS="$CFLAGS $MGLIB_CFLAGS"
+ LIBS="$MGLIB_LIBS $LIBS"],
+ $2)
+ AC_MSG_RESULT([$MGLIB_VERSION])
+else
+ ifelse([$3], [],
+ AC_MSG_ERROR([mgLib library not found or too old.]),
+ $3)
+ AC_MSG_RESULT([not found])
+fi])
+