mdw@git.distorted.org.uk Git - become/blob - configure.in

   1 dnl -*-fundamental-*-
   2 dnl
   3 dnl $Id: configure.in,v 1.18 1999/07/28 09:30:12 mdw Exp $
   4 dnl
   5 dnl Source for auto configuration for `become'
   6 dnl
   7 dnl (c) 1998 Mark Wooding
   8 dnl
   9
  10 dnl----- Licensing notice ---------------------------------------------------
  11 dnl
  12 dnl This file is part of `become'
  13 dnl
  14 dnl `Become' is free software; you can redistribute it and/or modify
  15 dnl it under the terms of the GNU General Public License as published by
  16 dnl the Free Software Foundation; either version 2 of the License, or
  17 dnl (at your option) any later version.
  18 dnl
  19 dnl `Become' is distributed in the hope that it will be useful,
  20 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 dnl GNU General Public License for more details.
  23 dnl
  24 dnl You should have received a copy of the GNU General Public License
  25 dnl along with `become'; if not, write to the Free Software Foundation,
  26 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  27
  28 dnl----- Revision history ---------------------------------------------------
  29 dnl
  30 dnl $Log: configure.in,v $
  31 dnl Revision 1.18  1999/07/28 09:30:12  mdw
  32 dnl Use new-fangled mdw_TYPE_SSIZE_T macro.
  33 dnl
  34 dnl Revision 1.17  1999/05/04 16:25:19  mdw
  35 dnl Fixes for new version of automake.
  36 dnl
  37 dnl Revision 1.16  1998/06/18  15:15:45  mdw
  38 dnl Set version number properly.  D'oh.
  39 dnl
  40 dnl Revision 1.15  1998/06/18 15:11:36  mdw
  41 dnl Change patchlevel.  Check for @sigprocmask@, for improved @noise__shell@
  42 dnl function.
  43 dnl
  44 dnl Revision 1.14  1998/06/08 11:22:16  mdw
  45 dnl Step version number and date.
  46 dnl
  47 dnl Revision 1.13  1998/04/23 13:34:10  mdw
  48 dnl Release version.
  49 dnl
  50 dnl Revision 1.12  1998/04/23 13:09:24  mdw
  51 dnl Add new option to disable networking.
  52 dnl
  53 dnl Revision 1.11  1998/02/20 17:55:56  mdw
  54 dnl Fix default HTML directory.
  55 dnl
  56 dnl Revision 1.10  1998/01/12 16:45:21  mdw
  57 dnl Fix copyright date.
  58 dnl
  59 dnl Revision 1.9  1997/09/18  11:24:27  mdw
  60 dnl Add `conf' directory.  Add an `htmldir' installation directory too.
  61 dnl
  62 dnl Revision 1.8  1997/09/17  10:36:30  mdw
  63 dnl Remove `set.c'.  No longer necessary.
  64 dnl
  65 dnl Revision 1.7  1997/09/09 18:18:41  mdw
  66 dnl Check for setgroups(2), to see whether subsidiary group lists need to be
  67 dnl fiddled with.
  68 dnl
  69 dnl Revision 1.6  1997/09/08  13:41:14  mdw
  70 dnl Check for `setreuid' for changing permissions.
  71 dnl
  72 dnl Revision 1.5  1997/09/05  11:45:18  mdw
  73 dnl Add support for different login styles, and environment variable
  74 dnl manipulation in a safe and useful way.
  75 dnl
  76 dnl Revision 1.4  1997/08/20  16:10:56  mdw
  77 dnl Lowercase `mdw_' prefixes to macros.  Add a `--with-etcdir=PATH'
  78 dnl option.  Update `stamp-h' as required by the Automake docs (silly
  79 dnl me).
  80 dnl
  81 dnl Revision 1.3  1997/08/07 09:34:32  mdw
  82 dnl Added `ElectricFence' support, and support for the `deep' package
  83 dnl structure.
  84 dnl
  85 dnl Revision 1.2  1997/08/04 10:24:21  mdw
  86 dnl Sources placed under CVS control.
  87 dnl
  88 dnl Revision 1.1  1997/07/21  13:47:51  mdw
  89 dnl Initial revision
  90 dnl
  91
  92 AC_INIT(src/icrypt.c)
  93 AM_INIT_AUTOMAKE(become, 1.3.3)
  94 AM_CONFIG_HEADER(config.h)
  95
  96 dnl --- Check for compilers and things ---
  97
  98 AC_PROG_CC
  99 mdw_GCC_FLAGS
 100 AM_PROG_LEX
 101 AC_CHECK_PROG(AR, ar, ar)
 102 AC_PROG_RANLIB
 103 AC_PROG_YACC
 104
 105 dnl --- Set default become style ---
 106
 107 AC_ARG_ENABLE([style],
 108 [  --enable-style=STYLE   set default style to preserve, setuser, or login],
 109 [case "$enableval" in
 110   preserve) style="l_preserve" ;;
 111   su|setuser) style="l_setuser" ;;
 112   login) style="l_login" ;;
 113   *) AC_MSG_ERROR([unknown login style: choose preserve, setuser, or login])
 114      ;;
 115 esac],
 116 [style="l_preserve"])
 117 AC_DEFINE_UNQUOTED(DEFAULT_LOGIN_STYLE, $style)
 118
 119 dnl --- Choose networking options ---
 120
 121 AC_ARG_ENABLE([network],
 122 [  --disable-network      disable the client-server bits of the program],
 123   [if test "$enableval" = "no"; then
 124     AC_DEFINE(NONETWORK)
 125   fi])
 126
 127 dnl --- Set configuration directory ---
 128
 129 AC_ARG_WITH([etcdir],
 130 [  --with-etcdir=PATH     set directory for configuration and key files
 131                           [default is /etc/become]],
 132 [etcdir="$withval"], [etcdir="/etc/become"])
 133 AC_SUBST(etcdir)
 134 AC_DEFINE_UNQUOTED(ETCDIR, "$etcdir")
 135
 136 AC_ARG_WITH([htmldir],
 137 [  --with-htmldir=PATH    set directory for HTML documentation
 138                           [default is PREFIX/html/become]],
 139 [htmldir="$withval"], [htmldir='${prefix}/html/become'])
 140 AC_SUBST(htmldir)
 141
 142 dnl --- Debugging stuff ---
 143
 144 AC_ARG_WITH(electric-fence,
 145 [  --with-electric-fence          link programs with Electric Fence],
 146   [if test "$withval" = "yes"; then
 147     AC_CHECK_LIB(efence, malloc)
 148   fi])
 149
 150 AC_ARG_ENABLE(debugging,
 151 [  --enable-debugging     spews vast swathes of useless information],
 152   [if test "$enableval" = "no"; then
 153     AC_DEFINE(NDEBUG, 1)
 154   fi],
 155   AC_DEFINE(NDEBUG, 1))
 156
 157 AC_ARG_ENABLE(tracing,
 158 [  --enable-tracing       enable output of tracing information],
 159   [if test "$enableval" = "yes"; then
 160     AC_DEFINE(TRACING)
 161   fi],
 162   AC_DEFINE(TRACING))
 163
 164 dnl --- Libraries ---
 165
 166 mdw_CHECK_MANYLIBS(socket, socket,,
 167   [AC_MSG_ERROR([Socket library not found])])
 168
 169 mdw_CHECK_MANYLIBS(gethostbyname, resolv nsl,,
 170   [AC_MSG_ERROR([Resolver library not found])])
 171
 172 mdw_CHECK_MANYLIBS(yp_all, nsl, AC_DEFINE(HAVE_YP))
 173
 174 dnl --- Other functions ---
 175
 176 AC_CHECK_FUNCS(sigprocmask)
 177
 178 dnl --- Types ---
 179
 180 AC_TYPE_PID_T
 181 AC_TYPE_UID_T
 182 mdw_TYPE_SSIZE_T
 183
 184 dnl --- Check on type sizes ---
 185
 186 AC_CHECK_SIZEOF(int, 2)
 187
 188 dnl --- Set the path separator ---
 189
 190 AC_DEFINE(PATHSEP, '/')
 191
 192 dnl --- Check for some useful functions ---
 193
 194 AC_CHECK_FUNCS(setreuid setgroups)
 195 AC_CHECK_FUNCS(getrusage vtimes)
 196
 197 dnl --- Done ---
 198
 199 AC_OUTPUT(Makefile conf/Makefile src/Makefile manual/Makefile)
 200
 201 dnl----- That's all, folks --------------------------------------------------