mdw@git.distorted.org.uk Git - become/blob - configure.in

   1 dnl -*-fundamental-*-
   2 dnl
   3 dnl $Id: configure.in,v 1.5 1997/09/05 11:45:18 mdw Exp $
   4 dnl
   5 dnl Source for auto configuration for `become'
   6 dnl
   7 dnl (c) 1997 Mark Wooding
   8 dnl
   9
  10 dnl----- Licensing notice ---------------------------------------------------
  11 dnl
  12 dnl This file is part of `become'
  13 dnl
  14 dnl `Become' is free software; you can redistribute it and/or modify
  15 dnl it under the terms of the GNU General Public License as published by
  16 dnl the Free Software Foundation; either version 2 of the License, or
  17 dnl (at your option) any later version.
  18 dnl
  19 dnl `Become' is distributed in the hope that it will be useful,
  20 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 dnl GNU General Public License for more details.
  23 dnl
  24 dnl You should have received a copy of the GNU General Public License
  25 dnl along with `become'; if not, write to the Free Software Foundation,
  26 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  27
  28 dnl----- Revision history ---------------------------------------------------
  29 dnl
  30 dnl $Log: configure.in,v $
  31 dnl Revision 1.5  1997/09/05 11:45:18  mdw
  32 dnl Add support for different login styles, and environment variable
  33 dnl manipulation in a safe and useful way.
  34 dnl
  35 # Revision 1.4  1997/08/20  16:10:56  mdw
  36 # Lowercase `mdw_' prefixes to macros.  Add a `--with-etcdir=PATH'
  37 # option.  Update `stamp-h' as required by the Automake docs (silly
  38 # me).
  39 #
  40 dnl Revision 1.3  1997/08/07 09:34:32  mdw
  41 dnl Added `ElectricFence' support, and support for the `deep' package
  42 dnl structure.
  43 dnl
  44 dnl Revision 1.2  1997/08/04 10:24:21  mdw
  45 dnl Sources placed under CVS control.
  46 dnl
  47 dnl Revision 1.1  1997/07/21  13:47:51  mdw
  48 dnl Initial revision
  49 dnl
  50
  51 AC_INIT(src/icrypt.c)
  52 AC_CONFIG_HEADER(config.h)
  53 PACKAGE=become VERSION=1.2-pre
  54 AC_SUBST(PACKAGE)
  55 AC_SUBST(VERSION)
  56 AC_DEFINE(VERSION, "1.2-pre (24 July 1997)")
  57
  58 dnl --- Check for compilers and things ---
  59
  60 AC_PROG_CC
  61 AC_PROG_INSTALL
  62 AC_PROG_LEX
  63 AC_CHECK_PROG(AR, ar, ar)
  64 AC_PROG_RANLIB
  65 AC_PROG_MAKE_SET
  66 AC_PROG_YACC
  67 AC_ARG_PROGRAM
  68 if test "$ac_cv_prog_gcc" = "yes"; then
  69   CFLAGS="$CFLAGS -pedantic -Wall"
  70 fi
  71
  72 dnl --- Libraries ---
  73
  74 mdw_CHECK_MANYLIBS(socket, socket,,
  75   AC_MSG_ERROR([Socket library not found]))
  76
  77 mdw_CHECK_MANYLIBS(gethostbyname, resolv nsl,,
  78   AC_MSG_ERROR([Resolver library not found]))
  79
  80 mdw_CHECK_MANYLIBS(yp_all, nsl, AC_DEFINE(HAVE_YP))
  81
  82 dnl --- Types ---
  83
  84 AC_TYPE_PID_T
  85 AC_TYPE_UID_T
  86 AC_CHECK_TYPE(ssize_t, int)
  87
  88 dnl --- Check on type sizes ---
  89
  90 AC_CHECK_SIZEOF(int, 2)
  91
  92 dnl --- Set the path separator ---
  93
  94 AC_DEFINE(PATHSEP, '/')
  95
  96 dnl --- Check for some useful functions ---
  97
  98 AC_CHECK_FUNCS(getrusage vtimes)
  99
 100 dnl --- Set default become style ---
 101
 102 AC_ARG_ENABLE([style],
 103 [  --enable-style=STYLE   set default style to preserve, su, or login],
 104 [case "$withval" in
 105   preserve) style="l_preserve" ;;
 106   su|user) style="l_user" ;;
 107   login) style="l_login" ;;
 108 esac],
 109 [style="l_preserve"])
 110 AC_DEFINE_UNQUOTED(DEFAULT_LOGIN_STYLE, $style)
 111
 112 dnl --- Set configuration directory ---
 113
 114 AC_ARG_WITH([etcdir],
 115 [  --with-etcdir=PATH     set directory for configuration and key files
 116                           [default is /etc/become]],
 117 [etcdir="$withval"], [etcdir="/etc/become"])
 118 AC_SUBST(etcdir)
 119 AC_DEFINE_UNQUOTED(ETCDIR, "$etcdir")
 120
 121 dnl --- Debugging stuff ---
 122
 123 AC_ARG_WITH(electric-fence,
 124 [  --with-electric-fence          link programs with Electric Fence],
 125   [if test "$withval" = "yes"; then
 126     AC_CHECK_LIB(efence, malloc)
 127   fi])
 128
 129 AC_ARG_ENABLE(debugging,
 130 [  --enable-debugging     spews vast swathes of useless information],
 131   [if test "$enableval" = "no"; then
 132     AC_DEFINE(NDEBUG, 1)
 133   fi],
 134   AC_DEFINE(NDEBUG, 1))
 135
 136 AC_ARG_ENABLE(tracing,
 137 [  --enable-tracing       enable output of tracing information],
 138   [if test "$enableval" = "yes"; then
 139     AC_DEFINE(TRACING)
 140   fi],
 141   AC_DEFINE(TRACING))
 142
 143 dnl --- Done ---
 144
 145 AC_OUTPUT(Makefile src/Makefile manual/Makefile,
 146           [test -z "$CONFIG_HEADERS" || echo timestamp >stamp-h])
 147
 148 dnl----- That's all, folks --------------------------------------------------