mdw@git.distorted.org.uk Git - become/blob - configure.in

   1 dnl -*-fundamental-*-
   2 dnl
   3 dnl $Id: configure.in,v 1.4 1997/08/20 16:10:56 mdw Exp $
   4 dnl
   5 dnl Source for auto configuration for `become'
   6 dnl
   7 dnl (c) 1997 Mark Wooding
   8 dnl
   9
  10 dnl----- Licensing notice ---------------------------------------------------
  11 dnl
  12 dnl This file is part of `become'
  13 dnl
  14 dnl `Become' is free software; you can redistribute it and/or modify
  15 dnl it under the terms of the GNU General Public License as published by
  16 dnl the Free Software Foundation; either version 2 of the License, or
  17 dnl (at your option) any later version.
  18 dnl
  19 dnl `Become' is distributed in the hope that it will be useful,
  20 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 dnl GNU General Public License for more details.
  23 dnl
  24 dnl You should have received a copy of the GNU General Public License
  25 dnl along with `become'; if not, write to the Free Software Foundation,
  26 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  27
  28 dnl----- Revision history ---------------------------------------------------
  29 dnl
  30 dnl $Log: configure.in,v $
  31 dnl Revision 1.4  1997/08/20 16:10:56  mdw
  32 dnl Lowercase `mdw_' prefixes to macros.  Add a `--with-etcdir=PATH'
  33 dnl option.  Update `stamp-h' as required by the Automake docs (silly
  34 dnl me).
  35 dnl
  36 dnl Revision 1.3  1997/08/07 09:34:32  mdw
  37 dnl Added `ElectricFence' support, and support for the `deep' package
  38 dnl structure.
  39 dnl
  40 dnl Revision 1.2  1997/08/04 10:24:21  mdw
  41 dnl Sources placed under CVS control.
  42 dnl
  43 dnl Revision 1.1  1997/07/21  13:47:51  mdw
  44 dnl Initial revision
  45 dnl
  46
  47 AC_INIT(src/icrypt.c)
  48 AC_CONFIG_HEADER(config.h)
  49 PACKAGE=become VERSION=1.2-pre
  50 AC_SUBST(PACKAGE)
  51 AC_SUBST(VERSION)
  52 AC_DEFINE(VERSION, "1.2-pre (24 July 1997)")
  53
  54 dnl --- Check for compilers and things ---
  55
  56 AC_PROG_CC
  57 AC_PROG_INSTALL
  58 AC_PROG_LEX
  59 AC_CHECK_PROG(AR, ar, ar)
  60 AC_PROG_RANLIB
  61 AC_PROG_MAKE_SET
  62 AC_PROG_YACC
  63 AC_ARG_PROGRAM
  64 if test "$ac_cv_prog_gcc" = "yes"; then
  65   CFLAGS="$CFLAGS -pedantic -Wall"
  66 fi
  67
  68 dnl --- Libraries ---
  69
  70 mdw_CHECK_MANYLIBS(socket, socket,,
  71   AC_MSG_ERROR([Socket library not found]))
  72
  73 mdw_CHECK_MANYLIBS(gethostbyname, resolv nsl,,
  74   AC_MSG_ERROR([Resolver library not found]))
  75
  76 mdw_CHECK_MANYLIBS(yp_all, nsl, AC_DEFINE(HAVE_YP))
  77
  78 dnl --- Types ---
  79
  80 AC_TYPE_PID_T
  81 AC_TYPE_UID_T
  82 AC_CHECK_TYPE(ssize_t, int)
  83
  84 dnl --- Check on type sizes ---
  85
  86 AC_CHECK_SIZEOF(int, 2)
  87
  88 dnl --- Set the path separator ---
  89
  90 AC_DEFINE(PATHSEP, '/')
  91
  92 dnl --- Check for some useful functions ---
  93
  94 AC_CHECK_FUNCS(getrusage vtimes)
  95
  96 dnl --- Set configuration directory ---
  97
  98 AC_ARG_WITH([etcdir],
  99 [  --with-etcdir=PATH     set directory for configuration and key files
 100                           [default is /etc/become]],
 101 [etcdir="$withval"], [etcdir="/etc/become"])
 102 AC_SUBST(etcdir)
 103 AC_DEFINE_UNQUOTED(ETCDIR, "$etcdir")
 104
 105 dnl --- Debugging stuff ---
 106
 107 AC_ARG_WITH(electric-fence,
 108 [  --with-electric-fence          link programs with Electric Fence],
 109   [if test "$withval" = "yes"; then
 110     AC_CHECK_LIB(efence, malloc)
 111   fi])
 112
 113 AC_ARG_ENABLE(debugging,
 114 [  --enable-debugging     spews vast swathes of useless information],
 115   [if test "$enableval" = "no"; then
 116     AC_DEFINE(NDEBUG, 1)
 117   fi],
 118   AC_DEFINE(NDEBUG, 1))
 119
 120 AC_ARG_ENABLE(tracing,
 121 [  --enable-tracing       enable output of tracing information],
 122   [if test "$enableval" = "yes"; then
 123     AC_DEFINE(TRACING)
 124   fi],
 125   AC_DEFINE(TRACING))
 126
 127 dnl --- Done ---
 128
 129 AC_OUTPUT(Makefile src/Makefile manual/Makefile,
 130           [test -z "$CONFIG_HEADERS" || echo timestamp >stamp-h])
 131
 132 dnl----- That's all, folks --------------------------------------------------