| 1 | ## -*-makefile-*- |
| 2 | ## |
| 3 | ## $Id: Makefile.m4,v 1.17 1999/11/25 11:38:31 mdw Exp $ |
| 4 | ## |
| 5 | ## Makefile for Catacomb |
| 6 | ## |
| 7 | ## (c) 1999 Straylight/Edgeware |
| 8 | ## |
| 9 | |
| 10 | ##----- Licensing notice ---------------------------------------------------- |
| 11 | ## |
| 12 | ## This file is part of Catacomb. |
| 13 | ## |
| 14 | ## Catacomb is free software; you can redistribute it and/or modify |
| 15 | ## it under the terms of the GNU Library General Public License as |
| 16 | ## published by the Free Software Foundation; either version 2 of the |
| 17 | ## License, or (at your option) any later version. |
| 18 | ## |
| 19 | ## Catacomb is distributed in the hope that it will be useful, |
| 20 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 21 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 22 | ## GNU Library General Public License for more details. |
| 23 | ## |
| 24 | ## You should have received a copy of the GNU Library General Public |
| 25 | ## License along with Catacomb; if not, write to the Free |
| 26 | ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, |
| 27 | ## MA 02111-1307, USA. |
| 28 | |
| 29 | ##----- Revision history ---------------------------------------------------- |
| 30 | ## |
| 31 | ## $Log: Makefile.m4,v $ |
| 32 | ## Revision 1.17 1999/11/25 11:38:31 mdw |
| 33 | ## Support for conversions between MPs and C integers. |
| 34 | ## |
| 35 | ## Revision 1.16 1999/11/22 20:51:33 mdw |
| 36 | ## Add yet more source files. |
| 37 | ## |
| 38 | ## Revision 1.15 1999/11/22 14:08:30 mdw |
| 39 | ## Improve dependencies for test programs. |
| 40 | ## |
| 41 | ## Revision 1.14 1999/11/22 00:17:09 mdw |
| 42 | ## Create object files for test programs so that rebuilding doesn't take so |
| 43 | ## long. |
| 44 | ## |
| 45 | ## Revision 1.12 1999/11/20 22:36:26 mdw |
| 46 | ## Improve dependencies. Move mpx testing into mpx.c. |
| 47 | ## |
| 48 | ## Revision 1.11 1999/11/20 22:24:53 mdw |
| 49 | ## Add Diffie-Hellman support. |
| 50 | ## |
| 51 | ## Revision 1.10 1999/11/19 19:28:24 mdw |
| 52 | ## Add DSA files and tests. |
| 53 | ## |
| 54 | ## Revision 1.9 1999/11/17 18:05:35 mdw |
| 55 | ## Many new files and test cases for multiprecision arithmetic. |
| 56 | ## |
| 57 | ## Revision 1.8 1999/11/13 01:56:07 mdw |
| 58 | ## Include multiprecision maths stuff. |
| 59 | ## |
| 60 | ## Revision 1.7 1999/11/11 19:01:02 mdw |
| 61 | ## Use `libtool' to generate a shared library. |
| 62 | ## |
| 63 | ## Revision 1.6 1999/11/11 17:47:34 mdw |
| 64 | ## Updates for new configuration system, and `mptypes' generator. |
| 65 | ## |
| 66 | ## Revision 1.5 1999/11/11 00:59:17 mdw |
| 67 | ## Minor reformatting. |
| 68 | ## |
| 69 | ## Revision 1.4 1999/10/24 10:20:36 mdw |
| 70 | ## Modify for standalone distribution. The library's getting far too large |
| 71 | ## to be sensibly embedded in other programs. |
| 72 | ## |
| 73 | ## Revision 1.3 1999/10/24 10:04:26 mdw |
| 74 | ## Install headers in the right directory. |
| 75 | ## |
| 76 | ## Revision 1.2 1999/10/23 12:55:35 mdw |
| 77 | ## The `CVS' directory can't be hardlinked. Don't worry about this |
| 78 | ## overmuch. |
| 79 | ## |
| 80 | ## Revision 1.1 1999/09/03 08:41:11 mdw |
| 81 | ## Initial import. |
| 82 | ## |
| 83 | |
| 84 | AUTOMAKE_OPTIONS = foreign |
| 85 | |
| 86 | archincludedir = $(libdir)/catacomb/include |
| 87 | |
| 88 | ## --- List handling macros --- |
| 89 | ## |
| 90 | ## List handling is nice, usually. Unfortunately, I based this design on |
| 91 | ## TeX list macros rather than anything sensible... |
| 92 | |
| 93 | define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'') |
| 94 | define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')') |
| 95 | define(`join', |
| 96 | `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')') |
| 97 | define(`addsuffix', `adorn(`', `$1', `$2')') |
| 98 | define(`lit', `adorn(`', `$1', `')') |
| 99 | define(`nl', ` |
| 100 | ') |
| 101 | |
| 102 | define(`allwithsuffix', |
| 103 | `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl |
| 104 | addsuffix(join(`$1', `-', `$2'), `$3')') |
| 105 | |
| 106 | ## --- Autogenerated source files --- |
| 107 | |
| 108 | define(`ciphers', `_(des) _(des3) _(blowfish) _(idea) _(rc5)') |
| 109 | define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb)') |
| 110 | |
| 111 | define(`hashes', `_(md5) _(md4) _(rmd160) _(sha)') |
| 112 | define(`hash_modes', `_(hmac)') |
| 113 | |
| 114 | MODES = \ |
| 115 | adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \ |
| 116 | adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \ |
| 117 | adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \ |
| 118 | adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h') |
| 119 | |
| 120 | $(MODES): $(srcdir)/genmodes |
| 121 | cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')" |
| 122 | cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')" |
| 123 | |
| 124 | des_sp.h: des-mktab |
| 125 | ./des-mktab >des_sp.h |
| 126 | |
| 127 | ptab.c ptab.h: genprimes |
| 128 | ./genprimes -h ptab.h -c ptab.c -m 256 -t "unsigned char" -i ptab |
| 129 | |
| 130 | archinclude_HEADERS = mptypes.h |
| 131 | |
| 132 | mptypes.h: mptypes |
| 133 | ./mptypes >mptypes.h |
| 134 | |
| 135 | BUILT_SOURCES = \ |
| 136 | getdate.c \ |
| 137 | addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \ |
| 138 | addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \ |
| 139 | addsuffix(join(`hashes', `-', `hash_modes'), `.c') \ |
| 140 | addsuffix(join(`hashes', `-', `hash_modes'), `.h') |
| 141 | |
| 142 | ## --- Building the main library --- |
| 143 | |
| 144 | lib_LTLIBRARIES = libcatacomb.la |
| 145 | |
| 146 | libcatacomb_la_LDFLAGS = -version-info 0:4:0 |
| 147 | ## Middle number is the patchlevel. Final number is the minor version. The |
| 148 | ## difference between the first and last numbers is major version. |
| 149 | |
| 150 | define(`emit', `$1.h ') |
| 151 | pkginclude_HEADERS = \ |
| 152 | paranoia.h \ |
| 153 | blkc.h hash.h \ |
| 154 | rc4.h \ |
| 155 | rand.h noise.h \ |
| 156 | key.h \ |
| 157 | mpx.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \ |
| 158 | mpmont.h mpcrt.h \ |
| 159 | ptab.h pgen.h rabin.h \ |
| 160 | dsa.h dh.h \ |
| 161 | allwithsuffix(`ciphers', `cipher_modes', `.h') \ |
| 162 | allwithsuffix(`hashes', `hash_modes', `.h') |
| 163 | |
| 164 | define(`emit', `$1.c ') |
| 165 | libcatacomb_la_SOURCES = \ |
| 166 | des-base.c des-base.h des_sp.h bf_ikey.h daftstory.h \ |
| 167 | rc4.c \ |
| 168 | rand.c noise.c \ |
| 169 | key.c \ |
| 170 | mpx.c mpscan.c mparena.c \ |
| 171 | mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \ |
| 172 | mp-gcd.c mp-jacobi.c \ |
| 173 | mpint.c \ |
| 174 | mptext.c mptext-file.c mptext-string.c mptext-dstr.c \ |
| 175 | mpmont.c mpmont-mexp.c \ |
| 176 | mpcrt.c \ |
| 177 | ptab.c pgen.c rabin.c \ |
| 178 | dsa-sign.c dsa-verify.c dsa-gen.c \ |
| 179 | dh-prime.c \ |
| 180 | addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \ |
| 181 | addsuffix(join(`hashes', `-', `hash_modes'), `.c') \ |
| 182 | addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c') |
| 183 | |
| 184 | des-base.lo: des_sp.h |
| 185 | mpx.lo: mptypes.h |
| 186 | |
| 187 | ## --- Utility programs --- |
| 188 | |
| 189 | bin_PROGRAMS = key |
| 190 | bin_SCRIPTS = catacomb-config |
| 191 | noinst_PROGRAMS = des-mktab genprimes mptypes |
| 192 | LDADD = libcatacomb.la |
| 193 | |
| 194 | key_SOURCES = keyutil.c getdate.y getdate.h |
| 195 | |
| 196 | des_mktab_SOURCES = des-mktab.c |
| 197 | des_mktab_LDADD = |
| 198 | |
| 199 | genprimes_SOURCES = genprimes.c |
| 200 | genprimes_LDADD = |
| 201 | |
| 202 | mptypes_SOURCES = mptypes.c |
| 203 | mptypes_LDADD = |
| 204 | |
| 205 | ## --- Documentation --- |
| 206 | |
| 207 | man_MANS = key.1 keyring.5 |
| 208 | |
| 209 | ## --- Other handy definitions --- |
| 210 | |
| 211 | EXTRA_DIST = Makefile.m4 genmodes $(man_MANS) |
| 212 | |
| 213 | dist-hook: |
| 214 | @ln getdate.c $(distdir) || ln $(srcdir)/getdate.c $(distdir) || true |
| 215 | @mkdir $(distdir)/tests |
| 216 | @ln $(srcdir)/tests/* $(distdir)/tests || true |
| 217 | @rm -f $(distdir)/tests/*~ |
| 218 | |
| 219 | ## --- Testing --- |
| 220 | |
| 221 | define(`testprogs', `') |
| 222 | |
| 223 | define(`CTESTRIG', |
| 224 | `define(`testprogs', testprogs \ |
| 225 | $1.t)dnl |
| 226 | $1.to: $1.c |
| 227 | $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to |
| 228 | $1.t: $1.to libcatacomb.la |
| 229 | $(CC) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t') |
| 230 | |
| 231 | CTESTRIG(rc4) |
| 232 | adorn(`nl`'CTESTRIG(', `ciphers', `)') |
| 233 | adorn(`nl`'CTESTRIG(', `hashes', `)') |
| 234 | adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)') |
| 235 | adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)') |
| 236 | CTESTRIG(mpx) |
| 237 | CTESTRIG(mptext) |
| 238 | CTESTRIG(mp-arith) |
| 239 | CTESTRIG(mp-gcd) |
| 240 | CTESTRIG(mp-jacobi) |
| 241 | CTESTRIG(mpint) |
| 242 | CTESTRIG(mpmont) |
| 243 | CTESTRIG(mpmont-mexp) |
| 244 | CTESTRIG(mpcrt) |
| 245 | CTESTRIG(pgen) |
| 246 | CTESTRIG(dsa-gen) |
| 247 | CTESTRIG(dsa-sign) |
| 248 | CTESTRIG(dsa-verify) |
| 249 | |
| 250 | TESTS = testprogs |
| 251 | |
| 252 | CLEANFILES = *.t *.to mptypes.h des_sp.h ptab.c ptab.h |
| 253 | |
| 254 | ## --- Makefile building (haha!) --- |
| 255 | |
| 256 | $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4 |
| 257 | m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am |
| 258 | |
| 259 | MAINTAINERCLEANFILES = \ |
| 260 | $(srcdir)/Makefile.am \ |
| 261 | $(srcdir)/getdate.c getdate.c \ |
| 262 | $(MODES) |
| 263 | |
| 264 | ##----- That's all, folks --------------------------------------------------- |