[lisp] / mdw-base.lisp

;;; -*-lisp-*-
;;;
;;; $Id$
;;;
;;; Basic definitions
;;;
;;; (c) 2005 Mark Wooding
;;;

;;;----- Licensing notice ---------------------------------------------------
;;;
;;; This program is free software; you can redistribute it and/or modify
;;; it under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 2 of the License, or
;;; (at your option) any later version.
;;; 
;;; This program is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;; 
;;; You should have received a copy of the GNU General Public License
;;; along with this program; if not, write to the Free Software Foundation,
;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

;;;--------------------------------------------------------------------------
;;; Package things.

(defpackage #:mdw.base
  (:use #:common-lisp)
  (:export #:compile-time-defun
	   #:show
	   #:stringify #:listify #:fix-pair #:pairify
	   #:whitespace-char-p
	   #:slot-uninitialized
	   #:nlet #:while #:case2 #:ecase2
	   #:with-gensyms #:let*/gensyms #:with-places
	   #:locp #:locf #:ref #:with-locatives
	   #:update-place #:update-place-after
	   #:incf-after #:decf-after))
(in-package #:mdw.base)

;;;--------------------------------------------------------------------------
;;; Some simple macros to get things going.

(defmacro compile-time-defun (name args &body body)
  "Define a function which can be used by macros during the compilation
process."
  `(eval-when (:compile-toplevel :load-toplevel)
     (defun ,name ,args ,@body)))

(defmacro show (x)
  "Debugging tool: print the expression X and its value."
  (let ((tmp (gensym)))
    `(let ((,tmp ,x))
       (format t "~&~S: ~S~%" ',x ,tmp)
       ,tmp)))

(defun stringify (str)
  "Return a string representation of STR.  Strings are returned unchanged;
symbols are converted to their names (unqualified!).  Other objects are
converted to their print representations."
  (typecase str
    (string str)
    (symbol (symbol-name str))
    (t (with-output-to-string (s)
	 (princ str s)))))

(compile-time-defun listify (x)
  "If X is a (possibly empty) list, return X; otherwise return (list X)."
  (if (listp x) x (list x)))

(compile-time-defun do-fix-pair (x y defaultp)
  "Helper function for fix-pair and pairify."
  (flet ((singleton (x) (values x (if defaultp y x))))
    (cond ((atom x) (singleton x))
	  ((null (cdr x)) (singleton (car x)))
	  ((atom (cdr x)) (values (car x) (cdr x)))
	  ((cddr x) (error "Too many elements for a pair."))
	  (t (values (car x) (cadr x))))))

(compile-time-defun fix-pair (x &optional (y nil defaultp))
  "Return two values extracted from X.  It works as follows:
  (A) -> A, Y
  (A B) -> A, B
  (A B . C) -> error
  (A . B) -> A, B
  A -> A, Y
where Y defaults to A if not specified."
  (do-fix-pair x y defaultp))

(compile-time-defun pairify (x &optional (y nil defaultp))
  "As for fix-pair, but returns a list instead of two values."
  (multiple-value-call #'list (do-fix-pair x y defaultp)))

(defun whitespace-char-p (ch)
  "Return whether CH is a whitespace character or not."
  (case ch
    ((#\space #\tab #\newline #\return #\vt #\formfeed) t)
    (t nil)))

(declaim (ftype (function nil ()) slot-unitialized))
(defun slot-uninitialized ()
  "A function which signals an error.  Can be used as an initializer form in
structure definitions without doom ensuing."
  (error "No initializer for slot."))

;;;--------------------------------------------------------------------------
;;; Generating symbols.

(defmacro with-gensyms (syms &body body)
  "Everyone's favourite macro helper."
  `(let (,@(mapcar (lambda (sym) `(,sym (gensym ,(symbol-name sym))))
                   (listify syms)))
     ,@body))

(defmacro let*/gensyms (binds &body body)
  "A macro helper.  BINDS is a list of binding pairs (VAR VALUE), where VALUE
defaults to VAR.  The result is that BODY is evaluated in a context where
each VAR is bound to a gensym, and in the final expansion, each of those
gensyms will be bound to the corresponding VALUE."
  (labels ((more (binds)
             (let ((tmp (gensym "TMP")) (bind (car binds)))
               `((let ((,tmp ,(cadr bind))
                       (,(car bind) (gensym ,(symbol-name (car bind)))))
                   `(let ((,,(car bind) ,,tmp))
                      ,,@(if (cdr binds)
                             (more (cdr binds))
                             body)))))))
    (if (null binds)
        `(progn ,@body)
        (car (more (mapcar #'pairify (listify binds)))))))

;;;--------------------------------------------------------------------------
;;; Some simple yet useful control structures.

(defmacro nlet (name binds &body body)
  "Scheme's named let."
  (multiple-value-bind (vars vals)
      (loop for bind in binds
	    for (var val) = (pairify bind nil)
	    collect var into vars
	    collect val into vals
	    finally (return (values vars vals)))
    `(labels ((,name ,vars
	        ,@body))
       (,name ,@vals))))

(defmacro while (cond &body body)
  "If COND is false, evaluate to nil; otherwise evaluate BODY and try again."
  `(loop
     (unless ,cond (return))
     ,@body))

(compile-time-defun do-case2-like (kind vform clauses)
  "Helper function for `case2' and `ecase2'."
  (with-gensyms (scrutinee argument)
    `(multiple-value-bind (,scrutinee ,argument) ,vform
       (declare (ignorable ,argument))
       (,kind ,scrutinee
	 ,@(mapcar (lambda (clause)
		     (destructuring-bind
			 (cases (&optional var) &rest forms)
			 clause
		       `(,cases
			 ,@(if var
			       (list `(let ((,var ,argument)) ,@forms))
			       forms))))
		   clauses)))))

(defmacro case2 (vform &body clauses)
  "VFORM is a form which evaluates to two values, SCRUTINEE and ARGUMENT.
The CLAUSES have the form (CASES ([VAR]) FORMS...), where a standard `case'
clause has the form (CASES FORMS...).  The `case2' form evaluates the VFORM,
and compares the SCRUTINEE to the various CASES, in order, just like `case'.
If there is a match, then the corresponding FORMs are evaluated with VAR (if
specified) bound to the value of ARGUMENT."
  (do-case2-like 'case vform clauses))

(defmacro ecase2 (vform &body clauses)
  "Like `case2', but signals an error if no clause matches the SCRUTINEE."
  (do-case2-like 'ecase vform clauses))

;;;--------------------------------------------------------------------------
;;; with-places

(defmacro %place-ref (getform setform newtmp)
  "Grim helper macro for with-places."
  (declare (ignore setform newtmp))
  getform)

(define-setf-expander %place-ref (getform setform newtmp)
  "Grim helper macro for with-places."
  (values nil nil newtmp setform getform))

(defmacro with-places ((&key environment) places &body body)
  "A hairy helper, for writing setf-like macros.  PLACES is a list of binding
pairs (VAR PLACE), where PLACE defaults to VAR.  The result is that BODY is
evaluated in a context where each VAR is bound to a gensym, and in the final
expansion, each of those gensyms will be bound to a symbol-macro capable of
reading or setting the value of the corresponding PLACE."
  (if (null places)
      `(progn ,@body)
      (let*/gensyms (environment)
        (labels
            ((more (places)
               (let ((place (car places)))
                 (with-gensyms (tmp valtmps valforms
                                    newtmps setform getform)
                   `((let ((,tmp ,(cadr place))
                           (,(car place)
                            (gensym ,(symbol-name (car place)))))
                       (multiple-value-bind
                           (,valtmps ,valforms
                            ,newtmps ,setform ,getform)
                           (get-setf-expansion ,tmp
                                               ,environment)
                         (list 'let*
                               (mapcar #'list ,valtmps ,valforms)
                               `(symbol-macrolet ((,,(car place)
                                                   (%place-ref ,,getform
                                                               ,,setform
                                                               ,,newtmps)))
                                  ,,@(if (cdr places)
                                         (more (cdr places))
                                         body))))))))))
          (car (more (mapcar #'pairify (listify places))))))))

;;;--------------------------------------------------------------------------
;;; Update-in-place macros built using with-places.

(defmacro update-place (op place arg &environment env)
  "Update PLACE with the value of OP PLACE ARG, returning the new value."
  (with-places (:environment env) (place)
    `(setf ,place (,op ,place ,arg))))

(defmacro update-place-after (op place arg &environment env)
  "Update PLACE with the value of OP PLACE ARG, returning the old value."
  (with-places (:environment env) (place)
    (with-gensyms (x)
      `(let ((,x ,place))
	 (setf ,place (,op ,x ,arg))
	 ,x))))

(defmacro incf-after (place &optional (by 1))
  "Increment PLACE by BY, returning the old value."
  `(update-place-after + ,place ,by))

(defmacro decf-after (place &optional (by 1))
  "Decrement PLACE by BY, returning the old value."
  `(update-place-after - ,place ,by))

;;;--------------------------------------------------------------------------
;;; Locatives.

(defstruct (loc (:predicate locp) (:constructor make-loc (reader writer)))
  "Locative data type.  See `locf' and `ref'."
  (reader (slot-uninitialized) :type function)
  (writer (slot-uninitialized) :type function))

(defmacro locf (place &environment env)
  "Slightly cheesy locatives.  (locf PLACE) returns an object which, using
the `ref' function, can be used to read or set the value of PLACE.  It's
cheesy because it uses closures rather than actually taking the address of
something.  Also, unlike Zetalisp, we don't overload `car' to do our dirty
work."
  (multiple-value-bind
      (valtmps valforms newtmps setform getform)
      (get-setf-expansion place env)
    `(let* (,@(mapcar #'list valtmps valforms))
       (make-loc (lambda () ,getform)
                 (lambda (,@newtmps) ,setform)))))

(declaim (inline loc (setf loc)))

(defun ref (loc)
  "Fetch the value referred to by a locative."
  (funcall (loc-reader loc)))

(defun (setf ref) (new loc)
  "Store a new value in the place referred to by a locative."
  (funcall (loc-writer loc) new))

(defmacro with-locatives (locs &body body)
  "LOCS is a list of items of the form (SYM [LOC-EXPR]), where SYM is a
symbol and LOC-EXPR evaluates to a locative.  If LOC-EXPR is omitted, it
defaults to SYM.  As an abbreviation for a common case, LOCS may be a symbol
instead of a list.  The BODY is evaluated in an environment where each SYM is
a symbol macro which expands to (ref LOC-EXPR) -- or, in fact, something
similar which doesn't break if LOC-EXPR has side-effects.  Thus, references,
including `setf' forms, fetch or modify the thing referred to by the
LOC-EXPR.  Useful for covering over where something uses a locative."
  (setf locs (mapcar #'pairify (listify locs)))
  (let ((tt (mapcar (lambda (l) (declare (ignore l)) (gensym)) locs))
	(ll (mapcar #'cadr locs))
	(ss (mapcar #'car locs)))
    `(let (,@(mapcar (lambda (tmp loc) `(,tmp ,loc)) tt ll))
       (symbol-macrolet (,@(mapcar (lambda (sym tmp)
				     `(,sym (ref ,tmp))) ss tt))
	 ,@body))))

;;;----- That's all, folks --------------------------------------------------
Commit	Line	Data
861345b4	1	;;; --lisp--
	2	;;;
	3	;;; $Id$
	4	;;;
	5	;;; Basic definitions
	6	;;;
	7	;;; (c) 2005 Mark Wooding
	8	;;;
	9
	10	;;;----- Licensing notice ---------------------------------------------------
	11	;;;
	12	;;; This program is free software; you can redistribute it and/or modify
	13	;;; it under the terms of the GNU General Public License as published by
	14	;;; the Free Software Foundation; either version 2 of the License, or
	15	;;; (at your option) any later version.
	16	;;;
	17	;;; This program is distributed in the hope that it will be useful,
	18	;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	19	;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	20	;;; GNU General Public License for more details.
	21	;;;
	22	;;; You should have received a copy of the GNU General Public License
	23	;;; along with this program; if not, write to the Free Software Foundation,
	24	;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
	25
02866e07 MW	26	;;;--------------------------------------------------------------------------
	27	;;; Package things.
	28
861345b4	29	(defpackage #:mdw.base
	30	(:use #:common-lisp)
	31	(:export #:compile-time-defun
	32	#:show
	33	#:stringify #:listify #:fix-pair #:pairify
	34	#:whitespace-char-p
	35	#:slot-uninitialized
560e1186	36	#:nlet #:while #:case2 #:ecase2
861345b4	37	#:with-gensyms #:let*/gensyms #:with-places
e979e568 MW	38	#:locp #:locf #:ref #:with-locatives
	39	#:update-place #:update-place-after
	40	#:incf-after #:decf-after))
861345b4	41	(in-package #:mdw.base)
861345b4	42
02866e07 MW	43	;;;--------------------------------------------------------------------------
	44	;;; Some simple macros to get things going.
	45
861345b4	46	(defmacro compile-time-defun (name args &body body)
	47	"Define a function which can be used by macros during the compilation
	48	process."
	49	`(eval-when (:compile-toplevel :load-toplevel)
	50	(defun ,name ,args ,@body)))
	51
	52	(defmacro show (x)
	53	"Debugging tool: print the expression X and its value."
	54	(let ((tmp (gensym)))
	55	`(let ((,tmp ,x))
	56	(format t "~&~S: ~S~%" ',x ,tmp)
	57	,tmp)))
	58
	59	(defun stringify (str)
	60	"Return a string representation of STR. Strings are returned unchanged;
	61	symbols are converted to their names (unqualified!). Other objects are
	62	converted to their print representations."
	63	(typecase str
	64	(string str)
	65	(symbol (symbol-name str))
	66	(t (with-output-to-string (s)
	67	(princ str s)))))
02866e07	68
861345b4	69	(compile-time-defun listify (x)
	70	"If X is a (possibly empty) list, return X; otherwise return (list X)."
	71	(if (listp x) x (list x)))
02866e07	72
861345b4	73	(compile-time-defun do-fix-pair (x y defaultp)
	74	"Helper function for fix-pair and pairify."
	75	(flet ((singleton (x) (values x (if defaultp y x))))
	76	(cond ((atom x) (singleton x))
	77	((null (cdr x)) (singleton (car x)))
	78	((atom (cdr x)) (values (car x) (cdr x)))
	79	((cddr x) (error "Too many elements for a pair."))
	80	(t (values (car x) (cadr x))))))
02866e07	81
861345b4	82	(compile-time-defun fix-pair (x &optional (y nil defaultp))
	83	"Return two values extracted from X. It works as follows:
	84	(A) -> A, Y
	85	(A B) -> A, B
	86	(A B . C) -> error
	87	(A . B) -> A, B
	88	A -> A, Y
	89	where Y defaults to A if not specified."
	90	(do-fix-pair x y defaultp))
02866e07	91
861345b4	92	(compile-time-defun pairify (x &optional (y nil defaultp))
	93	"As for fix-pair, but returns a list instead of two values."
	94	(multiple-value-call #'list (do-fix-pair x y defaultp)))
	95
	96	(defun whitespace-char-p (ch)
	97	"Return whether CH is a whitespace character or not."
	98	(case ch
	99	((#\space #\tab #\newline #\return #\vt #\formfeed) t)
	100	(t nil)))
	101
	102	(declaim (ftype (function nil ()) slot-unitialized))
	103	(defun slot-uninitialized ()
	104	"A function which signals an error. Can be used as an initializer form in
	105	structure definitions without doom ensuing."
	106	(error "No initializer for slot."))
	107
02866e07 MW	108	;;;--------------------------------------------------------------------------
	109	;;; Generating symbols.
	110
861345b4	111	(defmacro with-gensyms (syms &body body)
	112	"Everyone's favourite macro helper."
	113	`(let (,@(mapcar (lambda (sym) `(,sym (gensym ,(symbol-name sym))))
	114	(listify syms)))
	115	,@body))
	116
	117	(defmacro let*/gensyms (binds &body body)
	118	"A macro helper. BINDS is a list of binding pairs (VAR VALUE), where VALUE
	119	defaults to VAR. The result is that BODY is evaluated in a context where
	120	each VAR is bound to a gensym, and in the final expansion, each of those
	121	gensyms will be bound to the corresponding VALUE."
	122	(labels ((more (binds)
	123	(let ((tmp (gensym "TMP")) (bind (car binds)))
	124	`((let ((,tmp ,(cadr bind))
	125	(,(car bind) (gensym ,(symbol-name (car bind)))))
	126	`(let ((,,(car bind) ,,tmp))
	127	,,@(if (cdr binds)
	128	(more (cdr binds))
	129	body)))))))
	130	(if (null binds)
	131	`(progn ,@body)
	132	(car (more (mapcar #'pairify (listify binds)))))))
	133
02866e07	134	;;;--------------------------------------------------------------------------
f2d46aaa MW	135	;;; Some simple yet useful control structures.
	136
	137	(defmacro nlet (name binds &body body)
	138	"Scheme's named let."
	139	(multiple-value-bind (vars vals)
	140	(loop for bind in binds
	141	for (var val) = (pairify bind nil)
	142	collect var into vars
	143	collect val into vals
	144	finally (return (values vars vals)))
	145	`(labels ((,name ,vars
	146	,@body))
	147	(,name ,@vals))))
	148
	149	(defmacro while (cond &body body)
	150	"If COND is false, evaluate to nil; otherwise evaluate BODY and try again."
	151	`(loop
93f04724	152	(unless ,cond (return))
f2d46aaa MW	153	,@body))
f2d46aaa MW	154
560e1186 MW	155	(compile-time-defun do-case2-like (kind vform clauses)
	156	"Helper function for `case2' and `ecase2'."
	157	(with-gensyms (scrutinee argument)
	158	`(multiple-value-bind (,scrutinee ,argument) ,vform
	159	(declare (ignorable ,argument))
	160	(,kind ,scrutinee
	161	,@(mapcar (lambda (clause)
	162	(destructuring-bind
	163	(cases (&optional var) &rest forms)
	164	clause
	165	`(,cases
	166	,@(if var
	167	(list `(let ((,var ,argument)) ,@forms))
	168	forms))))
	169	clauses)))))
	170
	171	(defmacro case2 (vform &body clauses)
	172	"VFORM is a form which evaluates to two values, SCRUTINEE and ARGUMENT.
	173	The CLAUSES have the form (CASES ([VAR]) FORMS...), where a standard `case'
	174	clause has the form (CASES FORMS...). The `case2' form evaluates the VFORM,
	175	and compares the SCRUTINEE to the various CASES, in order, just like `case'.
	176	If there is a match, then the corresponding FORMs are evaluated with VAR (if
	177	specified) bound to the value of ARGUMENT."
	178	(do-case2-like 'case vform clauses))
	179
	180	(defmacro ecase2 (vform &body clauses)
	181	"Like `case2', but signals an error if no clause matches the SCRUTINEE."
	182	(do-case2-like 'ecase vform clauses))
	183
f2d46aaa	184	;;;--------------------------------------------------------------------------
02866e07 MW	185	;;; with-places
02866e07 MW	186
861345b4	187	(defmacro %place-ref (getform setform newtmp)
	188	"Grim helper macro for with-places."
	189	(declare (ignore setform newtmp))
	190	getform)
02866e07	191
861345b4	192	(define-setf-expander %place-ref (getform setform newtmp)
	193	"Grim helper macro for with-places."
	194	(values nil nil newtmp setform getform))
02866e07	195
861345b4	196	(defmacro with-places ((&key environment) places &body body)
	197	"A hairy helper, for writing setf-like macros. PLACES is a list of binding
	198	pairs (VAR PLACE), where PLACE defaults to VAR. The result is that BODY is
	199	evaluated in a context where each VAR is bound to a gensym, and in the final
	200	expansion, each of those gensyms will be bound to a symbol-macro capable of
	201	reading or setting the value of the corresponding PLACE."
	202	(if (null places)
	203	`(progn ,@body)
	204	(let*/gensyms (environment)
	205	(labels
	206	((more (places)
	207	(let ((place (car places)))
	208	(with-gensyms (tmp valtmps valforms
	209	newtmps setform getform)
	210	`((let ((,tmp ,(cadr place))
	211	(,(car place)
	212	(gensym ,(symbol-name (car place)))))
	213	(multiple-value-bind
	214	(,valtmps ,valforms
	215	,newtmps ,setform ,getform)
	216	(get-setf-expansion ,tmp
	217	,environment)
	218	(list 'let*
	219	(mapcar #'list ,valtmps ,valforms)
	220	`(symbol-macrolet ((,,(car place)
	221	(%place-ref ,,getform
	222	,,setform
	223	,,newtmps)))
	224	,,@(if (cdr places)
	225	(more (cdr places))
	226	body))))))))))
	227	(car (more (mapcar #'pairify (listify places))))))))
	228
02866e07 MW	229	;;;--------------------------------------------------------------------------
	230	;;; Update-in-place macros built using with-places.
	231
e979e568 MW	232	(defmacro update-place (op place arg &environment env)
	233	"Update PLACE with the value of OP PLACE ARG, returning the new value."
	234	(with-places (:environment env) (place)
	235	`(setf ,place (,op ,place ,arg))))
02866e07	236
e979e568 MW	237	(defmacro update-place-after (op place arg &environment env)
	238	"Update PLACE with the value of OP PLACE ARG, returning the old value."
	239	(with-places (:environment env) (place)
	240	(with-gensyms (x)
	241	`(let ((,x ,place))
02866e07 MW	242	(setf ,place (,op ,x ,arg))
	243	,x))))
	244
e979e568 MW	245	(defmacro incf-after (place &optional (by 1))
	246	"Increment PLACE by BY, returning the old value."
	247	`(update-place-after + ,place ,by))
02866e07	248
e979e568 MW	249	(defmacro decf-after (place &optional (by 1))
	250	"Decrement PLACE by BY, returning the old value."
	251	`(update-place-after - ,place ,by))
	252
02866e07 MW	253	;;;--------------------------------------------------------------------------
02866e07 MW	254	;;; Locatives.
e979e568	255
861345b4	256	(defstruct (loc (:predicate locp) (:constructor make-loc (reader writer)))
	257	"Locative data type. See `locf' and `ref'."
	258	(reader (slot-uninitialized) :type function)
	259	(writer (slot-uninitialized) :type function))
02866e07	260
861345b4	261	(defmacro locf (place &environment env)
	262	"Slightly cheesy locatives. (locf PLACE) returns an object which, using
	263	the `ref' function, can be used to read or set the value of PLACE. It's
	264	cheesy because it uses closures rather than actually taking the address of
	265	something. Also, unlike Zetalisp, we don't overload `car' to do our dirty
	266	work."
	267	(multiple-value-bind
	268	(valtmps valforms newtmps setform getform)
	269	(get-setf-expansion place env)
	270	`(let* (,@(mapcar #'list valtmps valforms))
	271	(make-loc (lambda () ,getform)
	272	(lambda (,@newtmps) ,setform)))))
02866e07	273
861345b4	274	(declaim (inline loc (setf loc)))
02866e07	275
861345b4	276	(defun ref (loc)
	277	"Fetch the value referred to by a locative."
	278	(funcall (loc-reader loc)))
02866e07	279
861345b4	280	(defun (setf ref) (new loc)
	281	"Store a new value in the place referred to by a locative."
	282	(funcall (loc-writer loc) new))
02866e07	283
861345b4	284	(defmacro with-locatives (locs &body body)
	285	"LOCS is a list of items of the form (SYM [LOC-EXPR]), where SYM is a
	286	symbol and LOC-EXPR evaluates to a locative. If LOC-EXPR is omitted, it
	287	defaults to SYM. As an abbreviation for a common case, LOCS may be a symbol
	288	instead of a list. The BODY is evaluated in an environment where each SYM is
	289	a symbol macro which expands to (ref LOC-EXPR) -- or, in fact, something
	290	similar which doesn't break if LOC-EXPR has side-effects. Thus, references,
	291	including `setf' forms, fetch or modify the thing referred to by the
	292	LOC-EXPR. Useful for covering over where something uses a locative."
	293	(setf locs (mapcar #'pairify (listify locs)))
	294	(let ((tt (mapcar (lambda (l) (declare (ignore l)) (gensym)) locs))
	295	(ll (mapcar #'cadr locs))
	296	(ss (mapcar #'car locs)))
	297	`(let (,@(mapcar (lambda (tmp loc) `(,tmp ,loc)) tt ll))
	298	(symbol-macrolet (,@(mapcar (lambda (sym tmp)
	299	`(,sym (ref ,tmp))) ss tt))
	300	,@body))))
	301
	302	;;;----- That's all, folks --------------------------------------------------