mdw@git.distorted.org.uk Git - become/blob - configure.in

   1 dnl -*-fundamental-*-
   2 dnl
   3 dnl $Id: configure.in,v 1.9 1997/09/18 11:24:27 mdw Exp $
   4 dnl
   5 dnl Source for auto configuration for `become'
   6 dnl
   7 dnl (c) 1997 Mark Wooding
   8 dnl
   9
  10 dnl----- Licensing notice ---------------------------------------------------
  11 dnl
  12 dnl This file is part of `become'
  13 dnl
  14 dnl `Become' is free software; you can redistribute it and/or modify
  15 dnl it under the terms of the GNU General Public License as published by
  16 dnl the Free Software Foundation; either version 2 of the License, or
  17 dnl (at your option) any later version.
  18 dnl
  19 dnl `Become' is distributed in the hope that it will be useful,
  20 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 dnl GNU General Public License for more details.
  23 dnl
  24 dnl You should have received a copy of the GNU General Public License
  25 dnl along with `become'; if not, write to the Free Software Foundation,
  26 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  27
  28 dnl----- Revision history ---------------------------------------------------
  29 dnl
  30 dnl $Log: configure.in,v $
  31 dnl Revision 1.9  1997/09/18 11:24:27  mdw
  32 dnl Add `conf' directory.  Add an `htmldir' installation directory too.
  33 dnl
  34 dnl Revision 1.8  1997/09/17  10:36:30  mdw
  35 dnl Remove `set.c'.  No longer necessary.
  36 dnl
  37 dnl Revision 1.7  1997/09/09 18:18:41  mdw
  38 dnl Check for setgroups(2), to see whether subsidiary group lists need to be
  39 dnl fiddled with.
  40 dnl
  41 dnl Revision 1.6  1997/09/08  13:41:14  mdw
  42 dnl Check for `setreuid' for changing permissions.
  43 dnl
  44 dnl Revision 1.5  1997/09/05  11:45:18  mdw
  45 dnl Add support for different login styles, and environment variable
  46 dnl manipulation in a safe and useful way.
  47 dnl
  48 dnl Revision 1.4  1997/08/20  16:10:56  mdw
  49 dnl Lowercase `mdw_' prefixes to macros.  Add a `--with-etcdir=PATH'
  50 dnl option.  Update `stamp-h' as required by the Automake docs (silly
  51 dnl me).
  52 dnl
  53 dnl Revision 1.3  1997/08/07 09:34:32  mdw
  54 dnl Added `ElectricFence' support, and support for the `deep' package
  55 dnl structure.
  56 dnl
  57 dnl Revision 1.2  1997/08/04 10:24:21  mdw
  58 dnl Sources placed under CVS control.
  59 dnl
  60 dnl Revision 1.1  1997/07/21  13:47:51  mdw
  61 dnl Initial revision
  62 dnl
  63
  64 AC_INIT(src/icrypt.c)
  65 AC_CONFIG_HEADER(config.h)
  66 PACKAGE=become VERSION=1.2-pre
  67 AC_SUBST(PACKAGE)
  68 AC_SUBST(VERSION)
  69 AC_DEFINE(VERSION, "1.2-pre (17 September 1997)")
  70
  71 dnl --- Check for compilers and things ---
  72
  73 AC_PROG_CC
  74 AC_PROG_INSTALL
  75 AC_PROG_LEX
  76 AC_CHECK_PROG(AR, ar, ar)
  77 AC_PROG_RANLIB
  78 AC_PROG_MAKE_SET
  79 AC_PROG_YACC
  80 AC_ARG_PROGRAM
  81 if test "$GCC" = "yes"; then
  82   CFLAGS="$CFLAGS -pedantic -Wall"
  83 fi
  84
  85 dnl --- Set default become style ---
  86
  87 AC_ARG_ENABLE([style],
  88 [  --enable-style=STYLE   set default style to preserve, setuser, or login],
  89 [case "$enableval" in
  90   preserve) style="l_preserve" ;;
  91   su|setuser) style="l_setuser" ;;
  92   login) style="l_login" ;;
  93   *) AC_MSG_ERROR([unknown login style: choose preserve, setuser, or login])
  94      ;;
  95 esac],
  96 [style="l_preserve"])
  97 AC_DEFINE_UNQUOTED(DEFAULT_LOGIN_STYLE, $style)
  98
  99 dnl --- Set configuration directory ---
 100
 101 AC_ARG_WITH([etcdir],
 102 [  --with-etcdir=PATH     set directory for configuration and key files
 103                           [default is /etc/become]],
 104 [etcdir="$withval"], [etcdir="/etc/become"])
 105 AC_SUBST(etcdir)
 106 AC_DEFINE_UNQUOTED(ETCDIR, "$etcdir")
 107
 108 AC_ARG_WITH([htmldir],
 109 [  --with-htmldir=PATH    set directory for HTML documentation
 110                           [default is PREFIX/html/become]],
 111 [htmldir="$withval"], [htmldir="${prefix}/html/become"])
 112 AC_SUBST(htmldir)
 113
 114 dnl --- Debugging stuff ---
 115
 116 AC_ARG_WITH(electric-fence,
 117 [  --with-electric-fence          link programs with Electric Fence],
 118   [if test "$withval" = "yes"; then
 119     AC_CHECK_LIB(efence, malloc)
 120   fi])
 121
 122 AC_ARG_ENABLE(debugging,
 123 [  --enable-debugging     spews vast swathes of useless information],
 124   [if test "$enableval" = "no"; then
 125     AC_DEFINE(NDEBUG, 1)
 126   fi],
 127   AC_DEFINE(NDEBUG, 1))
 128
 129 AC_ARG_ENABLE(tracing,
 130 [  --enable-tracing       enable output of tracing information],
 131   [if test "$enableval" = "yes"; then
 132     AC_DEFINE(TRACING)
 133   fi],
 134   AC_DEFINE(TRACING))
 135
 136 dnl --- Libraries ---
 137
 138 mdw_CHECK_MANYLIBS(socket, socket,,
 139   AC_MSG_ERROR([Socket library not found]))
 140
 141 mdw_CHECK_MANYLIBS(gethostbyname, resolv nsl,,
 142   AC_MSG_ERROR([Resolver library not found]))
 143
 144 mdw_CHECK_MANYLIBS(yp_all, nsl, AC_DEFINE(HAVE_YP))
 145
 146 dnl --- Types ---
 147
 148 AC_TYPE_PID_T
 149 AC_TYPE_UID_T
 150 AC_CHECK_TYPE(ssize_t, int)
 151
 152 dnl --- Check on type sizes ---
 153
 154 AC_CHECK_SIZEOF(int, 2)
 155
 156 dnl --- Set the path separator ---
 157
 158 AC_DEFINE(PATHSEP, '/')
 159
 160 dnl --- Check for some useful functions ---
 161
 162 AC_CHECK_FUNCS(setreuid setgroups)
 163 AC_CHECK_FUNCS(getrusage vtimes)
 164
 165 dnl --- Done ---
 166
 167 AC_OUTPUT(Makefile conf/Makefile src/Makefile manual/Makefile,
 168           [test -z "$CONFIG_HEADERS" || echo timestamp >stamp-h])
 169
 170 dnl----- That's all, folks --------------------------------------------------