git.distorted.org.uk Git - u/mdw/putty/blob - unix/configure.ac

   1 # To compile this into a configure script, you need:
   2 # * Autoconf 2.50 or newer
   3 # * Gtk (for $prefix/share/aclocal/gtk.m4)
   4 # * Automake (for aclocal)
   5 # If you've got them, running "autoreconf" should work.
   6
   7 AC_INIT
   8 AC_CONFIG_FILES([Makefile])
   9 AC_CONFIG_HEADERS([uxconfig.h:uxconfig.in])
  10
  11 AC_PROG_INSTALL
  12 AC_PROG_CC
  13 if test "X$GCC" = Xyes; then
  14     PUTTYCFLAGS="-Wall -Werror"
  15 else
  16     PUTTYCFLAGS=""
  17 fi
  18 AC_SUBST(PUTTYCFLAGS)
  19
  20 AC_ARG_WITH([gssapi],
  21   [AS_HELP_STRING([--without-gssapi],
  22                   [disable GSSAPI support])],
  23   [],
  24   [with_gssapi=yes])
  25
  26 WITH_GSSAPI=
  27 AS_IF([test "x$with_gssapi" != xno],
  28   [AC_DEFINE([WITH_GSSAPI], [1], [Define if building with GSSAPI support.])])
  29
  30 AC_CHECK_HEADERS([utmpx.h sys/select.h],,,[
  31 #include <sys/types.h>
  32 #include <utmp.h>])
  33
  34 # Look for both GTK 1 and GTK 2.
  35 ifdef([AM_PATH_GTK],[
  36 AM_PATH_GTK([1.2.0], [gtk=1], [gtk=none])
  37 ],[AC_WARNING([generating configure script without GTK 1 autodetection])])
  38 ifdef([AM_PATH_GTK_2_0],[
  39 AM_PATH_GTK_2_0([2.0.0], [gtk=2], [])
  40 ],[AC_WARNING([generating configure script without GTK 2 autodetection])])
  41 if test "$gtk" = "none"; then
  42   all_targets="all-cli"
  43 else
  44   all_targets="all-cli all-gtk"
  45 fi
  46 if test "$gtk" = "2"; then
  47   ac_save_CFLAGS="$CFLAGS"
  48   ac_save_LIBS="$LIBS"
  49   CFLAGS="$CFLAGS $GTK_CFLAGS"
  50   LIBS="$GTK_LIBS $LIBS"
  51   AC_CHECK_FUNCS([pango_font_family_is_monospace pango_font_map_list_families])
  52   CFLAGS="$ac_save_CFLAGS"
  53   LIBS="$ac_save_LIBS"
  54 fi
  55 AC_SUBST([all_targets])
  56
  57 AC_SEARCH_LIBS([socket], [xnet])
  58
  59 AS_IF([test "x$with_gssapi" != xno],
  60   [AC_SEARCH_LIBS(
  61     [dlopen],[dl],
  62     [],
  63     [AC_DEFINE([NO_LIBDL], [1], [Define if we could not find libdl.])
  64      AC_CHECK_HEADERS([gssapi/gssapi.h])
  65      AC_SEARCH_LIBS(
  66        [gss_init_sec_context],[gssapi gssapi_krb5 gss],
  67        [],
  68        [AC_DEFINE([NO_GSSAPI_LIB], [1], [Define if we could not find a gssapi library])])])])
  69
  70 AC_CHECK_LIB(X11, XOpenDisplay)
  71
  72 AC_CHECK_FUNCS([getaddrinfo ptsname setresuid strsignal updwtmpx])
  73
  74 AC_OUTPUT
  75
  76 AH_BOTTOM([
  77 /* Convert autoconf definitions to ones that PuTTY wants. */
  78
  79 #ifndef HAVE_GETADDRINFO
  80 # define NO_IPV6
  81 #endif
  82 #ifndef HAVE_SETRESUID
  83 # define HAVE_NO_SETRESUID
  84 #endif
  85 #ifndef HAVE_STRSIGNAL
  86 # define HAVE_NO_STRSIGNAL
  87 #endif
  88 #if !defined(HAVE_UTMPX_H) || !defined(HAVE_UPDWTMPX)
  89 # define OMIT_UTMP
  90 #endif
  91 #ifndef HAVE_PTSNAME
  92 # define BSD_PTYS
  93 #endif
  94 #ifndef HAVE_SYS_SELECT_H
  95 # define HAVE_NO_SYS_SELECT_H
  96 #endif
  97 #ifndef HAVE_PANGO_FONT_FAMILY_IS_MONOSPACE
  98 # define PANGO_PRE_1POINT4
  99 #endif
 100 #ifndef HAVE_PANGO_FONT_MAP_LIST_FAMILIES
 101 # define PANGO_PRE_1POINT6
 102 #endif
 103 #if !defined(WITH_GSSAPI)
 104 # define NO_GSSAPI
 105 #endif
 106 #if !defined(NO_GSSAPI) && defined(NO_LIBDL)
 107 # if !defined(HAVE_GSSAPI_GSSAPI_H) || defined(NO_GSSAPI_LIB)
 108 #  define NO_GSSAPI
 109 # endif
 110 #endif
 111 ])