mdw@git.distorted.org.uk Git - ca/blob - bin/withdraw

   1 #! /usr/bin/tclsh
   2 ### -*-tcl-*-
   3 ###
   4 ### Revoke a certificate request
   5 ###
   6 ### (c) 2011 Mark Wooding
   7 ###
   8
   9 ###----- Licensing notice ---------------------------------------------------
  10 ###
  11 ### This program is free software; you can redistribute it and/or modify
  12 ### it under the terms of the GNU General Public License as published by
  13 ### the Free Software Foundation; either version 2 of the License, or
  14 ### (at your option) any later version.
  15 ###
  16 ### This program is distributed in the hope that it will be useful,
  17 ### but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ### GNU General Public License for more details.
  20 ###
  21 ### You should have received a copy of the GNU General Public License
  22 ### along with this program; if not, write to the Free Software Foundation,
  23 ### Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  24
  25 ## Find the common utilities.
  26 source [file join [file dirname $argv0] "../lib/func.tcl"]
  27
  28 ## Open the database
  29 sqlite3 db "$CERTROOT/state/ca.db"
  30 db nullvalue nil
  31 cd "$CERTROOT"
  32
  33 ## Get the list of requests.
  34 if {[llength $argv] != 1} {
  35   puts stderr "usage: $QUIS REQID"
  36   exit 1
  37 }
  38 lassign $argv reqid
  39
  40 ## Set the request state.  Don't try to revoke the certificates: they'll
  41 ## expire soon enough, and there isn't really anything wrong with them
  42 ## anyway.  (If there were anything wrong, the request would have been
  43 ## revoked.)
  44 db transaction {
  45   set del {}
  46   foreach req [request-match $reqid "st = 'active'"] {
  47     lassign [db eval { SELECT st, tag FROM request WHERE id = $req; }] \
  48         reqst tag
  49     if {[string equal $reqst active]} { lappend del "req/active/$tag" }
  50     foreach {cert certst} [db eval {
  51       SELECT seq, st FROM certificate
  52       WHERE req = $req AND st = 'active';
  53     }] {
  54       db eval {
  55         UPDATE certificate
  56         SET st = 'withdrawn'
  57         WHERE seq = $cert;
  58       }
  59       lappend del "cert/active/$tag"
  60     }
  61     db eval {
  62       UPDATE request
  63       SET st = 'withdrawn'
  64       WHERE id = $req;
  65     }
  66   }
  67 }
  68 foreach f $del { file delete -force "$CERTROOT/$f" }