| 1 | ## -*-makefile-*- |
| 2 | ## |
| 3 | ## $Id: Makefile.m4,v 1.26 2000/06/17 10:33:43 mdw Exp $ |
| 4 | ## |
| 5 | ## Makefile for Catacomb |
| 6 | ## |
| 7 | ## (c) 1999 Straylight/Edgeware |
| 8 | ## |
| 9 | |
| 10 | ##----- Licensing notice ---------------------------------------------------- |
| 11 | ## |
| 12 | ## This file is part of Catacomb. |
| 13 | ## |
| 14 | ## Catacomb is free software; you can redistribute it and/or modify |
| 15 | ## it under the terms of the GNU Library General Public License as |
| 16 | ## published by the Free Software Foundation; either version 2 of the |
| 17 | ## License, or (at your option) any later version. |
| 18 | ## |
| 19 | ## Catacomb is distributed in the hope that it will be useful, |
| 20 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 21 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 22 | ## GNU Library General Public License for more details. |
| 23 | ## |
| 24 | ## You should have received a copy of the GNU Library General Public |
| 25 | ## License along with Catacomb; if not, write to the Free |
| 26 | ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, |
| 27 | ## MA 02111-1307, USA. |
| 28 | |
| 29 | ##----- Revision history ---------------------------------------------------- |
| 30 | ## |
| 31 | ## $Log: Makefile.m4,v $ |
| 32 | ## Revision 1.26 2000/06/17 10:33:43 mdw |
| 33 | ## Lots of new ciphers and other files. |
| 34 | ## |
| 35 | ## Revision 1.25 2000/02/12 18:55:40 mdw |
| 36 | ## Make it all compile properly. |
| 37 | ## |
| 38 | ## Revision 1.24 2000/02/12 18:22:26 mdw |
| 39 | ## Missed a file. Whoops. |
| 40 | ## |
| 41 | ## Revision 1.23 2000/02/12 18:21:01 mdw |
| 42 | ## Overhaul of key management (again). |
| 43 | ## |
| 44 | ## Revision 1.22 1999/12/22 16:04:06 mdw |
| 45 | ## Lots of new files. |
| 46 | ## |
| 47 | ## Revision 1.21 1999/12/13 15:47:58 mdw |
| 48 | ## Fix a couple of minor bugs in the distribution set. |
| 49 | ## |
| 50 | ## Revision 1.19 1999/12/11 10:58:24 mdw |
| 51 | ## Fix bug in test rig link flags. Add Karatsuba squaring. |
| 52 | ## |
| 53 | ## Revision 1.18 1999/12/10 23:30:01 mdw |
| 54 | ## Lots of new files. |
| 55 | ## |
| 56 | ## Revision 1.17 1999/11/25 11:38:31 mdw |
| 57 | ## Support for conversions between MPs and C integers. |
| 58 | ## |
| 59 | ## Revision 1.16 1999/11/22 20:51:33 mdw |
| 60 | ## Add yet more source files. |
| 61 | ## |
| 62 | ## Revision 1.15 1999/11/22 14:08:30 mdw |
| 63 | ## Improve dependencies for test programs. |
| 64 | ## |
| 65 | ## Revision 1.14 1999/11/22 00:17:09 mdw |
| 66 | ## Create object files for test programs so that rebuilding doesn't take so |
| 67 | ## long. |
| 68 | ## |
| 69 | ## Revision 1.12 1999/11/20 22:36:26 mdw |
| 70 | ## Improve dependencies. Move mpx testing into mpx.c. |
| 71 | ## |
| 72 | ## Revision 1.11 1999/11/20 22:24:53 mdw |
| 73 | ## Add Diffie-Hellman support. |
| 74 | ## |
| 75 | ## Revision 1.10 1999/11/19 19:28:24 mdw |
| 76 | ## Add DSA files and tests. |
| 77 | ## |
| 78 | ## Revision 1.9 1999/11/17 18:05:35 mdw |
| 79 | ## Many new files and test cases for multiprecision arithmetic. |
| 80 | ## |
| 81 | ## Revision 1.8 1999/11/13 01:56:07 mdw |
| 82 | ## Include multiprecision maths stuff. |
| 83 | ## |
| 84 | ## Revision 1.7 1999/11/11 19:01:02 mdw |
| 85 | ## Use `libtool' to generate a shared library. |
| 86 | ## |
| 87 | ## Revision 1.6 1999/11/11 17:47:34 mdw |
| 88 | ## Updates for new configuration system, and `mptypes' generator. |
| 89 | ## |
| 90 | ## Revision 1.5 1999/11/11 00:59:17 mdw |
| 91 | ## Minor reformatting. |
| 92 | ## |
| 93 | ## Revision 1.4 1999/10/24 10:20:36 mdw |
| 94 | ## Modify for standalone distribution. The library's getting far too large |
| 95 | ## to be sensibly embedded in other programs. |
| 96 | ## |
| 97 | ## Revision 1.3 1999/10/24 10:04:26 mdw |
| 98 | ## Install headers in the right directory. |
| 99 | ## |
| 100 | ## Revision 1.2 1999/10/23 12:55:35 mdw |
| 101 | ## The `CVS' directory can't be hardlinked. Don't worry about this |
| 102 | ## overmuch. |
| 103 | ## |
| 104 | ## Revision 1.1 1999/09/03 08:41:11 mdw |
| 105 | ## Initial import. |
| 106 | ## |
| 107 | |
| 108 | AUTOMAKE_OPTIONS = foreign |
| 109 | |
| 110 | SUBDIRS = tests |
| 111 | |
| 112 | archincludedir = $(libdir)/catacomb/include |
| 113 | |
| 114 | ## --- List handling macros --- |
| 115 | ## |
| 116 | ## List handling is nice, usually. Unfortunately, I based this design on |
| 117 | ## TeX list macros rather than anything sensible... |
| 118 | |
| 119 | define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'') |
| 120 | define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')') |
| 121 | define(`join', |
| 122 | `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')') |
| 123 | define(`addsuffix', `adorn(`', `$1', `$2')') |
| 124 | define(`lit', `adorn(`', `$1', `')') |
| 125 | define(`nl', ` |
| 126 | ') |
| 127 | |
| 128 | define(`allwithsuffix', |
| 129 | `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl |
| 130 | addsuffix(join(`$1', `-', `$2'), `$3')') |
| 131 | |
| 132 | ## --- Autogenerated source files --- |
| 133 | |
| 134 | define(`ciphers', `dnl |
| 135 | _(des) _(des3) dnl |
| 136 | _(idea) dnl |
| 137 | _(blowfish) _(twofish) dnl |
| 138 | _(rc2) _(rc5) dnl |
| 139 | _(cast128) _(cast256) dnl |
| 140 | _(rijndael) dnl |
| 141 | _(serpent)') |
| 142 | define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)') |
| 143 | |
| 144 | define(`hashes', `_(md5) _(md4) _(rmd160) _(sha)') |
| 145 | define(`hash_modes', `_(mgf) _(hmac)') |
| 146 | |
| 147 | MODES = \ |
| 148 | adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \ |
| 149 | adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \ |
| 150 | adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \ |
| 151 | adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h') |
| 152 | |
| 153 | $(MODES): |
| 154 | cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')" |
| 155 | cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')" |
| 156 | |
| 157 | des-tab.h: des-mktab |
| 158 | ./des-mktab >des-tab.h |
| 159 | |
| 160 | blowfish-tab.h: blowfish-mktab |
| 161 | ./blowfish-mktab >blowfish-tab.h |
| 162 | |
| 163 | twofish-tab.h: twofish-mktab |
| 164 | ./twofish-mktab >twofish-tab.h |
| 165 | |
| 166 | rijndael-tab.h: rijndael-mktab |
| 167 | ./rijndael-mktab >rijndael-tab.h |
| 168 | |
| 169 | primetab.c primetab.h: genprimes |
| 170 | ./genprimes -h primetab.h -c primetab.c -m 255 \ |
| 171 | -t "unsigned char" -i primetab |
| 172 | |
| 173 | gfshare-tab.h: gfshare-mktab |
| 174 | ./gfshare-mktab >gfshare-tab.h |
| 175 | |
| 176 | archinclude_HEADERS = mptypes.h |
| 177 | |
| 178 | mptypes.h: mptypes |
| 179 | ./mptypes >mptypes.h |
| 180 | |
| 181 | BUILT_SOURCES = \ |
| 182 | getdate.c \ |
| 183 | des-tab.h blowfish-tab.h twofish-tab.h rijndael-tab.h \ |
| 184 | gfshare-tab.h \ |
| 185 | addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \ |
| 186 | addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \ |
| 187 | addsuffix(join(`hashes', `-', `hash_modes'), `.c') \ |
| 188 | addsuffix(join(`hashes', `-', `hash_modes'), `.h') |
| 189 | |
| 190 | ## --- Building the main library --- |
| 191 | |
| 192 | lib_LTLIBRARIES = libcatacomb.la |
| 193 | |
| 194 | libcatacomb_la_LDFLAGS = -version-info 2:0:0 |
| 195 | ## Middle number is the patchlevel. Final number is the minor version. The |
| 196 | ## difference between the first and last numbers is major version. |
| 197 | |
| 198 | define(`emit', `$1.h ') |
| 199 | pkginclude_HEADERS = \ |
| 200 | arena.h paranoia.h \ |
| 201 | blkc.h hash.h \ |
| 202 | gcipher.h ghash.h gmac.h grand.h \ |
| 203 | ghash-def.h \ |
| 204 | rc4.h seal.h \ |
| 205 | rand.h noise.h fipstest.h maurer.h \ |
| 206 | key.h key-data.h passphrase.h pixie.h lmem.h \ |
| 207 | lcrand.h fibrand.h \ |
| 208 | mpx.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \ |
| 209 | mpbarrett.h mpmont.h mpcrt.h \ |
| 210 | mprand.h \ |
| 211 | primetab.h pfilt.h primorial.h rabin.h \ |
| 212 | pgen.h prim.h strongprime.h \ |
| 213 | bbs.h rsa.h dh.h dsarand.h dsa.h \ |
| 214 | gfshare.h share.h \ |
| 215 | allwithsuffix(`ciphers', `cipher_modes', `.h') \ |
| 216 | allwithsuffix(`hashes', `hash_modes', `.h') \ |
| 217 | addsuffix(`cipher_modes', `-def.h') \ |
| 218 | addsuffix(`hash_modes', `-def.h') |
| 219 | |
| 220 | define(`emit', `$1.c ') |
| 221 | libcatacomb_la_SOURCES = \ |
| 222 | grand.c keysz.c \ |
| 223 | des-base.c des-base.h \ |
| 224 | cast-s.c cast-sk.c cast-base.h cast-tab.h \ |
| 225 | daftstory.h \ |
| 226 | rc4.c seal.c \ |
| 227 | rand.c noise.c fipstest.c maurer.c \ |
| 228 | arena.c \ |
| 229 | key-data.c key-flags.c key-text.c key-binary.c key-pass.c \ |
| 230 | key-pack.c \ |
| 231 | key-misc.c key-file.c key-attr.c key-io.c key-moan.c key-error.c \ |
| 232 | key-fetch.c \ |
| 233 | passphrase.c pixie-client.c pixie-common.c lmem.c \ |
| 234 | lcrand.c fibrand.c \ |
| 235 | mpx.c mpx-kmul.c mpx-ksqr.c mpscan.c mparena.c \ |
| 236 | mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \ |
| 237 | mp-gcd.c mp-jacobi.c \ |
| 238 | mpint.c \ |
| 239 | mptext.c mptext-file.c mptext-string.c mptext-dstr.c \ |
| 240 | mpbarrett.c mpmont.c mpmont-mexp.c \ |
| 241 | mpcrt.c \ |
| 242 | mprand.c \ |
| 243 | primetab.c pfilt.c rabin.c primorial.c \ |
| 244 | pgen.c pgen-stdev.c pgen-safe.c pgen-gcd.c prim.c strongprime.c \ |
| 245 | bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \ |
| 246 | rsa-decrypt.c rsa-gen.c rsa-recover.c rsa-fetch.c \ |
| 247 | dh-gen.c dh-fetch.c \ |
| 248 | dsarand.c dsa-sign.c dsa-verify.c dsa-gen.c dsa-fetch.c \ |
| 249 | gfshare.c share.c \ |
| 250 | addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \ |
| 251 | addsuffix(join(`hashes', `-', `hash_modes'), `.c') \ |
| 252 | addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c') |
| 253 | |
| 254 | des-base.lo: des-tab.h |
| 255 | blowfish.lo: blowfish-tab.h |
| 256 | twofish.lo: twofish-tab.h |
| 257 | rijndael.lo: rijndael-tab.h |
| 258 | mpx.lo: mptypes.h |
| 259 | |
| 260 | ## --- Utility programs --- |
| 261 | |
| 262 | bin_PROGRAMS = dsig key pixie rspit |
| 263 | bin_SCRIPTS = catacomb-config xpixie |
| 264 | noinst_PROGRAMS = \ |
| 265 | genprimes mptypes \ |
| 266 | des-mktab blowfish-mktab twofish-mktab rijndael-mktab serpent-check \ |
| 267 | gfshare-mktab |
| 268 | LDADD = libcatacomb.la |
| 269 | |
| 270 | dsig_SOURCES = dsig.c getdate.y getdate.h |
| 271 | |
| 272 | key_SOURCES = keyutil.c getdate.y getdate.h |
| 273 | |
| 274 | pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c |
| 275 | pixie_LDADD = |
| 276 | |
| 277 | rspit_SOURCES = rspit.c |
| 278 | |
| 279 | des_mktab_SOURCES = des-mktab.c |
| 280 | des_mktab_LDADD = |
| 281 | |
| 282 | blowfish_mktab_SOURCES = blowfish-mktab.c |
| 283 | blowfish_mktab_LDADD = |
| 284 | |
| 285 | twofish_mktab_SOURCES = twofish-mktab.c |
| 286 | twofish_mktab_LDADD = |
| 287 | |
| 288 | rijndael_mktab_SOURCES = rijndael-mktab.c |
| 289 | rijndael_mktab_LDADD = |
| 290 | |
| 291 | serpent_check_SOURCES = serpent-check.c |
| 292 | serpent_check_LDADD = |
| 293 | |
| 294 | gfshare_mktab_SOURCES = gfshare-mktab.c |
| 295 | gfshare_mktab_LDADD = |
| 296 | |
| 297 | genprimes_SOURCES = genprimes.c |
| 298 | genprimes_LDADD = |
| 299 | |
| 300 | mptypes_SOURCES = mptypes.c |
| 301 | mptypes_LDADD = |
| 302 | |
| 303 | ## --- Install the pixie setuid-root if we can --- |
| 304 | |
| 305 | changequote(<, >) |
| 306 | install-exec-hook: |
| 307 | @pixie="$(bindir)/`echo pixie|sed $(transform)`"; \ |
| 308 | if chown root $$pixie && chmod 4755 $$pixie; then \ |
| 309 | echo "chown root $$pixie"; \ |
| 310 | echo "chmod 4755 $$pixie"; \ |
| 311 | else \ |
| 312 | echo "***"; \ |
| 313 | echo "*** You should probably install $$pixie setuid-root."; \ |
| 314 | echo "***"; \ |
| 315 | fi |
| 316 | changequote(`, ') |
| 317 | |
| 318 | ## --- Documentation --- |
| 319 | |
| 320 | man_MANS = key.1 keyring.5 |
| 321 | |
| 322 | ## --- Other handy definitions --- |
| 323 | |
| 324 | EXTRA_DIST = \ |
| 325 | Makefile.m4 genmodes $(man_MANS) xpixie \ |
| 326 | README.cipher README.hash README.random README.mp |
| 327 | |
| 328 | dist-hook: |
| 329 | @ln getdate.c $(distdir) || ln $(srcdir)/getdate.c $(distdir) || true |
| 330 | @mkdir $(distdir)/tests || true |
| 331 | @ln $(srcdir)/tests/* $(distdir)/tests || true |
| 332 | @rm -f $(distdir)/tests/*~ |
| 333 | # kr=$$HOME/.catacomb/dsig-keyring; \ |
| 334 | # if [ -r $$kr ]; then \ |
| 335 | # cd $(distdir); \ |
| 336 | # ../key -k $$kr extract -f -secret KEYRING; \ |
| 337 | # find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \ |
| 338 | # fi |
| 339 | |
| 340 | ## --- Testing --- |
| 341 | |
| 342 | define(`testprogs', `') |
| 343 | |
| 344 | define(`CTESTRIG', |
| 345 | `define(`testprogs', testprogs \ |
| 346 | $1.t)dnl |
| 347 | $1.to: $1.c |
| 348 | $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to |
| 349 | $1.t: $1.to $1.o libcatacomb.la |
| 350 | $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t') |
| 351 | |
| 352 | CTESTRIG(rc4) |
| 353 | CTESTRIG(seal) |
| 354 | adorn(`nl`'CTESTRIG(', `ciphers', `)') |
| 355 | adorn(`nl`'CTESTRIG(', `hashes', `)') |
| 356 | adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)') |
| 357 | adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)') |
| 358 | CTESTRIG(lcrand) |
| 359 | CTESTRIG(mpx) |
| 360 | CTESTRIG(mpx-kmul) |
| 361 | CTESTRIG(mpx-ksqr) |
| 362 | CTESTRIG(mp-arith) |
| 363 | CTESTRIG(mp-gcd) |
| 364 | CTESTRIG(mp-jacobi) |
| 365 | CTESTRIG(mptext) |
| 366 | CTESTRIG(mpint) |
| 367 | CTESTRIG(mpbarrett) |
| 368 | CTESTRIG(mpmont) |
| 369 | CTESTRIG(mpmont-mexp) |
| 370 | CTESTRIG(mpcrt) |
| 371 | CTESTRIG(pgen) |
| 372 | CTESTRIG(dsa-gen) |
| 373 | CTESTRIG(dsa-sign) |
| 374 | CTESTRIG(dsa-verify) |
| 375 | CTESTRIG(bbs-rand) |
| 376 | CTESTRIG(bbs-jump) |
| 377 | CTESTRIG(gfshare) |
| 378 | CTESTRIG(share) |
| 379 | |
| 380 | TESTS = testprogs |
| 381 | |
| 382 | CLEANFILES = \ |
| 383 | *.t *.to \ |
| 384 | mptypes.h primetab.c primetab.h \ |
| 385 | des-sp.h twofish-tab.h blowfish-tab.h |
| 386 | |
| 387 | ## --- Makefile building (haha!) --- |
| 388 | |
| 389 | $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4 |
| 390 | m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am |
| 391 | |
| 392 | MAINTAINERCLEANFILES = \ |
| 393 | $(srcdir)/Makefile.am \ |
| 394 | $(srcdir)/getdate.c getdate.c \ |
| 395 | $(MODES) |
| 396 | |
| 397 | ##----- That's all, folks --------------------------------------------------- |