git.distorted.org.uk Git - u/mdw/putty/blob - windows/putty.iss

   1 ; -*- no -*-
   2 ; putty.iss
   3 ;
   4 ; -- Inno Setup installer script for PuTTY and its related tools.
   5 ;
   6 ; TODO for future releases:
   7 ;
   8 ;  - It might be nice to have an option to add PSCP, Plink and PSFTP to
   9 ;    the PATH. This is probably only practical on NT-class systems; I
  10 ;    believe doing this on 9x would require mucking around with
  11 ;    AUTOEXEC.BAT.
  12 ;
  13 ;  - Maybe a "custom" installation might be useful? Hassle with icons,
  14 ;    though.
  15
  16 [Setup]
  17 AppName=PuTTY
  18 AppVerName=PuTTY version 0.57
  19 VersionInfoTextVersion=Release 0.57
  20 AppVersion=0.57
  21 ;FIXME -- enable this when we've got it going for individual EXEs too
  22 ;         and are committed to the version numbering scheme.
  23 ;VersionInfoVersion=0.57.0.0
  24 AppPublisher=Simon Tatham
  25 AppPublisherURL=http://www.chiark.greenend.org.uk/~sgtatham/putty/
  26 AppReadmeFile={app}\README.txt
  27 DefaultDirName={pf}\PuTTY
  28 DefaultGroupName=PuTTY
  29 UninstallDisplayIcon={app}\putty.exe
  30 ChangesAssociations=yes
  31 ;ChangesEnvironment=yes -- when PATH munging is sorted (probably)
  32 Compression=zip/9
  33 AllowNoIcons=yes
  34
  35 [Files]
  36 Source: "putty.exe"; DestDir: "{app}"
  37 Source: "pageant.exe"; DestDir: "{app}"
  38 Source: "puttygen.exe"; DestDir: "{app}"
  39 Source: "pscp.exe"; DestDir: "{app}"
  40 Source: "psftp.exe"; DestDir: "{app}"
  41 Source: "plink.exe"; DestDir: "{app}"
  42 Source: "website.url"; DestDir: "{app}"
  43 Source: "..\doc\putty.hlp"; DestDir: "{app}"
  44 Source: "..\doc\putty.cnt"; DestDir: "{app}"
  45 Source: "..\LICENCE"; DestDir: "{app}"
  46 Source: "..\README.txt"; DestDir: "{app}"; Flags: isreadme
  47
  48 [Icons]
  49 Name: "{group}\PuTTY"; Filename: "{app}\putty.exe"; Comment: "SSH, Telnet and Rlogin client";
  50 Name: "{group}\PuTTY Manual"; Filename: "{app}\putty.hlp"
  51 Name: "{group}\PuTTY Web Site"; Filename: "{app}\website.url"
  52 Name: "{group}\PSFTP"; Filename: "{app}\psftp.exe"; Comment: "Command-line interactive SFTP client"
  53 Name: "{group}\PuTTYgen"; Filename: "{app}\puttygen.exe"; Comment: "PuTTY SSH key generation utility"
  54 Name: "{group}\Pageant"; Filename: "{app}\pageant.exe"; Comment: "PuTTY SSH authentication agent"
  55 Name: "{commondesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon\common
  56 Name: "{userdesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon\user
  57 ; Putting this in {commonappdata} doesn't seem to work, on 98SE at least.
  58 Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\PuTTY"; Filename: "{app}\putty.exe"; Tasks: quicklaunchicon
  59
  60 [Tasks]
  61 Name: desktopicon; Description: "Create a &desktop icon for PuTTY"; GroupDescription: "Additional icons:"; Flags: unchecked
  62 Name: desktopicon\common; Description: "For all users"; GroupDescription: "Additional icons:"; Flags: exclusive unchecked
  63 Name: desktopicon\user; Description: "For the current user only"; GroupDescription: "Additional icons:"; Flags: exclusive unchecked
  64 Name: quicklaunchicon; Description: "Create a &Quick Launch icon for PuTTY (current user only)"; GroupDescription: "Additional icons:"; Flags: unchecked
  65 Name: associate; Description: "&Associate .PPK files (PuTTY Private Key) with Pageant and PuTTYgen"; GroupDescription: "Other tasks:"
  66
  67 [Registry]
  68 Root: HKCR; Subkey: ".ppk"; ValueType: string; ValueName: ""; ValueData: "PuTTYPrivateKey"; Flags: uninsdeletevalue; Tasks: associate
  69 Root: HKCR; Subkey: "PuTTYPrivateKey"; ValueType: string; ValueName: ""; ValueData: "PuTTY Private Key File"; Flags: uninsdeletekey; Tasks: associate
  70 Root: HKCR; Subkey: "PuTTYPrivateKey\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\pageant.exe,0"; Tasks: associate
  71 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\pageant.exe"" ""%1"""; Tasks: associate
  72 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit"; ValueType: string; ValueName: ""; ValueData: "&Edit"; Tasks: associate
  73 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit\command"; ValueType: string; ValueName: ""; ValueData: """{app}\puttygen.exe"" ""%1"""; Tasks: associate
  74 ; Add to PATH on NT-class OS?
  75
  76 [UninstallRun]
  77 ; -cleanup-during-uninstall is an undocumented option that tailors the
  78 ; message displayed.
  79 Filename: "{app}\putty.exe"; Parameters: "-cleanup-during-uninstall"; RunOnceId: "PuTTYCleanup"; StatusMsg: "Cleaning up saved sessions etc (optional)..."