mdw@git.distorted.org.uk Git - catacomb/blob - configure.ac

   1 dnl -*-autoconf-*-
   2 dnl
   3 dnl Configuration script for Catacomb
   4 dnl
   5 dnl (c) 2013 Straylight/Edgeware
   6 dnl
   7
   8 dnl----- Licensing notice ---------------------------------------------------
   9 dnl
  10 dnl This file is part of Catacomb.
  11 dnl
  12 dnl Catacomb is free software; you can redistribute it and/or modify
  13 dnl it under the terms of the GNU Library General Public License as
  14 dnl published by the Free Software Foundation; either version 2 of the
  15 dnl License, or (at your option) any later version.
  16 dnl
  17 dnl Catacomb is distributed in the hope that it will be useful,
  18 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 dnl GNU Library General Public License for more details.
  21 dnl
  22 dnl You should have received a copy of the GNU Library General Public
  23 dnl License along with Catacomb; if not, write to the Free
  24 dnl Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  25 dnl MA 02111-1307, USA.
  26
  27 dnl--------------------------------------------------------------------------
  28 dnl Initialization.
  29
  30 mdw_AUTO_VERSION
  31 AC_INIT([catacomb], AUTO_VERSION, [mdw@distorted.org.uk])
  32 AC_CONFIG_SRCDIR([catacomb.pc.in])
  33 AC_CONFIG_AUX_DIR([config])
  34 AM_INIT_AUTOMAKE([foreign parallel-tests color-tests subdir-objects])
  35 AC_CANONICAL_HOST
  36 mdw_SILENT_RULES
  37
  38 AC_PROG_CC
  39 AX_CFLAGS_WARN_ALL
  40 AM_PROG_LIBTOOL
  41 mdw_LIBTOOL_VERSION_INFO
  42
  43 AM_PROG_AS
  44
  45 AC_PROG_YACC
  46
  47 AC_SUBST(AM_CFLAGS)
  48
  49 dnl--------------------------------------------------------------------------
  50 dnl Define language support for assembler.
  51 dnl
  52 dnl This is stolen from https://gitlab.crest.iu.edu/jsfiroz/hpx/commit/
  53 dnl 84be4345db6eec3797a57b8e53483cb43f4733bf
  54
  55 AC_LANG_DEFINE([CPPAS], [cppas], [CPPAS], [CCAS], [C],
  56   [ac_ext=S ac_cpp='$CPP $CPPFLAGS'
  57    ac_compile='$CCAS -c $CCASFLAGS $CPPFLAGS dnl
  58         conftest.$ac_ext >&AS_MESSAGE_LOG_FD'
  59    ac_link='$CCAS -oconftest$ac_exeext $CCASFLAGS $CPPFLAGS $LDFLAGS dnl
  60         conftest.$ac_ext $LIBS >&AS_MESSAGE_LOG_FD'])
  61
  62 AC_DEFUN([AC_LANG_PREPROC(CPPAS)], [AC_REQUIRE([AC_PROG_CPP])])
  63 AC_DEFUN([AC_LANG_COMPILER(CPPAS)], [AC_REQUIRE([AM_PROG_AS])])
  64 AC_DEFUN([AC_LANG_CONFTEST(CPPAS)],
  65   [cat confdefs.h - <<_ACEOF >conftest.$ac_ext
  66 /* end confdefs.h. */
  67 $1
  68 _ACEOF])
  69
  70 AC_CACHE_CHECK(
  71   [whether the assembler is likely to work], [mdw_cv_gnuish_as],
  72   [AC_LANG_PUSH([CPPAS])
  73    AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  74         .text
  75         .L\$_test = 23
  76 .macro  mymac
  77         .L\$_test = .L\$_test + 1
  78 .endm
  79         .globl  foo
  80         .extern bar
  81         mymac]])],
  82      [mdw_cv_gnuish_as=yes], [mdw_cv_gnuish_as=no])
  83    AC_LANG_POP([CPPAS])])
  84 AM_CONDITIONAL([GNUISH_AS], [test $mdw_cv_gnuish_as = yes])
  85
  86 dnl--------------------------------------------------------------------------
  87 dnl Host-specific configuration.
  88
  89 AC_MSG_CHECKING([CPU family and ABI])
  90
  91 dnl The table of CPU families and ABIs which we might support.  Support is
  92 dnl not uniform: each dispatched function might or might not have an
  93 dnl implementation for any particular CPU/ABI combination.
  94 AC_DEFUN([catacomb_CPU_FAMILIES],
  95   [$1([i[[3-6]]86,cygwin], [x86], [win])
  96    $1([i[[3-6]]86,*], [x86], [sysv])
  97    $1([x86_64,cygwin], [amd64], [win])
  98    $1([x86_64,*], [amd64], [sysv])
  99    $1([arm,*-gnueabi | arm,*-gnueabihf | dnl
 100         armv*,*-gnueabi | armv*,*-gnueabihf], [armel], [gnueabi])])
 101
 102 dnl A utility to clear the `seen' flags, used so as to process each CPU or
 103 dnl ABI once.
 104 m4_define([catacomb_CLEAR_FLAGS],
 105 [m4_ifdef([catacomb_seen_cpu/$2],
 106           [m4_undefine([catacomb_seen_cpu/$2])])dnl
 107 m4_ifdef([catacomb_seen_abi/$3],
 108           [m4_undefine([catacomb_seen_abi/$3])])])
 109
 110 dnl Identify the current host.
 111 if test $mdw_cv_gnuish_as = no; then
 112   CPUFAM=nil ABI=nil
 113 else
 114   case $host_cpu,$host_os in
 115     m4_define([catacomb_CPU_CASE],
 116       [$1) CPUFAM=$2 ABI=$3 ;;
 117 ])
 118     catacomb_CPU_FAMILIES([catacomb_CPU_CASE])
 119     *) CPUFAM=nil ABI=nil ;;
 120   esac
 121 fi
 122
 123 dnl Figure out the current CPU.
 124 catacomb_CPU_FAMILIES([catacomb_CLEAR_FLAGS])
 125 case $CPUFAM in
 126   m4_define([catacomb_DEFINE_CPU],
 127     [m4_ifdef([catacomb_seen_cpu/$2], [],
 128       [$2)
 129         AC_DEFINE([CPUFAM_]m4_translit([$2], [a-z], [A-Z]), [1],
 130                   [Define if host CPU family is \`$2\'.])
 131         ;;m4_define([catacomb_seen_cpu/$2], [t])])])
 132   catacomb_CPU_FAMILIES([catacomb_DEFINE_CPU])
 133   nil) ;;
 134   *) AC_MSG_ERROR([BUG: unexpected cpufam \`$CPUFAM']) ;;
 135 esac
 136 AC_SUBST([CPUFAM])
 137
 138 dnl Figure out the current ABI.
 139 catacomb_CPU_FAMILIES([catacomb_CLEAR_FLAGS])
 140 case $ABI in
 141   m4_define([catacomb_DEFINE_ABI],
 142     [m4_ifdef([catacomb_seen_abi/$3], [],
 143       [$3)
 144         AC_DEFINE([ABI_]m4_translit([$3], [a-z], [A-Z]), [1],
 145                   [Define if host ABI variant is \`$3\'.])
 146         ;;m4_define([catacomb_seen_abi/$3], [t])])])
 147   catacomb_CPU_FAMILIES([catacomb_DEFINE_ABI])
 148   nil) ;;
 149   *) AC_MSG_ERROR([BUG: unexpected ABI \`$ABI']) ;;
 150 esac
 151 AC_SUBST([ABI])
 152
 153 dnl Establish Automake conditions for things.
 154 catacomb_CPU_FAMILIES([catacomb_CLEAR_FLAGS])
 155 m4_define([catacomb_COND_CPU],
 156 [m4_define([_CPU], m4_translit([$2], [a-z], [A-Z]))
 157 m4_define([_ABI], m4_translit([$3], [a-z], [A-Z]))
 158 AM_CONDITIONAL([CPUABI_]_CPU[_]_ABI, [test x$CPUFAM/$ABI = x$2/$3])
 159 m4_ifdef([catacomb_seen_cpu/$2], [],
 160 [AM_CONDITIONAL([CPUFAM_]_CPU, [test x$CPUFAM = x$2])dnl
 161 m4_define([catacomb_seen_cpu/$2], [t])])
 162 m4_ifdef([catacomb_seen_abi/$3], [],
 163 [AM_CONDITIONAL([ABI_]_ABI, [test x$ABI = x$3])dnl
 164 m4_define([catacomb_seen_abi/$3], [t])])])
 165 catacomb_CPU_FAMILIES([catacomb_COND_CPU])
 166 AM_CONDITIONAL([KNOWN_CPUFAM], [test x$CPUFAM != xnil])
 167
 168 dnl Report on what we found.
 169 case $CPUFAM in
 170   nil) AC_MSG_RESULT([not supported]) ;;
 171   *) AC_MSG_RESULT([$CPUFAM/$ABI]) ;;
 172 esac
 173
 174 dnl--------------------------------------------------------------------------
 175 dnl CPU-specific assembler features.
 176
 177 AC_LANG([CPPAS])
 178
 179 case $CPUFAM in
 180   armel)
 181     AC_CACHE_CHECK(
 182       [whether the assembler understands ARMv8 crypto extensions],
 183       [mdw_cv_as_armv8_crypto],
 184       [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 185         .arch   armv8-a
 186         .fpu    crypto-neon-fp-armv8
 187
 188         .text
 189         .globl  foo
 190 foo:
 191         vldmia  r0, {d0-d3}
 192         aese.8  q0, q1
 193         aesmc.8 q0, q0
 194         vstmia  r0, {d0, d1}
 195         bx      r14]])],
 196          [mdw_cv_as_armv8_crypto=yes],
 197          [mdw_cv_as_armv8_crypto=no])])
 198     ;;
 199 esac
 200
 201 : ${mdw_cv_as_armv8_crypto=no}
 202 AM_CONDITIONAL([HAVE_AS_ARMV8_CRYPTO], [test $mdw_cv_as_armv8_crypto = yes])
 203 if test $mdw_cv_as_armv8_crypto = yes; then
 204   AC_DEFINE([HAVE_AS_ARMV8_CRYPTO], [1],
 205     [Define to 1 if your ARM assembler supports the ARMv8 crypto instructions.])
 206 fi
 207
 208 dnl--------------------------------------------------------------------------
 209 dnl C programming environment.
 210
 211 AC_LANG([C])
 212
 213 CATACOMB_LIBS=
 214
 215 dnl Find out if we're cross-compiling.
 216 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 217
 218 dnl Various standard types.
 219 AC_CHECK_TYPE([pid_t], [int])
 220 AC_TYPE_UID_T
 221 AC_CHECK_TYPE([ssize_t], [int])
 222 AC_CHECK_TYPE([socklen_t], [int])
 223
 224 dnl The maths library.
 225 mdw_ORIG_LIBS=$LIBS LIBS=
 226 AC_SEARCH_LIBS([log], [m])
 227 AC_SEARCH_LIBS([sqrt], [m])
 228 AC_SUBST([MATHLIBS], [$LIBS])
 229 LIBS=$mdw_ORIG_LIBS
 230
 231 dnl Find out whether very long integer types are available.
 232 AC_CHECK_HEADERS([stdint.h])
 233 AC_SUBST([have_stdint_h])
 234 AX_C_LONG_LONG
 235
 236 dnl Some equipment wanted for checking CPU features at runtime.
 237 AC_CHECK_HEADERS([asm/hwcap.h])
 238 AC_CHECK_HEADERS([sys/auxv.h])
 239 AC_CHECK_HEADERS([linux/auxvec.h])
 240 AC_CHECK_FUNCS([getauxval])
 241
 242 dnl Find the bit lengths of the obvious integer types.  This will be useful
 243 dnl when deciding on a representation for multiprecision integers.
 244 type_bits="" type_bits_sep=""
 245 AC_DEFUN([catacomb_UINT_BITS],
 246   [mdw_UINT_BITS([$2], [$1])
 247    type_bits="$type_bits$type_bits_sep('$1', $[]$1_bits)"
 248    type_bits_sep=", "])
 249 catacomb_UINT_BITS([uchar], [unsigned char])
 250 catacomb_UINT_BITS([ushort], [unsigned short])
 251 catacomb_UINT_BITS([uint], [unsigned int])
 252 catacomb_UINT_BITS([ulong], [unsigned long])
 253 if test "$ac_cv_c_long_long" = "yes"; then
 254   catacomb_UINT_BITS([ullong], [unsigned long long])
 255 fi
 256 if test "$ac_cv_header_stdint_h" = "yes"; then
 257   catacomb_UINT_BITS([uintmax], [uintmax_t])
 258 fi
 259 AC_SUBST([type_bits])
 260
 261 dnl Determine the limits of common C integer types.
 262 limits="" limits_sep=""
 263 AC_DEFUN([catacomb_COMPILE_TIME_CONSTANT],
 264   [case "$2" in
 265      =*)
 266        $1="$2"; $1=${$1#=}
 267        ;;
 268      *)
 269        AC_CACHE_CHECK([compile-time value of $2], [mdw_cv_constant_$3],
 270                       [mdw_PROBE_CONSTANT([mdw_cv_constant_$3], [$2], [$4])])
 271        $1=$mdw_cv_constant_$3
 272        ;;
 273    esac])
 274 AC_DEFUN([catacomb_LIMIT],
 275 [catacomb_COMPILE_TIME_CONSTANT([lo], [$2], [$1_min],
 276 [#include <limits.h>
 277 #include <stddef.h>])
 278  catacomb_COMPILE_TIME_CONSTANT([hi], [$3], [$1_max],
 279 [#include <limits.h>
 280 #include <stddef.h>])
 281  limits="$limits$limits_sep('$1', $lo, $hi)" limits_sep=", "])
 282 catacomb_LIMIT([SCHAR],         [SCHAR_MIN],    [SCHAR_MAX])
 283 catacomb_LIMIT([CHAR],          [CHAR_MIN],     [CHAR_MAX])
 284 catacomb_LIMIT([UCHAR],         [=0],           [UCHAR_MAX])
 285 catacomb_LIMIT([UINT8],         [=0],           [=0xff])
 286 catacomb_LIMIT([SHRT],          [SHRT_MIN],     [SHRT_MAX])
 287 catacomb_LIMIT([USHRT],         [=0],           [USHRT_MAX])
 288 catacomb_LIMIT([UINT16],        [=0],           [=0xffff])
 289 catacomb_LIMIT([INT],           [INT_MIN],      [INT_MAX])
 290 catacomb_LIMIT([UINT],          [=0],           [UINT_MAX])
 291 catacomb_LIMIT([LONG],          [LONG_MIN],     [LONG_MAX])
 292 catacomb_LIMIT([ULONG],         [=0],           [ULONG_MAX])
 293 catacomb_LIMIT([UINT32],        [=0],           [=0xffffffff])
 294 if test "$ac_cv_c_long_long" = "yes"; then
 295   catacomb_LIMIT([LLONG],       [LLONG_MIN],    [LLONG_MAX])
 296   catacomb_LIMIT([ULLONG],      [=0],           [ULLONG_MAX])
 297 fi
 298 catacomb_LIMIT([SIZET],         [=0],           [~(size_t)0])
 299 AC_SUBST([limits])
 300
 301 dnl Functions used for noise-gathering.
 302 AC_CHECK_FUNCS([setgroups])
 303 AC_CHECK_HEADERS([linux/random.h])
 304 mdw_ORIG_LIBS=$LIBS LIBS=$CATACOMB_LIBS
 305 AC_SEARCH_LIBS([clock_gettime], [rt])
 306 CATACOMB_LIBS=$LIBS LIBS=$mdw_ORIG_LIBS
 307 if test "$ac_cv_search_clock_gettime" != no; then
 308   AC_DEFINE([HAVE_CLOCK_GETTIME], [1],
 309             [Define if you have the \`clock_gettime' function.])
 310 fi
 311 AC_CHECK_FUNCS([getentropy])
 312 AC_CACHE_CHECK([whether the freewheel noise generator will work],
 313         [catacomb_cv_freewheel],
 314 [AC_TRY_LINK(
 315 [#include <setjmp.h>
 316 #include <sys/time.h>],
 317 [struct itimerval itv = { { 0, 0 }, { 0, 5000 } };
 318 jmp_buf j;
 319 setitimer(ITIMER_REAL, &itv, 0);
 320 sigsetjmp(j, 1);],
 321 [catacomb_cv_freewheel=yes],
 322 [catacomb_cv_freewheel=no])])
 323 case $catacomb_cv_freewheel in
 324   yes)
 325     AC_DEFINE([USE_FREEWHEEL], [1],
 326               [Define if you want to use the freewheel noise generator.])
 327     ;;
 328 esac
 329
 330 dnl Support for the passphrase pixie.
 331 mdw_ORIG_LIBS=$LIBS
 332 AC_SEARCH_LIBS([socket], [socket])
 333 AC_SUBST([PIXIE_LIBS], [$LIBS])
 334 LIBS=$mdw_ORIG_LIBS
 335
 336 dnl Memory locking support.
 337 AC_CHECK_FUNCS([mlock])
 338
 339 dnl Set the master libraries we need.
 340 AC_SUBST([CATACOMB_LIBS])
 341
 342 dnl Necessary support libraries.
 343 PKG_CHECK_MODULES([mLib], [mLib >= 2.2.2.1])
 344 AM_CFLAGS="$AM_CFLAGS $mLib_CFLAGS"
 345
 346 dnl--------------------------------------------------------------------------
 347 dnl Python.
 348
 349 dnl Make sure we have a suitable version.
 350 AM_PATH_PYTHON([2.5])
 351
 352 dnl--------------------------------------------------------------------------
 353 dnl Special debugging options.
 354
 355 AC_ARG_ENABLE([mpw],
 356   [AS_HELP_STRING([--enable-mpw], [force small-width mp digits])],
 357   [case "$enableval" in
 358     y*|t*|short)
 359       AC_DEFINE([FORCE_MPW_SHORT], [1],
 360                 [Define to force small-width mp digits.])
 361       ;;
 362     cussid)
 363       AC_DEFINE([FORCE_MPW_CUSSID], [1],
 364                 [Define to force strange-width mp digits.])
 365       ;;
 366    esac])
 367
 368 dnl--------------------------------------------------------------------------
 369 dnl Produce output.
 370
 371 AC_CONFIG_HEADER([config/config.h])
 372
 373 AC_CONFIG_FILES(
 374   [Makefile]
 375   [base/Makefile]
 376   [key/Makefile]
 377   [math/Makefile]
 378   [misc/Makefile]
 379   [pub/Makefile]
 380   [rand/Makefile]
 381   [symm/Makefile]
 382   [progs/Makefile])
 383 AC_OUTPUT
 384
 385 dnl----- That's all, folks --------------------------------------------------