mdw@git.distorted.org.uk Git - clg/blob - gtk/gtkobject.lisp

   1 ;; Common Lisp bindings for GTK+ v2.x
   2 ;; Copyright 1999-2005 Espen S. Johnsen <espen@users.sf.net>
   3 ;;
   4 ;; Permission is hereby granted, free of charge, to any person obtaining
   5 ;; a copy of this software and associated documentation files (the
   6 ;; "Software"), to deal in the Software without restriction, including
   7 ;; without limitation the rights to use, copy, modify, merge, publish,
   8 ;; distribute, sublicense, and/or sell copies of the Software, and to
   9 ;; permit persons to whom the Software is furnished to do so, subject to
  10 ;; the following conditions:
  11 ;;
  12 ;; The above copyright notice and this permission notice shall be
  13 ;; included in all copies or substantial portions of the Software.
  14 ;;
  15 ;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  16 ;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 ;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  18 ;; IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  19 ;; CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 ;; TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 ;; SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 ;; $Id: gtkobject.lisp,v 1.41 2007-05-10 20:13:42 espen Exp $
  24
  25
  26 (in-package "GTK")
  27
  28
  29 ;;;; Superclass for the gtk class hierarchy
  30
  31 (eval-when (:compile-toplevel :load-toplevel :execute)
  32   (init-types-in-library
  33    #.(concatenate 'string (pkg-config:pkg-variable "gtk+-2.0" "libdir")
  34                           "/libgtk-x11-2.0." asdf:*dso-extension*))
  35
  36   (defclass %object (gobject)
  37     ()
  38     (:metaclass gobject-class)
  39     (:gtype |gtk_object_get_type|)))
  40
  41
  42 (defmethod initialize-instance ((object %object) &rest initargs &key signal)
  43   (declare (ignore signal))
  44   (call-next-method)
  45   (dolist (signal-definition (get-all initargs :signal))
  46     (apply #'signal-connect object signal-definition)))
  47
  48 (defmethod initialize-instance :around ((object %object) &rest initargs)
  49   (declare (ignore initargs))
  50   (call-next-method)
  51   ;; Add a temorary reference which will be removed when the object is
  52   ;; sinked
  53   (funcall (reference-function '%object) (foreign-location object))
  54   (%object-sink object))
  55
  56 (defbinding %object-sink () nil
  57   (object %object))
  58
  59 ;;;; Main loop and event handling
  60
  61 (defbinding events-pending-p () boolean)
  62
  63 (defbinding get-current-event () gdk:event)
  64
  65 (defbinding main-do-event () nil
  66   (event gdk:event))
  67
  68 (defbinding main () nil)
  69
  70 (defbinding main-level () int)
  71
  72 (defbinding main-quit () nil)
  73
  74 (defbinding main-iteration-do (&optional (blocking t)) boolean
  75   (blocking boolean))
  76
  77 (defun main-iterate-all (&rest args)
  78   (declare (ignore args))
  79   (loop
  80    while (events-pending-p)
  81    do (main-iteration-do nil))
  82   #+clisp 0)
  83
  84
  85 ;;;; Metaclass for child classes
  86
  87 (defvar *container-to-child-class-mappings* (make-hash-table))
  88
  89 (eval-when (:compile-toplevel :load-toplevel :execute)
  90   (defclass container-child-class (virtual-slots-class)
  91     ())
  92
  93   (defclass direct-child-slot-definition (direct-virtual-slot-definition)
  94     ((pname :reader slot-definition-pname :initarg :pname)))
  95
  96   (defclass effective-child-slot-definition (effective-virtual-slot-definition)
  97     ((pname :reader slot-definition-pname :initarg :pname))))
  98
  99
 100 (defmethod shared-initialize ((class container-child-class) names &key container)
 101   (declare (ignore names))
 102   (call-next-method)
 103   (setf
 104    (gethash (find-class (first container)) *container-to-child-class-mappings*)
 105     class)
 106   #+clisp
 107   (loop
 108    for slotd in (class-direct-slots class)
 109    when (typep slotd 'direct-child-slot-definition)
 110    do (loop
 111        for reader in (slot-definition-readers slotd)
 112        do (add-reader-method class
 113            (ensure-generic-function reader :lambda-list '(object))
 114            (slot-definition-name slotd)))
 115       (loop
 116        for writer in (slot-definition-writers slotd)
 117        do (add-writer-method class
 118            (ensure-generic-function writer :lambda-list '(value object))
 119            (slot-definition-name slotd)))))
 120
 121 (defmethod direct-slot-definition-class ((class container-child-class) &rest initargs)
 122   (case (getf initargs :allocation)
 123     (:property (find-class 'direct-child-slot-definition))
 124     (t (call-next-method))))
 125
 126 (defmethod effective-slot-definition-class ((class container-child-class) &rest initargs)
 127   (case (getf initargs :allocation)
 128     (:property (find-class 'effective-child-slot-definition))
 129     (t (call-next-method))))
 130
 131 (defmethod compute-effective-slot-definition-initargs ((class container-child-class) direct-slotds)
 132   (if (eq (slot-definition-allocation (first direct-slotds)) :property)
 133       (nconc
 134        (list :pname (most-specific-slot-value direct-slotds 'pname))
 135        (call-next-method))
 136     (call-next-method)))
 137
 138 (defmethod slot-readable-p ((slotd effective-child-slot-definition))
 139   (declare (ignore slotd))
 140   t)
 141
 142 (defmethod compute-slot-reader-function ((slotd effective-child-slot-definition) &optional signal-unbound-p)
 143   (declare (ignore signal-unbound-p))
 144   (let* ((type (slot-definition-type slotd))
 145          (pname (slot-definition-pname slotd))
 146          (reader (reader-function type :ref :get)))
 147     #'(lambda (object)
 148         (with-slots (parent child) object
 149           (with-memory (gvalue +gvalue-size+)
 150             (glib::%gvalue-init gvalue (find-type-number type))
 151             (%container-child-get-property parent child pname gvalue)
 152             (funcall reader gvalue +gvalue-value-offset+))))))
 153
 154 (defmethod slot-writable-p ((slotd effective-child-slot-definition))
 155   (declare (ignore slotd))
 156   t)
 157
 158 (defmethod compute-slot-writer-function ((slotd effective-child-slot-definition))
 159   (let* ((type (slot-definition-type slotd))
 160          (pname (slot-definition-pname slotd))
 161          (writer (writer-function type :temp t))
 162          (destroy (destroy-function type :temp t)))
 163     #'(lambda (value object)
 164         (with-slots (parent child) object
 165           (with-memory (gvalue +gvalue-size+)
 166             (glib::%gvalue-init gvalue (find-type-number type))
 167             (funcall writer value gvalue +gvalue-value-offset+)
 168             (%container-child-set-property parent child pname gvalue)
 169             (funcall destroy gvalue +gvalue-value-offset+))
 170           value))))
 171
 172
 173 (defmethod add-reader-method ((class container-child-class) generic-function slot-name #?(sbcl>= 1 0 2)slot-documentation)
 174   (add-method
 175    generic-function
 176    (make-instance 'standard-method
 177     :specializers (list (find-class 'widget))
 178     :lambda-list '(widget)
 179     :documentation (or #?(sbcl>= 1 0 2)slot-documentation "automatically generated reader method")
 180     :function #'(lambda (args next-methods)
 181                   (declare (ignore next-methods))
 182                   (child-property-value (first args) slot-name)))))
 183
 184 (defmethod add-writer-method ((class container-child-class) generic-function slot-name #?(sbcl>= 1 0 2)slot-documentation)
 185   (add-method
 186    generic-function
 187    (make-instance 'standard-method
 188     :specializers (list (find-class t) (find-class 'widget))
 189     :lambda-list '(value widget)
 190     :documentation (or #?(sbcl>= 1 0 2)slot-documentation "automatically generated reader method")
 191     :function #'(lambda (args next-methods)
 192                   (declare (ignore next-methods))
 193                   (destructuring-bind (value widget) args
 194                     (setf (child-property-value widget slot-name) value))))))
 195
 196
 197 (defmethod validate-superclass ((class container-child-class) (super standard-class))
 198   ;(subtypep (class-name super) 'container-child)
 199   t)
 200
 201
 202 (defclass container-child (virtual-slots-object)
 203   ((parent :initarg :parent :type container)
 204    (child :initarg :child :type widget)))
 205
 206
 207 ;;;;
 208
 209 (defbinding %container-class-list-child-properties () pointer
 210   (class pointer)
 211   (n-properties unsigned-int :out))
 212
 213 (defun query-container-class-child-properties (type-number)
 214   (let ((class (type-class-ref type-number)))
 215     (multiple-value-bind (array length)
 216         (%container-class-list-child-properties class)
 217       (unwind-protect
 218           (map-c-vector 'list #'identity array 'param length)
 219         (deallocate-memory array)))))
 220
 221 (defun default-container-child-name (container-class)
 222   (intern (format nil "~A-CHILD" container-class)))
 223
 224 (defun expand-container-type (type forward-p options)
 225   (let* ((class (type-from-number type))
 226          (super (supertype type))
 227          (child-class (default-container-child-name class)))
 228     (if forward-p
 229         (expand-gobject-type type t options)
 230       `(progn
 231          ,(expand-gobject-type type nil options)
 232          (defclass ,child-class (,(default-container-child-name super))
 233            ,(slot-definitions child-class
 234              (query-container-class-child-properties type) nil)
 235            (:metaclass container-child-class)
 236            (:container ,class))))))
 237
 238 (defun container-child-class (container-class)
 239   (gethash container-class *container-to-child-class-mappings*))
 240
 241 (defun container-dependencies (type options)
 242   (delete-duplicates
 243    (append
 244     (gobject-dependencies type options)
 245     (mapcar #'param-value-type (query-container-class-child-properties type)))))
 246
 247 (register-derivable-type 'container "GtkContainer" 'expand-container-type 'container-dependencies)