mdw@git.distorted.org.uk Git - firewall/blob - base.m4

   1 m4_divert(-1)
   2 ### -*-m4-*-
   3 ###
   4 ### Failsafe prologue for firewall scripts
   5 ###
   6 ### (c) 2008 Mark Wooding
   7 ###
   8
   9 ###----- Licensing notice ---------------------------------------------------
  10 ###
  11 ### This program is free software; you can redistribute it and/or modify
  12 ### it under the terms of the GNU General Public License as published by
  13 ### the Free Software Foundation; either version 2 of the License, or
  14 ### (at your option) any later version.
  15 ###
  16 ### This program is distributed in the hope that it will be useful,
  17 ### but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ### GNU General Public License for more details.
  20 ###
  21 ### You should have received a copy of the GNU General Public License
  22 ### along with this program; if not, write to the Free Software Foundation,
  23 ### Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  24
  25 m4_changequote(<:, :>)
  26 m4_changecom(<:##:>)
  27
  28 ###--------------------------------------------------------------------------
  29 ### Overall structure.
  30 ###
  31 ###  0  File header: shebang, do-not-edit warning.              [base]
  32 ###  5  Configuration.                                          [config]
  33 ### 10  Prologue: command-line parsing and failsafe.            [prologue]
  34 ### 20  Function definitions.                                   [functions]
  35 ### 25  Port numbers etc.                                       [numbers]
  36 ### 30  Initialization.                                         [bookends]
  37 ### 30    Clear existing rules.                                 [bookends]
  38 ### 32    Set safe IP options.                                  [bookends]
  39 ### 34    Error chains.                                         [bookends]
  40 ### 36    Give loopback traffic a free pass.                    [bookends]
  41 ### 38    Utility chains.                                       [functions]
  42 ### 40  Address classification.                                 [classify]
  43 ### 42    Definition of address class policies.                 [local]
  44 ### 44    Definition of interfaces and addresses.               [local]
  45 ### 46    Handling of default interface.                        [classify]
  46 ### 50  ICMP filtering.                                         [icmp]
  47 ### 52    Local configuration.                                  [local]
  48 ### 58    Finally accept ICMP, hook onto INPUT and FORWARD.     [icmp]
  49 ### 60  Local configuration.                                    [local]
  50 ### 90  Finishing touches.                                      [bookends]
  51 ### 94    Set final policies.                                   [bookends]
  52 ### 99  File footer: do-not-edit warning.                       [base]
  53
  54 ###--------------------------------------------------------------------------
  55 ### Headers and footers.
  56
  57 m4_divert(0)m4_dnl
  58 #! /bin/sh
  59 ### BEGIN INIT INFO
  60 # Provides:             firewall
  61 # Required-Start:       mountkernfs
  62 # Required-Stop:
  63 # X-Start-Before:       ifupdown
  64 # X-Stop-After:         ifupdown
  65 # Default-Start:        S
  66 # Default-Stop:         0 6
  67 # Description:          Provides customized packet filter rules.
  68 ### END INIT INFO
  69 ### *** GENERATED FILE: DO NOT EDIT ***
  70
  71 set -e
  72 PATH=/bin:/sbin:/usr/bin:/usr/sbin; export PATH
  73
  74 m4_divert(99)m4_dnl
  75 ### *** GENERATED FILE: DO NOT EDIT ***
  76 m4_divert(-1)
  77
  78 ###--------------------------------------------------------------------------
  79 ### Unpleasant m4 hacking.
  80
  81 ## dolist(VAR, LIST, BODY)
  82 ##
  83 ## LIST is a parenthesized list of comma-separated items.  For each item,
  84 ## set VAR to expand to the item and emit the BODY.
  85 m4_define(<:dolist:>, <:m4_pushdef(<:$1:>)__loop($@)m4_popdef(<:$1:>):>)
  86 m4_define(<:__loop:>, <:m4_ifelse(<:$2:>, <:():>, ,m4_dnl
  87 <:m4_define(<:$1:>, __first$2)$3<::>__loop(<:$1:>,(m4_shift$2),<:$3:>):>):>)
  88 m4_define(<:__first:>, <:$1:>)
  89
  90 ## split(DELIM, TEXT)
  91 ##
  92 ## Split TEXT at characters in DELIM; stash result in positional parameters.
  93 m4_define(<:split:>, <:IFS=$1; set -- $2; IFS=$STDIFS:>)
  94
  95 ## defconf(CONF, DEFAULT)
  96 ##
  97 ## Define config variable CONF, assigning it the DEFAULT value if not
  98 ## overridden by setconf.
  99 m4_define(<:defconf:>, <:: ${$1=m4_ifdef(<:conf_$1:>, conf_$1, $2)}:>)
 100
 101 ## setconf(CONF, VALUE)
 102 ##
 103 ## Set config variable VALUE.
 104 m4_define(<:setconf:>, <:m4_define(<:conf_$1:>, <:$2:>):>)
 105
 106 ###----- That's all, folks --------------------------------------------------