mdw@git.distorted.org.uk Git - become/blob - configure.in

   1 dnl -*-m4-*-
   2 dnl
   3 dnl $Id: configure.in,v 1.22 2004/04/17 10:46:08 mdw Exp $
   4 dnl
   5 dnl Source for auto configuration for `become'
   6 dnl
   7 dnl (c) 1998 Mark Wooding
   8 dnl
   9
  10 dnl----- Licensing notice ---------------------------------------------------
  11 dnl
  12 dnl This file is part of `become'
  13 dnl
  14 dnl `Become' is free software; you can redistribute it and/or modify
  15 dnl it under the terms of the GNU General Public License as published by
  16 dnl the Free Software Foundation; either version 2 of the License, or
  17 dnl (at your option) any later version.
  18 dnl
  19 dnl `Become' is distributed in the hope that it will be useful,
  20 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 dnl GNU General Public License for more details.
  23 dnl
  24 dnl You should have received a copy of the GNU General Public License
  25 dnl along with `become'; if not, write to the Free Software Foundation,
  26 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  27
  28 AC_INIT(src/become.c)
  29 AM_INIT_AUTOMAKE(become, 1.4.0)
  30 AM_CONFIG_HEADER(config.h)
  31
  32 dnl --- Check for compilers and things ---
  33
  34 AC_PROG_CC
  35 mdw_GCC_FLAGS
  36 AM_PROG_LEX
  37 AC_CHECK_PROG(AR, ar, ar)
  38 AC_PROG_RANLIB
  39 AC_PROG_YACC
  40
  41 dnl --- Set default become style ---
  42
  43 AC_ARG_ENABLE([style],
  44 [  --enable-style=STYLE   set default style to preserve, setuser, or login],
  45 [case "$enableval" in
  46   preserve) style="l_preserve" ;;
  47   su|setuser) style="l_setuser" ;;
  48   login) style="l_login" ;;
  49   *) AC_MSG_ERROR([unknown login style: choose preserve, setuser, or login])
  50      ;;
  51 esac],
  52 [style="l_preserve"])
  53 AC_DEFINE_UNQUOTED(DEFAULT_LOGIN_STYLE, $style)
  54
  55 dnl --- Choose networking options ---
  56
  57 AC_ARG_ENABLE([network],
  58 [  --disable-network      disable the client-server bits of the program],
  59   [if test "$enableval" = "no"; then
  60     AC_DEFINE(NONETWORK)
  61   fi])
  62
  63 dnl --- Set configuration directory ---
  64
  65 AC_ARG_WITH([etcdir],
  66 [  --with-etcdir=PATH     set directory for configuration and key files
  67                           [default is /etc/become]],
  68 [etcdir="$withval"], [etcdir="/etc/become"])
  69 AC_SUBST(etcdir)
  70
  71 AC_ARG_WITH([pidfile],
  72 [  --with-pidfile=PATH    set filename for pidfile
  73                           [default is ETCDIR/become/pid]],
  74 [pidfile="$withval"], [pidfile="${etcdir}/become.pid"])
  75 AC_SUBST(pidfile)
  76
  77 AC_ARG_WITH([htmldir],
  78 [  --with-htmldir=PATH    set directory for HTML documentation
  79                           [default is PREFIX/html/become]],
  80 [htmldir="$withval"], [htmldir='${prefix}/html/become'])
  81 AC_SUBST(htmldir)
  82
  83 mdw_DEFINE_PATHS([
  84   mdw_DEFINE_PATH([ETCDIR], [$etcdir])
  85   mdw_DEFINE_PATH([file_PID], [$pidfile])
  86 ])
  87
  88 dnl --- Debugging stuff ---
  89
  90 mdw_OPT_EFENCE
  91 mdw_OPT_NDEBUG
  92 mdw_OPT_TRACE
  93
  94 dnl --- Libraries ---
  95
  96 mdw_MLIB(2.0.1)
  97 mdw_CATACOMB(2.1.0)
  98
  99 mdw_CHECK_MANYLIBS(socket, socket,,
 100   [AC_MSG_ERROR([Socket library not found])])
 101
 102 mdw_CHECK_MANYLIBS(gethostbyname, resolv nsl,,
 103   [AC_MSG_ERROR([Resolver library not found])])
 104
 105 mdw_CHECK_MANYLIBS(yp_all, nsl, AC_DEFINE(HAVE_YP))
 106
 107 dnl --- Other functions ---
 108
 109 AC_CHECK_FUNCS(sigprocmask)
 110
 111 dnl --- Types ---
 112
 113 AC_TYPE_PID_T
 114 AC_TYPE_UID_T
 115 mdw_TYPE_SSIZE_T
 116
 117 dnl --- Set the path separator ---
 118
 119 AC_DEFINE(PATHSEP, '/')
 120
 121 dnl --- Check for some useful functions ---
 122
 123 AC_CHECK_FUNCS(setreuid setgroups)
 124 AC_CHECK_FUNCS(getrusage vtimes)
 125
 126 dnl --- Done ---
 127
 128 AC_OUTPUT(Makefile conf/Makefile src/Makefile manual/Makefile)
 129
 130 dnl----- That's all, folks --------------------------------------------------