git.distorted.org.uk Git - u/mdw/putty/blob - putty.iss

   1 ; -*- no -*-
   2 ; putty.iss
   3 ;
   4 ; -- Inno Setup installer script for PuTTY and its related tools.
   5 ;
   6 ; TODO for future releases:
   7 ;
   8 ;  - It would be neighbourly to set up an [UninstallRun] entry that ran
   9 ;    some close cousin of `putty -cleanup', only it should prompt first
  10 ;    in case the user wants to keep stuff. And make the `leave it alone'
  11 ;    button the DEFAULT. And perhaps warn that on NT-style systems not
  12 ;    everything will be caught by this.
  13 ;
  14 ;  - The Quick Launch bar is an interesting thought. Certainly a fair
  15 ;    number of people actually _believe_ my silly joke about how PuTTY
  16 ;    is the only thing that makes Windows usable, so perhaps they'd like
  17 ;    that. Unchecked by default, though, I think.
  18 ;     * does this need to be conditional on the Windows version?
  19
  20 [Setup]
  21 AppName=PuTTY
  22 AppVerName=PuTTY version 0.56
  23 DefaultDirName={pf}\PuTTY
  24 DefaultGroupName=PuTTY
  25 UninstallDisplayIcon={app}\putty.exe
  26 ChangesAssociations=yes
  27 Compression=zip/9
  28
  29 [Files]
  30 Source: "putty.exe"; DestDir: "{app}"
  31 Source: "pageant.exe"; DestDir: "{app}"
  32 Source: "puttygen.exe"; DestDir: "{app}"
  33 Source: "pscp.exe"; DestDir: "{app}"
  34 Source: "psftp.exe"; DestDir: "{app}"
  35 Source: "plink.exe"; DestDir: "{app}"
  36 Source: "website.url"; DestDir: "{app}"
  37 Source: "doc\putty.hlp"; DestDir: "{app}"
  38 Source: "doc\putty.cnt"; DestDir: "{app}"
  39 Source: "LICENCE"; DestDir: "{app}"
  40 Source: "README.txt"; DestDir: "{app}"; Flags: isreadme
  41
  42 [Icons]
  43 Name: "{group}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: startmenu
  44 Name: "{group}\PuTTY Manual"; Filename: "{app}\putty.hlp"; Tasks: startmenu
  45 Name: "{group}\PuTTY Web Site"; Filename: "{app}\website.url"; Tasks: startmenu
  46 Name: "{group}\PSFTP"; Filename: "{app}\psftp.exe"; Tasks: startmenu
  47 Name: "{group}\PuTTYgen"; Filename: "{app}\puttygen.exe"; Tasks: startmenu
  48 Name: "{group}\Pageant"; Filename: "{app}\pageant.exe"; Tasks: startmenu
  49 Name: "{userdesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon
  50
  51 [Tasks]
  52 Name: startmenu; Description: "Create a &Start Menu group"
  53 Name: desktopicon; Description: "Create a &desktop icon for PuTTY"
  54 Name: associate; Description: "&Associate .PPK files (PuTTY Private Key) with Pageant"
  55
  56 [Registry]
  57 Root: HKCR; Subkey: ".ppk"; ValueType: string; ValueName: ""; ValueData: "PuTTYPrivateKey"; Flags: uninsdeletevalue; Tasks: associate
  58 Root: HKCR; Subkey: "PuTTYPrivateKey"; ValueType: string; ValueName: ""; ValueData: "PuTTY Private Key File"; Flags: uninsdeletekey; Tasks: associate
  59 Root: HKCR; Subkey: "PuTTYPrivateKey\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\pageant.exe,0"; Tasks: associate
  60 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\pageant.exe"" ""%1"""; Tasks: associate
  61 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit"; ValueType: string; ValueName: ""; ValueData: "&Edit"; Tasks: associate
  62 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit\command"; ValueType: string; ValueName: ""; ValueData: """{app}\puttygen.exe"" ""%1"""; Tasks: associate