| 1 | ## -*-makefile-*- |
| 2 | ## |
| 3 | ## $Id: Makefile.m4,v 1.28 2000/06/18 23:31:18 mdw Exp $ |
| 4 | ## |
| 5 | ## Makefile for Catacomb |
| 6 | ## |
| 7 | ## (c) 1999 Straylight/Edgeware |
| 8 | ## |
| 9 | |
| 10 | ##----- Licensing notice ---------------------------------------------------- |
| 11 | ## |
| 12 | ## This file is part of Catacomb. |
| 13 | ## |
| 14 | ## Catacomb is free software; you can redistribute it and/or modify |
| 15 | ## it under the terms of the GNU Library General Public License as |
| 16 | ## published by the Free Software Foundation; either version 2 of the |
| 17 | ## License, or (at your option) any later version. |
| 18 | ## |
| 19 | ## Catacomb is distributed in the hope that it will be useful, |
| 20 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 21 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 22 | ## GNU Library General Public License for more details. |
| 23 | ## |
| 24 | ## You should have received a copy of the GNU Library General Public |
| 25 | ## License along with Catacomb; if not, write to the Free |
| 26 | ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, |
| 27 | ## MA 02111-1307, USA. |
| 28 | |
| 29 | ##----- Revision history ---------------------------------------------------- |
| 30 | ## |
| 31 | ## $Log: Makefile.m4,v $ |
| 32 | ## Revision 1.28 2000/06/18 23:31:18 mdw |
| 33 | ## Rearrange build order to ensure that `mptypes.h' exists by the time it's |
| 34 | ## needed. |
| 35 | ## |
| 36 | ## Revision 1.27 2000/06/17 13:28:50 mdw |
| 37 | ## Minor tidying and fixing. |
| 38 | ## |
| 39 | ## Revision 1.26 2000/06/17 10:33:43 mdw |
| 40 | ## Lots of new ciphers and other files. |
| 41 | ## |
| 42 | ## Revision 1.25 2000/02/12 18:55:40 mdw |
| 43 | ## Make it all compile properly. |
| 44 | ## |
| 45 | ## Revision 1.24 2000/02/12 18:22:26 mdw |
| 46 | ## Missed a file. Whoops. |
| 47 | ## |
| 48 | ## Revision 1.23 2000/02/12 18:21:01 mdw |
| 49 | ## Overhaul of key management (again). |
| 50 | ## |
| 51 | ## Revision 1.22 1999/12/22 16:04:06 mdw |
| 52 | ## Lots of new files. |
| 53 | ## |
| 54 | ## Revision 1.21 1999/12/13 15:47:58 mdw |
| 55 | ## Fix a couple of minor bugs in the distribution set. |
| 56 | ## |
| 57 | ## Revision 1.19 1999/12/11 10:58:24 mdw |
| 58 | ## Fix bug in test rig link flags. Add Karatsuba squaring. |
| 59 | ## |
| 60 | ## Revision 1.18 1999/12/10 23:30:01 mdw |
| 61 | ## Lots of new files. |
| 62 | ## |
| 63 | ## Revision 1.17 1999/11/25 11:38:31 mdw |
| 64 | ## Support for conversions between MPs and C integers. |
| 65 | ## |
| 66 | ## Revision 1.16 1999/11/22 20:51:33 mdw |
| 67 | ## Add yet more source files. |
| 68 | ## |
| 69 | ## Revision 1.15 1999/11/22 14:08:30 mdw |
| 70 | ## Improve dependencies for test programs. |
| 71 | ## |
| 72 | ## Revision 1.14 1999/11/22 00:17:09 mdw |
| 73 | ## Create object files for test programs so that rebuilding doesn't take so |
| 74 | ## long. |
| 75 | ## |
| 76 | ## Revision 1.12 1999/11/20 22:36:26 mdw |
| 77 | ## Improve dependencies. Move mpx testing into mpx.c. |
| 78 | ## |
| 79 | ## Revision 1.11 1999/11/20 22:24:53 mdw |
| 80 | ## Add Diffie-Hellman support. |
| 81 | ## |
| 82 | ## Revision 1.10 1999/11/19 19:28:24 mdw |
| 83 | ## Add DSA files and tests. |
| 84 | ## |
| 85 | ## Revision 1.9 1999/11/17 18:05:35 mdw |
| 86 | ## Many new files and test cases for multiprecision arithmetic. |
| 87 | ## |
| 88 | ## Revision 1.8 1999/11/13 01:56:07 mdw |
| 89 | ## Include multiprecision maths stuff. |
| 90 | ## |
| 91 | ## Revision 1.7 1999/11/11 19:01:02 mdw |
| 92 | ## Use `libtool' to generate a shared library. |
| 93 | ## |
| 94 | ## Revision 1.6 1999/11/11 17:47:34 mdw |
| 95 | ## Updates for new configuration system, and `mptypes' generator. |
| 96 | ## |
| 97 | ## Revision 1.5 1999/11/11 00:59:17 mdw |
| 98 | ## Minor reformatting. |
| 99 | ## |
| 100 | ## Revision 1.4 1999/10/24 10:20:36 mdw |
| 101 | ## Modify for standalone distribution. The library's getting far too large |
| 102 | ## to be sensibly embedded in other programs. |
| 103 | ## |
| 104 | ## Revision 1.3 1999/10/24 10:04:26 mdw |
| 105 | ## Install headers in the right directory. |
| 106 | ## |
| 107 | ## Revision 1.2 1999/10/23 12:55:35 mdw |
| 108 | ## The `CVS' directory can't be hardlinked. Don't worry about this |
| 109 | ## overmuch. |
| 110 | ## |
| 111 | ## Revision 1.1 1999/09/03 08:41:11 mdw |
| 112 | ## Initial import. |
| 113 | ## |
| 114 | |
| 115 | AUTOMAKE_OPTIONS = foreign |
| 116 | |
| 117 | SUBDIRS = tests |
| 118 | |
| 119 | archincludedir = $(libdir)/catacomb/include |
| 120 | |
| 121 | ## --- List handling macros --- |
| 122 | ## |
| 123 | ## List handling is nice, usually. Unfortunately, I based this design on |
| 124 | ## TeX list macros rather than anything sensible... |
| 125 | |
| 126 | define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'') |
| 127 | define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')') |
| 128 | define(`join', |
| 129 | `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')') |
| 130 | define(`addsuffix', `adorn(`', `$1', `$2')') |
| 131 | define(`lit', `adorn(`', `$1', `')') |
| 132 | define(`nl', ` |
| 133 | ') |
| 134 | |
| 135 | define(`allwithsuffix', |
| 136 | `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl |
| 137 | addsuffix(join(`$1', `-', `$2'), `$3')') |
| 138 | |
| 139 | ## --- Autogenerated source files --- |
| 140 | |
| 141 | define(`ciphers', `dnl |
| 142 | _(des) _(des3) dnl |
| 143 | _(idea) dnl |
| 144 | _(blowfish) _(twofish) dnl |
| 145 | _(rc2) _(rc5) dnl |
| 146 | _(cast128) _(cast256) dnl |
| 147 | _(rijndael) dnl |
| 148 | _(serpent)') |
| 149 | define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)') |
| 150 | |
| 151 | define(`hashes', `_(md5) _(md4) _(rmd160) _(sha)') |
| 152 | define(`hash_modes', `_(mgf) _(hmac)') |
| 153 | |
| 154 | MODES = \ |
| 155 | adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \ |
| 156 | adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \ |
| 157 | adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \ |
| 158 | adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h') |
| 159 | |
| 160 | $(MODES): |
| 161 | cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')" |
| 162 | cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')" |
| 163 | |
| 164 | des-tab.h: des-mktab |
| 165 | ./des-mktab >des-tab.h |
| 166 | |
| 167 | blowfish-tab.h: blowfish-mktab |
| 168 | ./blowfish-mktab >blowfish-tab.h |
| 169 | |
| 170 | twofish-tab.h: twofish-mktab |
| 171 | ./twofish-mktab >twofish-tab.h |
| 172 | |
| 173 | rijndael-tab.h: rijndael-mktab |
| 174 | ./rijndael-mktab >rijndael-tab.h |
| 175 | |
| 176 | primetab.c primetab.h: genprimes |
| 177 | ./genprimes -h primetab.h -c primetab.c -m 255 \ |
| 178 | -t "unsigned char" -i primetab |
| 179 | |
| 180 | gfshare-tab.h: gfshare-mktab |
| 181 | ./gfshare-mktab >gfshare-tab.h |
| 182 | |
| 183 | archinclude_HEADERS = mptypes.h |
| 184 | |
| 185 | mptypes.h: mptypes |
| 186 | ./mptypes >mptypes.h |
| 187 | |
| 188 | BUILT_SOURCES = \ |
| 189 | getdate.c \ |
| 190 | des-tab.h blowfish-tab.h twofish-tab.h rijndael-tab.h \ |
| 191 | gfshare-tab.h \ |
| 192 | addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \ |
| 193 | addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \ |
| 194 | addsuffix(join(`hashes', `-', `hash_modes'), `.c') \ |
| 195 | addsuffix(join(`hashes', `-', `hash_modes'), `.h') |
| 196 | |
| 197 | ## --- Building the main library --- |
| 198 | |
| 199 | lib_LTLIBRARIES = libcatacomb.la |
| 200 | |
| 201 | libcatacomb_la_LDFLAGS = -version-info 2:0:0 |
| 202 | ## Middle number is the patchlevel. Final number is the minor version. The |
| 203 | ## difference between the first and last numbers is major version. |
| 204 | |
| 205 | pkginclude_HEADERS = \ |
| 206 | arena.h paranoia.h \ |
| 207 | blkc.h hash.h \ |
| 208 | gcipher.h ghash.h gmac.h grand.h \ |
| 209 | ghash-def.h \ |
| 210 | rc4.h seal.h \ |
| 211 | rand.h noise.h fipstest.h maurer.h \ |
| 212 | key.h key-data.h passphrase.h pixie.h lmem.h \ |
| 213 | lcrand.h fibrand.h \ |
| 214 | mpx.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \ |
| 215 | mpbarrett.h mpmont.h mpcrt.h \ |
| 216 | mprand.h \ |
| 217 | primetab.h pfilt.h primorial.h rabin.h \ |
| 218 | pgen.h prim.h strongprime.h \ |
| 219 | bbs.h rsa.h dh.h dsarand.h dsa.h \ |
| 220 | gfshare.h share.h \ |
| 221 | allwithsuffix(`ciphers', `cipher_modes', `.h') \ |
| 222 | allwithsuffix(`hashes', `hash_modes', `.h') \ |
| 223 | addsuffix(`cipher_modes', `-def.h') \ |
| 224 | addsuffix(`hash_modes', `-def.h') |
| 225 | |
| 226 | libcatacomb_la_SOURCES = \ |
| 227 | grand.c keysz.c \ |
| 228 | des-base.c des-base.h \ |
| 229 | cast-s.c cast-sk.c cast-base.h cast-tab.h \ |
| 230 | serpent-sbox.h \ |
| 231 | daftstory.h \ |
| 232 | rc4.c seal.c \ |
| 233 | rand.c noise.c fipstest.c maurer.c \ |
| 234 | arena.c \ |
| 235 | passphrase.c pixie-client.c pixie-common.c lmem.c \ |
| 236 | lcrand.c fibrand.c \ |
| 237 | mpx.c mpx-kmul.c mpx-ksqr.c mpx-kmac.h mpscan.c mparena.c \ |
| 238 | mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \ |
| 239 | mp-gcd.c mp-jacobi.c \ |
| 240 | mpint.c \ |
| 241 | mptext.c mptext-file.c mptext-string.c mptext-dstr.c \ |
| 242 | mpbarrett.c mpmont.c mpmont-mexp.c \ |
| 243 | mpcrt.c \ |
| 244 | mprand.c \ |
| 245 | primetab.c pfilt.c rabin.c primorial.c \ |
| 246 | pgen.c pgen-stdev.c pgen-safe.c pgen-gcd.c prim.c strongprime.c \ |
| 247 | bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \ |
| 248 | rsa-decrypt.c rsa-gen.c rsa-recover.c rsa-fetch.c \ |
| 249 | dh-gen.c dh-fetch.c \ |
| 250 | dsarand.c dsa-sign.c dsa-verify.c dsa-gen.c dsa-fetch.c \ |
| 251 | gfshare.c share.c \ |
| 252 | key-data.c key-flags.c key-text.c key-binary.c key-pass.c \ |
| 253 | key-pack.c \ |
| 254 | key-misc.c key-file.c key-attr.c key-io.c key-moan.c key-error.c \ |
| 255 | key-fetch.c \ |
| 256 | addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \ |
| 257 | addsuffix(join(`hashes', `-', `hash_modes'), `.c') \ |
| 258 | addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c') |
| 259 | |
| 260 | des-base.lo: des-tab.h |
| 261 | blowfish.lo: blowfish-tab.h |
| 262 | twofish.lo: twofish-tab.h |
| 263 | rijndael.lo: rijndael-tab.h |
| 264 | mpx.lo: mptypes.h |
| 265 | |
| 266 | ## --- Utility programs --- |
| 267 | |
| 268 | bin_PROGRAMS = dsig key pixie rspit |
| 269 | bin_SCRIPTS = catacomb-config xpixie |
| 270 | noinst_PROGRAMS = \ |
| 271 | genprimes mptypes \ |
| 272 | des-mktab blowfish-mktab twofish-mktab rijndael-mktab serpent-check \ |
| 273 | gfshare-mktab |
| 274 | LDADD = libcatacomb.la |
| 275 | |
| 276 | dsig_SOURCES = dsig.c getdate.y getdate.h |
| 277 | |
| 278 | key_SOURCES = keyutil.c getdate.y getdate.h |
| 279 | |
| 280 | pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c |
| 281 | pixie_LDADD = |
| 282 | |
| 283 | rspit_SOURCES = rspit.c |
| 284 | |
| 285 | des_mktab_SOURCES = des-mktab.c |
| 286 | des_mktab_LDADD = |
| 287 | |
| 288 | blowfish_mktab_SOURCES = blowfish-mktab.c |
| 289 | blowfish_mktab_LDADD = |
| 290 | |
| 291 | twofish_mktab_SOURCES = twofish-mktab.c |
| 292 | twofish_mktab_LDADD = |
| 293 | |
| 294 | rijndael_mktab_SOURCES = rijndael-mktab.c |
| 295 | rijndael_mktab_LDADD = |
| 296 | |
| 297 | serpent_check_SOURCES = serpent-check.c |
| 298 | serpent_check_LDADD = |
| 299 | |
| 300 | gfshare_mktab_SOURCES = gfshare-mktab.c |
| 301 | gfshare_mktab_LDADD = |
| 302 | |
| 303 | genprimes_SOURCES = genprimes.c |
| 304 | genprimes_LDADD = |
| 305 | |
| 306 | mptypes_SOURCES = mptypes.c |
| 307 | mptypes_LDADD = |
| 308 | |
| 309 | ## --- Install the pixie setuid-root if we can --- |
| 310 | |
| 311 | changequote(<, >) |
| 312 | install-exec-hook: |
| 313 | @pixie="$(bindir)/`echo pixie|sed $(transform)`"; \ |
| 314 | if chown root $$pixie && chmod 4755 $$pixie; then \ |
| 315 | echo "chown root $$pixie"; \ |
| 316 | echo "chmod 4755 $$pixie"; \ |
| 317 | else \ |
| 318 | echo "***"; \ |
| 319 | echo "*** You should probably install $$pixie setuid-root."; \ |
| 320 | echo "***"; \ |
| 321 | fi |
| 322 | changequote(`, ') |
| 323 | |
| 324 | ## --- Documentation --- |
| 325 | |
| 326 | man_MANS = key.1 keyring.5 |
| 327 | |
| 328 | ## --- Other handy definitions --- |
| 329 | |
| 330 | EXTRA_DIST = \ |
| 331 | Makefile.m4 genmodes $(man_MANS) xpixie \ |
| 332 | README.cipher README.hash README.random README.mp |
| 333 | |
| 334 | dist-hook: |
| 335 | @ln getdate.c $(distdir) || ln $(srcdir)/getdate.c $(distdir) || true |
| 336 | @mkdir $(distdir)/tests || true |
| 337 | @ln $(srcdir)/tests/* $(distdir)/tests || true |
| 338 | @rm -f $(distdir)/tests/*~ |
| 339 | # kr=$$HOME/.catacomb/dsig-keyring; \ |
| 340 | # if [ -r $$kr ]; then \ |
| 341 | # cd $(distdir); \ |
| 342 | # ../key -k $$kr extract -f -secret KEYRING; \ |
| 343 | # find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \ |
| 344 | # fi |
| 345 | |
| 346 | ## --- Testing --- |
| 347 | |
| 348 | define(`testprogs', `') |
| 349 | |
| 350 | define(`CTESTRIG', |
| 351 | `define(`testprogs', testprogs \ |
| 352 | $1.t)dnl |
| 353 | $1.to: $1.c |
| 354 | $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to |
| 355 | $1.t: $1.to $1.o libcatacomb.la |
| 356 | $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t') |
| 357 | |
| 358 | CTESTRIG(rc4) |
| 359 | CTESTRIG(seal) |
| 360 | adorn(`nl`'CTESTRIG(', `ciphers', `)') |
| 361 | adorn(`nl`'CTESTRIG(', `hashes', `)') |
| 362 | adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)') |
| 363 | adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)') |
| 364 | CTESTRIG(lcrand) |
| 365 | CTESTRIG(mpx) |
| 366 | CTESTRIG(mpx-kmul) |
| 367 | CTESTRIG(mpx-ksqr) |
| 368 | CTESTRIG(mp-arith) |
| 369 | CTESTRIG(mp-gcd) |
| 370 | CTESTRIG(mp-jacobi) |
| 371 | CTESTRIG(mptext) |
| 372 | CTESTRIG(mpint) |
| 373 | CTESTRIG(mpbarrett) |
| 374 | CTESTRIG(mpmont) |
| 375 | CTESTRIG(mpmont-mexp) |
| 376 | CTESTRIG(mpcrt) |
| 377 | CTESTRIG(pgen) |
| 378 | CTESTRIG(dsa-gen) |
| 379 | CTESTRIG(dsa-sign) |
| 380 | CTESTRIG(dsa-verify) |
| 381 | CTESTRIG(bbs-rand) |
| 382 | CTESTRIG(bbs-jump) |
| 383 | CTESTRIG(gfshare) |
| 384 | CTESTRIG(share) |
| 385 | |
| 386 | TESTS = testprogs |
| 387 | |
| 388 | CLEANFILES = \ |
| 389 | *.t *.to \ |
| 390 | mptypes.h primetab.c primetab.h \ |
| 391 | des-sp.h twofish-tab.h blowfish-tab.h |
| 392 | |
| 393 | ## --- Makefile building (haha!) --- |
| 394 | |
| 395 | $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4 |
| 396 | m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am |
| 397 | |
| 398 | MAINTAINERCLEANFILES = \ |
| 399 | $(srcdir)/Makefile.am \ |
| 400 | $(srcdir)/getdate.c getdate.c \ |
| 401 | $(MODES) |
| 402 | |
| 403 | ##----- That's all, folks --------------------------------------------------- |