mdw@git.distorted.org.uk Git - become/blob - configure.in

   1 dnl -*-fundamental-*-
   2 dnl
   3 dnl $Id: configure.in,v 1.8 1997/09/17 10:36:30 mdw Exp $
   4 dnl
   5 dnl Source for auto configuration for `become'
   6 dnl
   7 dnl (c) 1997 Mark Wooding
   8 dnl
   9
  10 dnl----- Licensing notice ---------------------------------------------------
  11 dnl
  12 dnl This file is part of `become'
  13 dnl
  14 dnl `Become' is free software; you can redistribute it and/or modify
  15 dnl it under the terms of the GNU General Public License as published by
  16 dnl the Free Software Foundation; either version 2 of the License, or
  17 dnl (at your option) any later version.
  18 dnl
  19 dnl `Become' is distributed in the hope that it will be useful,
  20 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 dnl GNU General Public License for more details.
  23 dnl
  24 dnl You should have received a copy of the GNU General Public License
  25 dnl along with `become'; if not, write to the Free Software Foundation,
  26 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  27
  28 dnl----- Revision history ---------------------------------------------------
  29 dnl
  30 dnl $Log: configure.in,v $
  31 dnl Revision 1.8  1997/09/17 10:36:30  mdw
  32 dnl Remove `set.c'.  No longer necessary.
  33 dnl
  34 dnl Revision 1.7  1997/09/09 18:18:41  mdw
  35 dnl Check for setgroups(2), to see whether subsidiary group lists need to be
  36 dnl fiddled with.
  37 dnl
  38 dnl Revision 1.6  1997/09/08  13:41:14  mdw
  39 dnl Check for `setreuid' for changing permissions.
  40 dnl
  41 dnl Revision 1.5  1997/09/05  11:45:18  mdw
  42 dnl Add support for different login styles, and environment variable
  43 dnl manipulation in a safe and useful way.
  44 dnl
  45 dnl Revision 1.4  1997/08/20  16:10:56  mdw
  46 dnl Lowercase `mdw_' prefixes to macros.  Add a `--with-etcdir=PATH'
  47 dnl option.  Update `stamp-h' as required by the Automake docs (silly
  48 dnl me).
  49 dnl
  50 dnl Revision 1.3  1997/08/07 09:34:32  mdw
  51 dnl Added `ElectricFence' support, and support for the `deep' package
  52 dnl structure.
  53 dnl
  54 dnl Revision 1.2  1997/08/04 10:24:21  mdw
  55 dnl Sources placed under CVS control.
  56 dnl
  57 dnl Revision 1.1  1997/07/21  13:47:51  mdw
  58 dnl Initial revision
  59 dnl
  60
  61 AC_INIT(src/icrypt.c)
  62 AC_CONFIG_HEADER(config.h)
  63 PACKAGE=become VERSION=1.2-pre
  64 AC_SUBST(PACKAGE)
  65 AC_SUBST(VERSION)
  66 AC_DEFINE(VERSION, "1.2-pre (17 September 1997)")
  67
  68 dnl --- Check for compilers and things ---
  69
  70 AC_PROG_CC
  71 AC_PROG_INSTALL
  72 AC_PROG_LEX
  73 AC_CHECK_PROG(AR, ar, ar)
  74 AC_PROG_RANLIB
  75 AC_PROG_MAKE_SET
  76 AC_PROG_YACC
  77 AC_ARG_PROGRAM
  78 if test "$GCC" = "yes"; then
  79   CFLAGS="$CFLAGS -pedantic -Wall"
  80 fi
  81
  82 dnl --- Set default become style ---
  83
  84 AC_ARG_ENABLE([style],
  85 [  --enable-style=STYLE   set default style to preserve, setuser, or login],
  86 [case "$enableval" in
  87   preserve) style="l_preserve" ;;
  88   su|setuser) style="l_setuser" ;;
  89   login) style="l_login" ;;
  90   *) AC_MSG_ERROR([unknown login style: choose preserve, setuser, or login])
  91      ;;
  92 esac],
  93 [style="l_preserve"])
  94 AC_DEFINE_UNQUOTED(DEFAULT_LOGIN_STYLE, $style)
  95
  96 dnl --- Set configuration directory ---
  97
  98 AC_ARG_WITH([etcdir],
  99 [  --with-etcdir=PATH     set directory for configuration and key files
 100                           [default is /etc/become]],
 101 [etcdir="$withval"], [etcdir="/etc/become"])
 102 AC_SUBST(etcdir)
 103 AC_DEFINE_UNQUOTED(ETCDIR, "$etcdir")
 104
 105 dnl --- Debugging stuff ---
 106
 107 AC_ARG_WITH(electric-fence,
 108 [  --with-electric-fence          link programs with Electric Fence],
 109   [if test "$withval" = "yes"; then
 110     AC_CHECK_LIB(efence, malloc)
 111   fi])
 112
 113 AC_ARG_ENABLE(debugging,
 114 [  --enable-debugging     spews vast swathes of useless information],
 115   [if test "$enableval" = "no"; then
 116     AC_DEFINE(NDEBUG, 1)
 117   fi],
 118   AC_DEFINE(NDEBUG, 1))
 119
 120 AC_ARG_ENABLE(tracing,
 121 [  --enable-tracing       enable output of tracing information],
 122   [if test "$enableval" = "yes"; then
 123     AC_DEFINE(TRACING)
 124   fi],
 125   AC_DEFINE(TRACING))
 126
 127 dnl --- Libraries ---
 128
 129 mdw_CHECK_MANYLIBS(socket, socket,,
 130   AC_MSG_ERROR([Socket library not found]))
 131
 132 mdw_CHECK_MANYLIBS(gethostbyname, resolv nsl,,
 133   AC_MSG_ERROR([Resolver library not found]))
 134
 135 mdw_CHECK_MANYLIBS(yp_all, nsl, AC_DEFINE(HAVE_YP))
 136
 137 dnl --- Types ---
 138
 139 AC_TYPE_PID_T
 140 AC_TYPE_UID_T
 141 AC_CHECK_TYPE(ssize_t, int)
 142
 143 dnl --- Check on type sizes ---
 144
 145 AC_CHECK_SIZEOF(int, 2)
 146
 147 dnl --- Set the path separator ---
 148
 149 AC_DEFINE(PATHSEP, '/')
 150
 151 dnl --- Check for some useful functions ---
 152
 153 AC_CHECK_FUNCS(setreuid setgroups)
 154 AC_CHECK_FUNCS(getrusage vtimes)
 155
 156 dnl --- Done ---
 157
 158 AC_OUTPUT(Makefile src/Makefile manual/Makefile,
 159           [test -z "$CONFIG_HEADERS" || echo timestamp >stamp-h])
 160
 161 dnl----- That's all, folks --------------------------------------------------