mdw@git.distorted.org.uk Git - disorder/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # This file is part of DisOrder.
   4 # Copyright (C) 2004, 2005, 2006, 2007 Richard Kettlewell
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 # General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  19 # USA
  20 #
  21
  22 AC_INIT([disorder], [1.5.99+], [richard+disorder@sfere.greenend.org.uk])
  23 AC_CONFIG_AUX_DIR([config.aux])
  24 AM_INIT_AUTOMAKE(disorder, [1.5.99+])
  25 AC_CONFIG_SRCDIR([server/disorderd.c])
  26 AM_CONFIG_HEADER([config.h])
  27
  28 # Find host type
  29 AC_CANONICAL_HOST
  30
  31 # What we want to build
  32 want_gtk=yes
  33 want_python=yes
  34
  35 # APIs we want
  36 want_alsa=yes
  37 want_oss=yes
  38 want_coreaudio=yes
  39
  40 # Checks for programs.
  41 AC_PROG_CC
  42 AC_SET_MAKE
  43 if test "x$GCC" = xyes; then
  44   gcc_werror=-Werror
  45 else
  46   gcc_werror=""
  47 fi
  48
  49 AC_ARG_WITH([alsa],
  50             [AS_HELP_STRING([--without-alsa],
  51                             [do not build with ALSA support])],
  52             [want_alsa=$withval])
  53 AC_ARG_WITH([oss],
  54             [AS_HELP_STRING([--without-oss],
  55                             [do not build with OSS support])],
  56             [want_oss=$withval])
  57 AC_ARG_WITH([coreaudio],
  58             [AS_HELP_STRING([--without-coreaudio],
  59                             [do not build with Core Audio support])],
  60             [want_coreaudio=$withval])
  61
  62 AC_MSG_CHECKING([for a known target platform])
  63 case "$host" in
  64 *empeg* )
  65   AC_MSG_RESULT([empeg car stereo])
  66   AC_DEFINE([EMPEG_HOST],[1],[define if host is an empeg car stereo])
  67   # work around broken toolchain
  68   AC_CHECK_LIB([gpg-error], [gpg_strerror])
  69   AC_CHECK_LIB([pthread], [pthread_create])
  70   want_server=no
  71  ;;
  72 *linux* | *Linux* )
  73   AC_MSG_RESULT([Linux])
  74   want_server=yes
  75   ;;
  76 *-apple-darwin* )
  77   AC_MSG_RESULT([Mac OS X])
  78   want_server=yes
  79   if test $want_coreaudio = yes; then
  80     COREAUDIO="-framework CoreAudio"
  81   fi
  82   ;;
  83 * )
  84   AC_MSG_RESULT([unknown, winging it])
  85   want_server=no
  86   ;;
  87 esac
  88 AC_SUBST([COREAUDIO])
  89
  90 AC_ARG_WITH([server],
  91             [AS_HELP_STRING([--without-server],
  92                             [do not build server])],
  93             [want_server=$withval])
  94 AC_ARG_WITH([gtk],
  95             [AS_HELP_STRING([--without-gtk],
  96                             [do not build GTK+ client])],
  97             [want_gtk=$withval])
  98 AC_ARG_WITH([python],
  99             [AS_HELP_STRING([--without-python],
 100                             [do not build Python support])],
 101             [want_python=$withval])
 102
 103 subdirs="scripts lib clients doc examples debian"
 104
 105 if test $want_server = yes; then
 106   subdirs="${subdirs} server plugins driver templates sounds images"
 107 fi
 108 if test $want_python = yes; then
 109   AM_PATH_PYTHON
 110   subdirs="${subdirs} python"
 111 fi
 112 if test $want_gtk = yes; then
 113   subdirs="${subdirs} disobedience"
 114   if test $want_server = no; then
 115     subdirs="${subdirs} images"
 116   fi
 117 fi
 118 subdirs="${subdirs} tests"
 119 AC_SUBST([subdirs])
 120
 121 # libtool config
 122 AC_LIBTOOL_DLOPEN
 123 AC_DISABLE_STATIC
 124
 125 AC_PROG_LIBTOOL
 126
 127 missing_libraries=""
 128 missing_headers=""
 129 missing_functions=""
 130
 131 AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])
 132
 133 # Macs might have libraries under fink's root
 134 AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
 135 if test "x$FINK" != xnone; then
 136   AC_CACHE_CHECK([fink install directory],[rjk_cv_finkprefix],[
 137     rjk_cv_finkprefix="`echo "$FINK" | sed 's,/bin/fink$,,'`"
 138   ])
 139   finkdir="${rjk_cv_finkprefix}"
 140   finkbindir="${rjk_cv_finkprefix}/bin"
 141   CPPFLAGS="${CPPFLAGS} -I${rjk_cv_finkprefix}/include/gc -I${rjk_cv_finkprefix}/include"
 142   if test $want_server = yes; then
 143     CPPFLAGS="${CPPFLAGS} -I${rjk_cv_finkprefix}/include/db4"
 144   fi
 145   LDFLAGS="${LDFLAGS} -L${rjk_cv_finkprefix}/lib"
 146 else
 147   finkbindir=""
 148 fi
 149 AC_SUBST([finkdir])
 150 AC_SUBST([finkbindir])
 151
 152 # Checks for libraries.
 153 # We save up a list of missing libraries that we can't do without
 154 # and report them all at once.
 155 AC_CHECK_LIB(gc, GC_malloc,            [AC_SUBST(LIBGC,[-lgc])],
 156             [missing_libraries="$missing_libraries libgc"])
 157 AC_CHECK_LIB(gcrypt, gcry_md_open,
 158              [AC_SUBST(LIBGCRYPT,[-lgcrypt])],
 159             [missing_libraries="$missing_libraries libgcrypt"])
 160 AC_CHECK_LIB(pcre, pcre_compile,
 161              [AC_SUBST(LIBPCRE,[-lpcre])],
 162              [missing_libraries="$missing_libraries libpcre"])
 163 if test $want_alsa = yes; then
 164   AC_CHECK_LIB([asound], [snd_pcm_open],
 165                [AC_SUBST(LIBASOUND,[-lasound])])
 166 fi
 167 if test $want_server = yes; then
 168   RJK_CHECK_LIB(db, db_create, [#include <db.h>],
 169                [AC_SUBST(LIBDB,[-ldb])],
 170                [missing_libraries="$missing_libraries libdb"])
 171   AC_CHECK_LIB(vorbis, vorbis_info_clear,
 172                [:],
 173                [missing_libraries="$missing_libraries libvorbis"])
 174   AC_CHECK_LIB(vorbisfile, ov_open,
 175                [AC_SUBST(LIBVORBISFILE,["-lvorbisfile -lvorbis"])],
 176                [missing_libraries="$missing_libraries libvorbisfile"],
 177                [-lvorbis])
 178   AC_CHECK_LIB(mad, mad_stream_init,
 179                [AC_SUBST(LIBMAD,[-lmad])],
 180                [missing_libraries="$missing_libraries libmad"])
 181   AC_CHECK_LIB([ao], [ao_initialize],
 182                [AC_SUBST(LIBAO,[-lao])],
 183                [missing_libraries="$missing_libraries libao"])
 184   AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new],
 185                [AC_SUBST(LIBFLAC,[-lFLAC])],
 186                [missing_libraries="$missing_libraries libFLAC"])
 187 fi
 188
 189 if test $want_gtk = yes; then
 190   AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
 191   AM_PATH_GTK_2_0([],[],[missing_libraries="$missing_libraries libgtk"])
 192 fi
 193
 194 # Some platforms have iconv already
 195 AC_CHECK_FUNC(iconv_open, [:],
 196               [RJK_CHECK_LIB(iconv, iconv_open, [#include <iconv.h>],
 197                             [AC_SUBST(LIBICONV,[-liconv])],
 198                             [missing_functions="$missing_functions iconv_open"])])
 199 AC_CHECK_FUNC([gethostbyname],[:],[
 200   AC_CHECK_LIB(nsl,gethostbyname,
 201                [AC_SUBST(LIBNSL,[-lnsl])],
 202                [missing_functions="$missing_functions gethostbyname"])])
 203 AC_CHECK_FUNC([socket],[:],[
 204   AC_CHECK_LIB(socket,socket,
 205                [AC_SUBST(LIBSOCKET,[-lsocket])],
 206                [missing_functions="$missing_functions socket"])])
 207 AC_CHECK_FUNC([dlopen],[:],[
 208   AC_CHECK_LIB(dl,dlopen,
 209                [AC_SUBST(LIBDL,[-ldl])],
 210                [missing_functions="$missing_functions dlopen"])])
 211
 212 if test ! -z "$missing_libraries"; then
 213   AC_MSG_ERROR([missing libraries:$missing_libraries])
 214 fi
 215
 216 # We require that libpcre support UTF-8
 217 RJK_REQUIRE_PCRE_UTF8([-lpcre])
 218
 219 # Checks for header files.
 220 RJK_FIND_GC_H
 221 if test $want_oss = yes; then
 222   AC_CHECK_HEADERS([sys/soundcard.h])
 223 fi
 224 if test $want_alsa = yes; then
 225   AC_CHECK_HEADERS([alsa/asoundlib.h])
 226 fi
 227 if test $want_coreaudio = yes; then
 228   AC_CHECK_HEADERS([CoreAudio/AudioHardware.h])
 229 fi
 230 AC_CHECK_HEADERS([inttypes.h])
 231 # We don't bother checking very standard stuff
 232 # Compilation will fail if any of these headers are missing, so we
 233 # check for them here and fail early.
 234 if test $want_server = yes; then
 235   AC_CHECK_HEADERS([db.h],[:],[
 236     missing_headers="$missing_headers $ac_header"
 237   ])
 238 fi
 239 AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
 240                  getopt.h iconv.h langinfo.h \
 241                  pcre.h sys/ioctl.h \
 242                  syslog.h unistd.h],[:],[
 243   missing_headers="$missing_headers $ac_header"
 244 ])
 245
 246 if test ! -z "$missing_headers"; then
 247   AC_MSG_ERROR([missing headers:$missing_headers])
 248 fi
 249
 250 # Checks for typedefs, structures, and compiler characteristics.
 251 AC_C_CONST
 252 AC_TYPE_SIZE_T
 253 AC_C_INLINE
 254 AC_C_BIGENDIAN
 255 AC_CHECK_TYPES([struct sockaddr_in6],,,[AC_INCLUDES_DEFAULT
 256 #include <netinet/in.h>])
 257
 258 # enable -Werror when we check for certain characteristics:
 259
 260 old_CFLAGS="${CFLAGS}"
 261 CFLAGS="${CFLAGS} $gcc_werror"
 262 AC_CHECK_TYPES([long long,uint32_t,uint8_t,intmax_t,uintmax_t])
 263
 264 # Some GCC invocations warn for converting function pointers to void *.
 265 # This is fair enough, as it's technically forbidden, but we use dlsym()
 266 # which can pretty much only exist if object and function pointers are
 267 # interconvertable.  So we disable -Werror if need be.
 268 if test ! -z "$gcc_werror"; then
 269   AC_CACHE_CHECK([whether function pointers can be converted to void * without a warning],
 270                  [rjk_cv_function_pointer_cast],[
 271     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 272   void somefunction(void);],
 273                       [(void *)somefunction])],
 274                       [rjk_cv_function_pointer_cast=yes],
 275                       [rjk_cv_function_pointer_cast=no])])
 276   if test $rjk_cv_function_pointer_cast = no; then
 277     gcc_werror=""
 278   fi
 279 fi
 280
 281 CFLAGS="${old_CFLAGS}"
 282
 283 # gcrypt maintainers keep changing everything.  Design your interface
 284 # first, then implement it once, rather than getting it wrong three or
 285 # four times and shipping between each attempt.
 286 AC_CACHE_CHECK([for hash handle type in <grypt.h>],
 287                [rjk_cv_gcrypt_hash_handle],[
 288   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 289 #include <gcrypt.h>
 290 ],
 291                [gcry_md_hd_t h;])],
 292                [rjk_cv_gcrypt_hash_handle=gcry_md_hd_t],[
 293     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 294 #include <gcrypt.h>
 295 ],
 296                  [GcryMDHd h;])],
 297                  [rjk_cv_gcrypt_hash_handle=GcryMDHd],
 298                  [rjk_cv_gcrypt_hash_handle=GCRY_MD_HD])])])
 299 AC_DEFINE_UNQUOTED([gcrypt_hash_handle],[$rjk_cv_gcrypt_hash_handle],
 300                    [libgcrypt hash handle type])
 301
 302 AC_CACHE_CHECK([for gcry_error_t in <grypt.h>],
 303                [rjk_cv_have_gcry_error_t],[
 304   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 305 #include <gcrypt.h>
 306 ],
 307                  [gcry_error_t e;])],
 308                  [rjk_cv_have_gcry_error_t=yes],
 309                  [rjk_cv_have_gcry_error_t=no])])
 310 if test $rjk_cv_have_gcry_error_t = yes; then
 311   AC_DEFINE([HAVE_GCRY_ERROR_T],1,[define if <gcrypt.h> defines gcry_error_t])
 312 fi
 313
 314 # Checks for functions
 315 if test $ac_cv_type_long_long = yes; then
 316   AC_CHECK_FUNCS([atoll strtoll],[:],[
 317     missing_functions="$missing_functions $ac_func"
 318   ])
 319   # Darwin sometimes fails to declare strtoll (e.g. if you ask for -std=c99)
 320   AC_CACHE_CHECK([whether strtoll is declared in <stdlib.h>],
 321                  [rjk_cv_strtoll_declared],[
 322     AC_EGREP_HEADER([strtoll], [stdlib.h],
 323                     [rjk_cv_strtoll_declared=yes],
 324                     [rjk_cv_strtoll_declared=no])])
 325   if test $rjk_cv_strtoll_declared = yes; then
 326     AC_DEFINE([DECLARES_STRTOLL],[1],[define if <stdlib.h> declares strtoll])
 327   fi
 328   AC_CACHE_CHECK([whether atoll is declared in <stdlib.h>],
 329                  [rjk_cv_atoll_declared],[
 330     AC_EGREP_HEADER([atoll], [stdlib.h],
 331                     [rjk_cv_atoll_declared=yes],
 332                     [rjk_cv_atoll_declared=no])])
 333   if test $rjk_cv_atoll_declared = yes; then
 334     AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
 335   fi
 336 fi
 337 AC_CHECK_FUNCS([ioctl nl_langinfo strsignal],[:],[
 338   missing_functions="$missing_functions $ac_func"
 339 ])
 340 # fsync will do if fdatasync not available
 341 AC_CHECK_FUNCS([fdatasync],[:],[
 342   AC_CHECK_FUNCS([fsync],
 343                  [AC_DEFINE([fdatasync],[fsync],[define fdatasync to fsync if not available])],
 344                  [missing_functions="$missing_functions fdatasync"])])
 345 if test ! -z "$missing_functions"; then
 346   AC_MSG_ERROR([missing functions:$missing_functions])
 347 fi
 348 if test $want_server = yes; then
 349   # <db.h> had better be version 3 or later
 350   AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
 351     AC_PREPROC_IFELSE([
 352                        #include <db.h>
 353                        #ifndef DB_VERSION_MAJOR
 354                        # error cannot determine db version
 355                        #endif
 356                        #if DB_VERSION_MAJOR < 4
 357                        # error inadequate db version
 358                        #endif
 359                        #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR < 2
 360                        # error inadequate db version
 361                        #endif
 362                       ],
 363                       [rjk_cv_db_version=ok],
 364                       [rjk_cv_db_version=inadequate])
 365   ])
 366   if test $rjk_cv_db_version != ok; then
 367     AC_MSG_ERROR([need db.h version at least 4.2])
 368   fi
 369 fi
 370
 371 if test "x$GCC" = xyes; then
 372   # a reasonable default set of warnings
 373   CC="${CC} -Wall -W -Wpointer-arith -Wbad-function-cast \
 374         -Wwrite-strings -Wmissing-prototypes \
 375         -Wmissing-declarations -Wnested-externs"
 376
 377   # Fix up GTK+ and GLib compiler flags
 378   GTK_CFLAGS="`echo \"$GTK_CFLAGS\"|sed 's/-I/-isystem /g'`"
 379   GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"|sed 's/-I/-isystem /g'`"
 380
 381   # GCC 2.95 doesn't know to ignore warnings from system headers
 382   AC_CACHE_CHECK([whether -Werror is usable],
 383                   rjk_cv_werror, [
 384     save_CFLAGS="${CFLAGS}"
 385     CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
 386     AC_TRY_COMPILE([#include <gtk/gtk.h>],
 387                    [],
 388                    [rjk_cv_werror=yes],
 389                    [rjk_cv_werror=no])
 390     CFLAGS="${save_CFLAGS}"
 391   ])
 392   if test $rjk_cv_werror = no; then
 393     gcc_werror=''
 394   fi
 395   CC="${CC} $gcc_werror"
 396
 397   # for older GCCs that don't know %ju (etc)
 398   AC_CACHE_CHECK([whether -Wno-format is required],
 399                  rjk_cv_noformat,
 400                  AC_TRY_COMPILE([#include <stdio.h>
 401 #include <stdint.h>
 402 ],
 403                                 [printf("%ju", (uintmax_t)0);],
 404                                 [rjk_cv_noformat=no],
 405                                 [rjk_cv_noformat=yes]))
 406   if test $rjk_cv_noformat = yes; then
 407     CC="${CC} -Wno-format"
 408   fi
 409
 410   AC_CACHE_CHECK([whether -Wshadow is OK],
 411                  rjk_cv_shadow,
 412                  oldCC="${CC}"
 413                  CC="${CC} -Wshadow"
 414                  [AC_TRY_COMPILE([
 415 #include <unistd.h>
 416 #include <vorbis/vorbisfile.h>
 417 ],
 418                                 [],
 419                                 [rjk_cv_shadow=yes],
 420                                 [rjk_cv_shadow=no])
 421                  CC="${oldCC}"])
 422   if test $rjk_cv_shadow = yes; then
 423     CC="${CC} -Wshadow"
 424   fi
 425
 426
 427 fi
 428
 429 AH_BOTTOM([#ifdef __GNUC__
 430 # define attribute(x) __attribute__(x)
 431 #else
 432 # define attribute(x)
 433 #endif])
 434
 435 AC_CONFIG_FILES([Makefile
 436                  templates/Makefile
 437                  images/Makefile
 438                  scripts/Makefile
 439                  lib/Makefile
 440                  server/Makefile
 441                  clients/Makefile
 442                  disobedience/Makefile
 443                  doc/Makefile
 444                  plugins/Makefile
 445                  driver/Makefile
 446                  debian/Makefile
 447                  sounds/Makefile
 448                  python/Makefile
 449                  examples/Makefile
 450                  tests/Makefile])
 451 AC_OUTPUT