mdw@git.distorted.org.uk Git - clg/blob - gtk/gtkobject.lisp

   1 ;; Common Lisp bindings for GTK+ v2.0
   2 ;; Copyright (C) 1999-2000 Espen S. Johnsen <espejohn@online.no>
   3 ;;
   4 ;; This library is free software; you can redistribute it and/or
   5 ;; modify it under the terms of the GNU Lesser General Public
   6 ;; License as published by the Free Software Foundation; either
   7 ;; version 2 of the License, or (at your option) any later version.
   8 ;;
   9 ;; This library is distributed in the hope that it will be useful,
  10 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 ;; Lesser General Public License for more details.
  13 ;;
  14 ;; You should have received a copy of the GNU Lesser General Public
  15 ;; License along with this library; if not, write to the Free Software
  16 ;; Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18 ;; $Id: gtkobject.lisp,v 1.4 2000-08-16 22:16:23 espen Exp $
  19
  20
  21 (in-package "GTK")
  22
  23 ;;;; Misc utils
  24
  25 (defun name-to-string (name)
  26   (substitute #\_ #\- (string-downcase (string name))))
  27
  28 (defun string-to-name (name &optional (package "KEYWORD"))
  29   (intern (substitute #\- #\_ (string-upcase name)) package))
  30
  31
  32 ;;;; Argument stuff
  33
  34 (deftype arg () 'pointer)
  35
  36 (defconstant +arg-type-offset+ 0)
  37 (defconstant +arg-name-offset+ 4)
  38 (defconstant +arg-value-offset+ 8)
  39 (defconstant +arg-size+ 16)
  40
  41 (define-foreign arg-new () arg
  42   (type type-number))
  43
  44 (define-foreign %arg-free () nil
  45   (arg arg)
  46   (free-contents boolean))
  47
  48 (defun arg-free (arg free-contents &optional alien)
  49   (cond
  50    (alien (%arg-free arg free-contents))
  51    (t
  52     (unless (null-pointer-p arg)
  53       (when free-contents
  54         (funcall
  55          (get-destroy-function (type-from-number (arg-type arg)))
  56          arg +arg-value-offset+))
  57       (deallocate-memory arg)))))
  58
  59 (define-foreign %arg-reset () nil
  60   (arg arg))
  61
  62 (defun arg-name (arg)
  63   (funcall (get-reader-function '(static string)) arg +arg-name-offset+))
  64
  65 (defun (setf arg-name) (name arg)
  66   (funcall (get-writer-function '(static string)) name arg +arg-name-offset+)
  67   name)
  68
  69 (defun arg-type (arg)
  70   (system:sap-ref-32 arg +arg-type-offset+))
  71
  72 (defun (setf arg-type) (type arg)
  73   (setf (system:sap-ref-32 arg +arg-type-offset+) type))
  74
  75 (defun arg-value (arg &optional (type (type-from-number (arg-type arg))))
  76   (funcall (get-reader-function type) arg +arg-value-offset+))
  77
  78 ;; One should never call this function on an arg whose value is already set
  79 (defun (setf arg-value)
  80     (value arg &optional (type (type-from-number (arg-type arg))))
  81   (funcall (get-writer-function type) value arg +arg-value-offset+)
  82   value)
  83
  84 (defun (setf return-arg-value)
  85     (value arg &optional (type (type-from-number (arg-type arg))))
  86   ; this is probably causing a memory leak
  87   (funcall (get-writer-function type) value (arg-value arg 'pointer) 0)
  88   value)
  89
  90 (defun arg-array-ref (arg0 index)
  91   (system:sap+ arg0 (* index +arg-size+)))
  92
  93
  94 ;;;; Superclass for the gtk class hierarchy
  95
  96 (eval-when (:compile-toplevel :load-toplevel :execute)
  97   (defclass object (gobject)
  98     ()
  99 ;   ((flags
 100 ;     :allocation :alien
 101 ;     :accessor object-flags
 102 ;     :type object-flags))
 103     (:metaclass gobject-class)
 104     (:alien-name "GtkObject")))
 105
 106
 107 (defmethod shared-initialize ((object object) names &rest initargs &key signals)
 108   (declare (ignore initargs names))
 109   (call-next-method)
 110   (dolist (signal signals)
 111     (apply #'signal-connect object signal)))
 112
 113
 114 (defmethod initialize-instance :after ((object object) &rest initargs &key)
 115   (declare (ignore initargs))
 116   (object-default-construct object)
 117   (reference-instance object)
 118   (object-sink object))
 119
 120
 121 (defmethod from-alien-initialzie-instance ((object object) &rest initargs)
 122   (declare (ignore initargs))
 123   (call-next-method)
 124   (object-sink object))
 125
 126
 127 (define-foreign object-default-construct () nil
 128   (object object))
 129
 130 (define-foreign object-sink () nil
 131   (object object))
 132
 133 (define-foreign ("gtk_object_getv" object-get-arg) () nil
 134   (object object)
 135   (1 unsigned-int)
 136   (arg arg))
 137
 138 (define-foreign ("gtk_object_setv" object-set-arg) () nil
 139   (object object)
 140   (1 unsigned-int)
 141   (arg arg))
 142
 143 (defun object-arg (object name)
 144   (with-gc-disabled
 145     (let ((arg (arg-new 0)))
 146       (setf (arg-name arg) name)
 147       (object-get-arg object arg)
 148       (let ((type (type-from-number (arg-type arg))))
 149         (prog1
 150             (arg-value arg type)
 151           (arg-free arg t))))))
 152
 153 (defun (setf object-arg) (value object name)
 154   (with-gc-disabled
 155     (let ((arg (arg-new 0)))
 156       (setf (arg-name arg) name)
 157       (object-get-arg object arg)
 158       (let* ((type-number (arg-type arg))
 159              (type (type-from-number type-number)))
 160         (%arg-reset arg)
 161         (setf (arg-type arg) type-number)
 162         (setf (arg-value arg type) value)
 163         (object-set-arg object arg)
 164         (arg-free arg t))))
 165   value)
 166
 167
 168 ;;;; Callback and user data mechanism
 169
 170 (declaim (fixnum *user-data-count*))
 171
 172 (defvar *user-data* (make-hash-table))
 173 (defvar *user-data-count* 0)
 174
 175 (defun register-user-data (object &optional destroy-function)
 176   (check-type destroy-function (or null symbol function))
 177 ;  (incf *user-data-count*)
 178   (setq *user-data-count* (the fixnum (1+ *user-data-count*)))
 179   (setf
 180    (gethash *user-data-count* *user-data*)
 181    (cons object destroy-function))
 182   *user-data-count*)
 183
 184
 185 (defun find-user-data (id)
 186   (check-type id fixnum)
 187   (multiple-value-bind (user-data p) (gethash id *user-data*)
 188     (values (car user-data) p)))
 189
 190
 191 (defun register-callback-function (function)
 192   (check-type function (or null symbol function))
 193   ; We treat callbacks just as ordinary user data
 194   (register-user-data function))
 195
 196
 197 (defun callback-trampoline (callback-id nargs arg-array)
 198   (declare (fixnum callback-id nargs))
 199   (let* ((return-arg (unless (null-pointer-p arg-array)
 200                        (arg-array-ref arg-array nargs)))
 201          (return-type (if return-arg
 202                           (type-from-number (arg-type return-arg))
 203                         nil))
 204          (args nil)
 205          (callback-function (find-user-data callback-id)))
 206
 207     (dotimes (n nargs)
 208       (push (arg-value (arg-array-ref arg-array (- nargs n 1))) args))
 209
 210     (labels ((invoke-callback ()
 211                (restart-case
 212                    (unwind-protect
 213                        (let ((return-value (apply callback-function args)))
 214                          (when return-type
 215                            (setf (return-arg-value return-arg) return-value))))
 216
 217                  (continue nil :report "Return from callback function"
 218                   (when return-type
 219                     (format
 220                      *query-io*
 221                      "Enter return value of type ~S: "
 222                      return-type)
 223                     (force-output *query-io*)
 224                     (setf
 225                      (return-arg-value return-arg)
 226                      (eval (read *query-io*)))))
 227                  (re-invoke nil :report "Re-invoke callback function"
 228                   (invoke-callback)))))
 229       (invoke-callback))))
 230
 231
 232 (defun destroy-user-data (id)
 233   (check-type id fixnum)
 234   (let ((user-data (gethash id *user-data*)))
 235     (when (cdr user-data)
 236       (funcall (cdr user-data) (car user-data))))
 237   (remhash id *user-data*))
 238
 239
 240 (defvar *callback-marshal* (system:foreign-symbol-address "callback_marshal"))
 241 (defvar *destroy-marshal* (system:foreign-symbol-address "destroy_marshal"))
 242
 243 (defun after-gc-hook ()
 244   (setf
 245    (extern-alien "callback_trampoline" system-area-pointer)
 246    (make-pointer (kernel:get-lisp-obj-address #'callback-trampoline))
 247    (extern-alien "destroy_user_data" system-area-pointer)
 248    (make-pointer (kernel:get-lisp-obj-address #'destroy-user-data))))
 249
 250 (pushnew 'after-gc-hook ext:*after-gc-hooks*)
 251 (after-gc-hook)
 252
 253
 254
 255 ;;;; Main loop, timeouts and idle functions
 256
 257 (declaim (inline events-pending-p main-iteration))
 258
 259 (define-foreign ("gtk_events_pending" events-pending-p) () boolean)
 260
 261 (define-foreign get-current-event () gdk:event)
 262
 263 (define-foreign main-do-event () nil
 264   (event gdk:event))
 265
 266 (define-foreign main () nil)
 267
 268 (define-foreign main-level () int)
 269
 270 (define-foreign main-quit () nil)
 271
 272 (define-foreign
 273     ("gtk_main_iteration_do" main-iteration) (&optional (blocking t)) boolean
 274   (blocking boolean))
 275
 276 (defun main-iterate-all (&rest args)
 277   (declare (ignore args))
 278   (when (events-pending-p)
 279     (main-iteration nil)
 280     (main-iterate-all)))
 281
 282 (define-foreign ("gtk_timeout_add_full" timeout-add)
 283     (interval function) unsigned-int
 284   (interval (unsigned 32))
 285   (0 unsigned-long)
 286   (*callback-marshal* pointer)
 287   ((register-callback-function function) unsigned-long)
 288   (*destroy-marshal* pointer))
 289
 290 (define-foreign timeout-remove () nil
 291   (timeout-handler-id unsigned-int))
 292
 293 (define-foreign ("gtk_idle_add_full" idle-add)
 294     (function &optional (priority 200)) unsigned-int
 295   (priority int)
 296   (0 unsigned-long)
 297   (*callback-marshal* pointer)
 298   ((register-callback-function function) unsigned-long)
 299   (*destroy-marshal* pointer))
 300
 301 (define-foreign idle-remove () nil
 302   (idle-handler-id unsigned-int))
 303
 304
 305 (system:add-fd-handler (gdk:event-poll-fd) :input #'main-iterate-all)
 306 (setq lisp::*periodic-polling-function* #'main-iterate-all)
 307 (setq lisp::*max-event-to-sec* 0)
 308 (setq lisp::*max-event-to-usec* 1000)
 309
 310
 311
 312 ;;;; Signals
 313
 314 (define-foreign %signal-emit-stop () nil
 315   (object object)
 316   (signal-id unsigned-int))
 317
 318 (define-foreign %signal-emit-stop-by-name (object signal) nil
 319   (object object)
 320   ((name-to-string signal) string))
 321
 322 (defun signal-emit-stop (object signal)
 323   (if (numberp signal)
 324       (%signal-emit-stop object signal)
 325     (%signal-emit-stop-by-name object signal)))
 326
 327 (define-foreign %signal-connect-full
 328     (object signal function after) unsigned-int
 329   (object object)
 330   ((name-to-string signal) string)
 331   (0 unsigned-long)
 332   (*callback-marshal* pointer)
 333   ((register-callback-function function) unsigned-long)
 334   (*destroy-marshal* pointer)
 335   (nil boolean)
 336   (after boolean))
 337
 338 (defun signal-connect (object signal function
 339                        &key after ((:object callback-object)))
 340   (let* ((callback-object (if (eq callback-object t)
 341                               object
 342                             callback-object))
 343          (callback-function
 344           (if callback-object
 345               #'(lambda (&rest args) (apply function callback-object args))
 346             function)))
 347     (%signal-connect-full object signal callback-function after)))
 348
 349 (define-foreign signal-disconnect () nil
 350   (object object)
 351   (handler unsigned-int))
 352
 353 (define-foreign signal-handler-block () nil
 354   (object object)
 355   (handler unsigned-int))
 356
 357 (define-foreign signal-handler-unblock () nil
 358   (object object)
 359   (handler unsigned-int))
 360
 361
 362 ;;;; Metaclass used for subclasses of object
 363
 364 (eval-when (:compile-toplevel :load-toplevel :execute)
 365   (defclass object-class (gobject-class))
 366
 367   (defclass direct-object-slot-definition (direct-virtual-slot-definition))
 368
 369   (defclass effective-object-slot-definition
 370     (effective-virtual-slot-definition)))
 371
 372
 373 (defmethod initialize-instance :after ((slotd direct-object-slot-definition)
 374                                    &rest initargs &key)
 375   (declare (ignore initargs))
 376   (unless (slot-boundp slotd 'location)
 377     (with-slots (pcl::name location pcl::class) slotd
 378       (setf
 379        location
 380        (format nil "~A::~A"
 381         (alien-type-name (class-name pcl::class))
 382         (name-to-string pcl::name))))))
 383
 384
 385 (defmethod direct-slot-definition-class ((class object-class) initargs)
 386   (case (getf initargs :allocation)
 387     (:arg (find-class 'direct-object-slot-definition))
 388     (t (call-next-method))))
 389
 390
 391 (defmethod effective-slot-definition-class ((class object-class) initargs)
 392   (case (getf initargs :allocation)
 393     (:arg (find-class 'effective-object-slot-definition))
 394     (t (call-next-method))))
 395
 396
 397 (defmethod compute-virtual-slot-location
 398     ((class object-class) (slotd effective-object-slot-definition)
 399      direct-slotds)
 400   (with-slots (type) slotd
 401     (let ((location (slot-definition-location (first direct-slotds)))
 402           (type-number (find-type-number type))
 403           (reader (get-reader-function type))
 404           (writer (get-writer-function type))
 405           (destroy (get-destroy-function type)))
 406       (list
 407        #'(lambda (object)
 408            (with-gc-disabled
 409              (let ((arg (arg-new type-number)))
 410                (setf (arg-name arg) location)
 411                (object-get-arg object arg)
 412                (prog1
 413                    (funcall reader arg +arg-value-offset+)
 414                  (arg-free arg t t)))))
 415        #'(lambda (value object)
 416            (with-gc-disabled
 417              (let ((arg (arg-new type-number)))
 418                (setf (arg-name arg) location)
 419                (funcall writer value arg +arg-value-offset+)
 420                (object-set-arg object arg)
 421                (funcall destroy arg +arg-value-offset+)
 422                (arg-free arg nil)
 423                value)))))))
 424
 425
 426 (defmethod validate-superclass ((class object-class)
 427                                 (super pcl::standard-class))
 428   (subtypep (class-name super) 'object))
 429
 430
 431 ;;;; Metaclasses used for widgets and containers
 432
 433 (eval-when (:compile-toplevel :load-toplevel :execute)
 434   (defclass widget-class (object-class))
 435
 436   (defclass container-class (widget-class)
 437     (child-class)))
 438
 439
 440 (defvar *child-to-container-class-mappings* (make-hash-table))
 441
 442 (defmethod shared-initialize ((class container-class) names
 443                               &rest initargs &key name child-class)
 444   (declare (ignore initargs))
 445   (call-next-method)
 446   (with-slots ((child-class-slot child-class)) class
 447     (setf
 448      child-class-slot
 449      (or
 450       (first child-class)
 451       (intern (format nil "~A-CHILD" (or name (class-name class)))))
 452      (gethash child-class-slot *child-to-container-class-mappings*)
 453      class)))
 454
 455
 456 (defmethod validate-superclass ((class widget-class)
 457                                 (super pcl::standard-class))
 458   (subtypep (class-name super) 'widget))
 459
 460 (defmethod validate-superclass ((class container-class)
 461                                 (super pcl::standard-class))
 462   (subtypep (class-name super) 'container))
 463
 464
 465
 466 ;;;; Metaclass for child classes
 467
 468 (eval-when (:compile-toplevel :load-toplevel :execute)
 469   (defclass child-class (virtual-class))
 470
 471   (defclass direct-child-slot-definition (direct-virtual-slot-definition))
 472
 473   (defclass effective-child-slot-definition
 474     (effective-virtual-slot-definition)))
 475
 476
 477 (defmethod initialize-instance  ((slotd direct-child-slot-definition)
 478                                  &rest initargs &key)
 479   (declare (ignore initargs))
 480   (call-next-method)
 481   (unless (slot-boundp slotd 'location)
 482     (with-slots (pcl::name location pcl::class) slotd
 483       (setf
 484        location
 485        (format nil "~A::~A"
 486         (alien-type-name
 487          (gethash (class-name pcl::class) *child-to-container-class-mappings*))
 488         (name-to-string pcl::name))))))
 489
 490
 491 (defmethod direct-slot-definition-class ((class child-class) initargs)
 492   (case (getf initargs :allocation)
 493     (:arg (find-class 'direct-child-slot-definition))
 494     (t (call-next-method))))
 495
 496
 497 (defmethod effective-slot-definition-class ((class child-class) initargs)
 498   (case (getf initargs :allocation)
 499     (:arg (find-class 'effective-child-slot-definition))
 500     (t (call-next-method))))
 501
 502
 503 (defmethod compute-virtual-slot-location
 504     ((class child-class) (slotd effective-child-slot-definition) direct-slotds)
 505   (with-slots (type) slotd
 506     (let ((location (slot-definition-location (first direct-slotds)))
 507           (type-number (find-type-number type))
 508           (reader (get-reader-function type))
 509           (writer (get-writer-function type))
 510           (destroy (get-destroy-function type)))
 511       (list
 512        #'(lambda (object)
 513            (with-slots (parent child) object
 514              (with-gc-disabled
 515                (let ((arg (arg-new type-number)))
 516                  (setf (arg-name arg) location)
 517                  (container-child-get-arg parent child arg)
 518                  (prog1
 519                      (funcall reader arg +arg-value-offset+)
 520                    (arg-free arg t t))))))
 521        #'(lambda (value object)
 522            (with-slots (parent child) object
 523              (with-gc-disabled
 524                (let ((arg (arg-new type-number)))
 525                  (setf (arg-name arg) location)
 526                  (funcall writer value arg +arg-value-offset+)
 527                  (container-child-set-arg parent child arg)
 528                  (funcall destroy arg +arg-value-offset+)
 529                  (arg-free arg nil)
 530                  value))))))))
 531
 532
 533 (defmethod pcl::add-reader-method ((class child-class) generic-function slot-name)
 534   (add-method
 535    generic-function
 536    (make-instance 'standard-method
 537                   :specializers (list (find-class 'widget))
 538                   :lambda-list '(widget)
 539                   :function #'(lambda (args next-methods)
 540                                 (declare (ignore next-methods))
 541                                 (child-slot-value (first args) slot-name)))))
 542
 543 (defmethod pcl::add-writer-method
 544     ((class child-class) generic-function slot-name)
 545   (add-method
 546    generic-function
 547    (make-instance 'standard-method
 548                   :specializers (list (find-class t) (find-class 'widget))
 549                   :lambda-list '(value widget)
 550                   :function #'(lambda (args next-methods)
 551                                 (declare (ignore next-methods))
 552                                 (destructuring-bind (value widget) args
 553                                   (setf
 554                                    (child-slot-value widget slot-name)
 555                                    value))))))
 556
 557
 558 (defmethod validate-superclass ((class child-class) (super pcl::standard-class))
 559   (subtypep (class-name super) 'container-child))
 560
 561