mdw@git.distorted.org.uk Git - become/blob - configure.in

   1 dnl -*-fundamental-*-
   2 dnl
   3 dnl $Id: configure.in,v 1.13 1998/04/23 13:34:10 mdw Exp $
   4 dnl
   5 dnl Source for auto configuration for `become'
   6 dnl
   7 dnl (c) 1998 Mark Wooding
   8 dnl
   9
  10 dnl----- Licensing notice ---------------------------------------------------
  11 dnl
  12 dnl This file is part of `become'
  13 dnl
  14 dnl `Become' is free software; you can redistribute it and/or modify
  15 dnl it under the terms of the GNU General Public License as published by
  16 dnl the Free Software Foundation; either version 2 of the License, or
  17 dnl (at your option) any later version.
  18 dnl
  19 dnl `Become' is distributed in the hope that it will be useful,
  20 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 dnl GNU General Public License for more details.
  23 dnl
  24 dnl You should have received a copy of the GNU General Public License
  25 dnl along with `become'; if not, write to the Free Software Foundation,
  26 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  27
  28 dnl----- Revision history ---------------------------------------------------
  29 dnl
  30 dnl $Log: configure.in,v $
  31 dnl Revision 1.13  1998/04/23 13:34:10  mdw
  32 dnl Release version.
  33 dnl
  34 dnl Revision 1.12  1998/04/23 13:09:24  mdw
  35 dnl Add new option to disable networking.
  36 dnl
  37 dnl Revision 1.11  1998/02/20 17:55:56  mdw
  38 dnl Fix default HTML directory.
  39 dnl
  40 dnl Revision 1.10  1998/01/12 16:45:21  mdw
  41 dnl Fix copyright date.
  42 dnl
  43 dnl Revision 1.9  1997/09/18  11:24:27  mdw
  44 dnl Add `conf' directory.  Add an `htmldir' installation directory too.
  45 dnl
  46 dnl Revision 1.8  1997/09/17  10:36:30  mdw
  47 dnl Remove `set.c'.  No longer necessary.
  48 dnl
  49 dnl Revision 1.7  1997/09/09 18:18:41  mdw
  50 dnl Check for setgroups(2), to see whether subsidiary group lists need to be
  51 dnl fiddled with.
  52 dnl
  53 dnl Revision 1.6  1997/09/08  13:41:14  mdw
  54 dnl Check for `setreuid' for changing permissions.
  55 dnl
  56 dnl Revision 1.5  1997/09/05  11:45:18  mdw
  57 dnl Add support for different login styles, and environment variable
  58 dnl manipulation in a safe and useful way.
  59 dnl
  60 dnl Revision 1.4  1997/08/20  16:10:56  mdw
  61 dnl Lowercase `mdw_' prefixes to macros.  Add a `--with-etcdir=PATH'
  62 dnl option.  Update `stamp-h' as required by the Automake docs (silly
  63 dnl me).
  64 dnl
  65 dnl Revision 1.3  1997/08/07 09:34:32  mdw
  66 dnl Added `ElectricFence' support, and support for the `deep' package
  67 dnl structure.
  68 dnl
  69 dnl Revision 1.2  1997/08/04 10:24:21  mdw
  70 dnl Sources placed under CVS control.
  71 dnl
  72 dnl Revision 1.1  1997/07/21  13:47:51  mdw
  73 dnl Initial revision
  74 dnl
  75
  76 AC_INIT(src/icrypt.c)
  77 AC_CONFIG_HEADER(config.h)
  78 PACKAGE=become
  79 VERSION=1.3
  80 AC_DEFINE(VERSION, "1.3 (23 April 1998)")
  81 AC_SUBST(PACKAGE)
  82 AC_SUBST(VERSION)
  83
  84 dnl --- Check for compilers and things ---
  85
  86 AC_PROG_CC
  87 AC_PROG_INSTALL
  88 AC_PROG_LEX
  89 AC_CHECK_PROG(AR, ar, ar)
  90 AC_PROG_RANLIB
  91 AC_PROG_MAKE_SET
  92 AC_PROG_YACC
  93 AC_ARG_PROGRAM
  94 if test "$GCC" = "yes"; then
  95   CFLAGS="$CFLAGS -pedantic -Wall"
  96 fi
  97
  98 dnl --- Set default become style ---
  99
 100 AC_ARG_ENABLE([style],
 101 [  --enable-style=STYLE   set default style to preserve, setuser, or login],
 102 [case "$enableval" in
 103   preserve) style="l_preserve" ;;
 104   su|setuser) style="l_setuser" ;;
 105   login) style="l_login" ;;
 106   *) AC_MSG_ERROR([unknown login style: choose preserve, setuser, or login])
 107      ;;
 108 esac],
 109 [style="l_preserve"])
 110 AC_DEFINE_UNQUOTED(DEFAULT_LOGIN_STYLE, $style)
 111
 112 dnl --- Choose networking options ---
 113
 114 AC_ARG_ENABLE([network],
 115 [  --disable-network      disable the client-server bits of the program],
 116   [if test "$enableval" = "no"; then
 117     AC_DEFINE(NONETWORK)
 118   fi])
 119
 120 dnl --- Set configuration directory ---
 121
 122 AC_ARG_WITH([etcdir],
 123 [  --with-etcdir=PATH     set directory for configuration and key files
 124                           [default is /etc/become]],
 125 [etcdir="$withval"], [etcdir="/etc/become"])
 126 AC_SUBST(etcdir)
 127 AC_DEFINE_UNQUOTED(ETCDIR, "$etcdir")
 128
 129 AC_ARG_WITH([htmldir],
 130 [  --with-htmldir=PATH    set directory for HTML documentation
 131                           [default is PREFIX/html/become]],
 132 [htmldir="$withval"], [htmldir='${prefix}/html/become'])
 133 AC_SUBST(htmldir)
 134
 135 dnl --- Debugging stuff ---
 136
 137 AC_ARG_WITH(electric-fence,
 138 [  --with-electric-fence          link programs with Electric Fence],
 139   [if test "$withval" = "yes"; then
 140     AC_CHECK_LIB(efence, malloc)
 141   fi])
 142
 143 AC_ARG_ENABLE(debugging,
 144 [  --enable-debugging     spews vast swathes of useless information],
 145   [if test "$enableval" = "no"; then
 146     AC_DEFINE(NDEBUG, 1)
 147   fi],
 148   AC_DEFINE(NDEBUG, 1))
 149
 150 AC_ARG_ENABLE(tracing,
 151 [  --enable-tracing       enable output of tracing information],
 152   [if test "$enableval" = "yes"; then
 153     AC_DEFINE(TRACING)
 154   fi],
 155   AC_DEFINE(TRACING))
 156
 157 dnl --- Libraries ---
 158
 159 mdw_CHECK_MANYLIBS(socket, socket,,
 160   [AC_MSG_ERROR([Socket library not found])])
 161
 162 mdw_CHECK_MANYLIBS(gethostbyname, resolv nsl,,
 163   [AC_MSG_ERROR([Resolver library not found])])
 164
 165 mdw_CHECK_MANYLIBS(yp_all, nsl, AC_DEFINE(HAVE_YP))
 166
 167 dnl --- Types ---
 168
 169 AC_TYPE_PID_T
 170 AC_TYPE_UID_T
 171 AC_CHECK_TYPE(ssize_t, int)
 172
 173 dnl --- Check on type sizes ---
 174
 175 AC_CHECK_SIZEOF(int, 2)
 176
 177 dnl --- Set the path separator ---
 178
 179 AC_DEFINE(PATHSEP, '/')
 180
 181 dnl --- Check for some useful functions ---
 182
 183 AC_CHECK_FUNCS(setreuid setgroups)
 184 AC_CHECK_FUNCS(getrusage vtimes)
 185
 186 dnl --- Done ---
 187
 188 AC_OUTPUT(Makefile conf/Makefile src/Makefile manual/Makefile,
 189           [test -z "$CONFIG_HEADERS" || echo timestamp >stamp-h])
 190
 191 dnl----- That's all, folks --------------------------------------------------