[zx-fizzbuzz] / fizzbuzz.s

;;; -*-asm-*-
;;; (c) 2021 Mark Wooding
;;;
;;; Best not to ask why.

;;;----- Licensing notice ---------------------------------------------------
;;;
;;; This file is part of ZX Fizzbuzz.
;;;
;;; ZX Fizzbuzz is free software: you can redistribute it and/or modify it
;;; under the terms of the GNU Lesser General Public License as published
;;; by the Free Software Foundation; either version 3 of the License, or
;;; (at your option) any later version.
;;;
;;; ZX Fizzbuzz is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; Lesser General Public License for more details.
;;;
;;; You should have received a copy of the GNU Lesser General Public
;;; License along with ZX Fizzbuzz.  If not, see
;;; <https://www.gnu.org/licenses/>.

	;; Look at the buffer and decide what to do.
again:	ld	e, 0

	;; First, decide whether it's a multiple of three.  This is a bit
	;; fiddly.
	ld	a, (len)
	ld	b, a
	ld	hl, buf
	xor	a

	;; Main `mod 3' loop.  Load a byte and add it into the accumulator in
	;; decimal.
mod3:	ld	c, (hl)
	inc	hl
	add	a, c
	daa
	jr	nc, mod3_1
	call	squish
	add	a, 1
	daa
mod3_1:	djnz	mod3

	call	squish
	call	squish

	and	a
	jr	z, prfizz
	cp	3
	jr	z, prfizz
	cp	6
	jr	z, prfizz
	cp	9
	jr	nz, nofizz

prfizz:	ld	hl, fizz
	call	print
	inc	e

	;; Next, decide whether it's a multiple of five.  This is easier.
nofizz:	ld	a, (buf)
	and	0x0f
	jr	z, prbuzz
	cp	5
	jr	nz, nobuzz

prbuzz:	ld	hl, buzz
	call	print
	jr	prnl

	;; Not a multiple of five.  Skip ahead if it was a multiple of three.
nobuzz:	ld	a, e
	and	a
	jr	nz, prnl

	;; OK, so just print the value.
	ld	hl, buf - 1
	ld	bc, (len)
	add	hl, bc
	ld	b, c

	ld	a, (hl)
	ld	d, a
	srl	a
	srl	a
	srl	a
	srl	a
	jr	z, skiplz
	fixdig
	print_a
skiplz:	ld	a, d
	and	0x0f
	fixdig
	print_a
	dec	b
	jr	z, prnl

prdig:	dec	hl
	ld	a, (hl)
	ld	d, a
	srl	a
	srl	a
	srl	a
	srl	a
	fixdig
	print_a
	ld	a, d
	and	0x0f
	fixdig
	print_a
	djnz	prdig

	;; Print the newline.
prnl:	ld	a, spc
	print_a

	;; Increment the counter.
	ld	hl, buf
	ld	a, (len)
	ld	b, a
	scf
incr:	ld	a, (hl)
	adc	a, 0
	daa
	ld	(hl), a
	jp	nc, again
	inc	hl
	djnz	incr

	;; Carry out.
	ld	(hl), 1
	ld	hl, len
	inc	(hl)
	jp	again

squish:
	;; Add the two halves of a.
	ld	c, a
	and	0x0f
	srl	c
	srl	c
	srl	c
	srl	c
	add	a, c
	daa
	ret

print:
	;; Print the string at hl.
	ld	a, (hl)
	endstrp
	ret	z
	print_a
	inc	hl
	jr	print

	;; Initial state.  The buffer notionally continues for another 254
	;; bytes, but there's no point in including them in the image.
len:	db	1, 0
buf:	db	1
Commit	Line	Data
a221d644	1	;;; --asm--
4278b406	2	;;; (c) 2021 Mark Wooding
a221d644 MW	3	;;;
	4	;;; Best not to ask why.
	5
4278b406 MW	6	;;;----- Licensing notice ---------------------------------------------------
	7	;;;
	8	;;; This file is part of ZX Fizzbuzz.
	9	;;;
	10	;;; ZX Fizzbuzz is free software: you can redistribute it and/or modify it
	11	;;; under the terms of the GNU Lesser General Public License as published
	12	;;; by the Free Software Foundation; either version 3 of the License, or
	13	;;; (at your option) any later version.
	14	;;;
	15	;;; ZX Fizzbuzz is distributed in the hope that it will be useful, but
	16	;;; WITHOUT ANY WARRANTY; without even the implied warranty of
	17	;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
	18	;;; Lesser General Public License for more details.
	19	;;;
	20	;;; You should have received a copy of the GNU Lesser General Public
	21	;;; License along with ZX Fizzbuzz. If not, see
	22	;;; <https://www.gnu.org/licenses/>.
	23
a221d644 MW	24	;; Look at the buffer and decide what to do.
	25	again: ld e, 0
	26
	27	;; First, decide whether it's a multiple of three. This is a bit
	28	;; fiddly.
	29	ld a, (len)
	30	ld b, a
	31	ld hl, buf
	32	xor a
	33
	34	;; Main `mod 3' loop. Load a byte and add it into the accumulator in
	35	;; decimal.
	36	mod3: ld c, (hl)
	37	inc hl
	38	add a, c
	39	daa
	40	jr nc, mod3_1
	41	call squish
	42	add a, 1
	43	daa
	44	mod3_1: djnz mod3
	45
	46	call squish
	47	call squish
	48
64b6fca5	49	and a
a221d644 MW	50	jr z, prfizz
	51	cp 3
	52	jr z, prfizz
	53	cp 6
	54	jr z, prfizz
	55	cp 9
	56	jr nz, nofizz
	57
	58	prfizz: ld hl, fizz
	59	call print
	60	inc e
	61
	62	;; Next, decide whether it's a multiple of five. This is easier.
	63	nofizz: ld a, (buf)
	64	and 0x0f
	65	jr z, prbuzz
	66	cp 5
	67	jr nz, nobuzz
	68
	69	prbuzz: ld hl, buzz
	70	call print
	71	jr prnl
	72
	73	;; Not a multiple of five. Skip ahead if it was a multiple of three.
	74	nobuzz: ld a, e
64b6fca5	75	and a
a221d644 MW	76	jr nz, prnl
	77
	78	;; OK, so just print the value.
a221d644	79	ld hl, buf - 1
0bf6b60e	80	ld bc, (len)
a221d644 MW	81	add hl, bc
	82	ld b, c
	83
	84	ld a, (hl)
	85	ld d, a
	86	srl a
	87	srl a
	88	srl a
	89	srl a
	90	jr z, skiplz
64b6fca5 MW	91	fixdig
64b6fca5 MW	92	print_a
a221d644 MW	93	skiplz: ld a, d
a221d644 MW	94	and 0x0f
64b6fca5 MW	95	fixdig
64b6fca5 MW	96	print_a
a221d644 MW	97	dec b
	98	jr z, prnl
	99
	100	prdig: dec hl
	101	ld a, (hl)
	102	ld d, a
	103	srl a
	104	srl a
	105	srl a
	106	srl a
64b6fca5 MW	107	fixdig
64b6fca5 MW	108	print_a
a221d644 MW	109	ld a, d
a221d644 MW	110	and 0x0f
64b6fca5 MW	111	fixdig
64b6fca5 MW	112	print_a
a221d644 MW	113	djnz prdig
	114
	115	;; Print the newline.
64b6fca5 MW	116	prnl: ld a, spc
64b6fca5 MW	117	print_a
a221d644 MW	118
	119	;; Increment the counter.
	120	ld hl, buf
	121	ld a, (len)
	122	ld b, a
	123	scf
	124	incr: ld a, (hl)
	125	adc a, 0
	126	daa
	127	ld (hl), a
	128	jp nc, again
	129	inc hl
	130	djnz incr
	131
	132	;; Carry out.
a221d644	133	ld (hl), 1
b4fd0180 MW	134	ld hl, len
b4fd0180 MW	135	inc (hl)
a221d644 MW	136	jp again
	137
	138	squish:
	139	;; Add the two halves of a.
	140	ld c, a
	141	and 0x0f
	142	srl c
	143	srl c
	144	srl c
	145	srl c
	146	add a, c
	147	daa
	148	ret
	149
	150	print:
	151	;; Print the string at hl.
	152	ld a, (hl)
64b6fca5	153	endstrp
a221d644	154	ret z
64b6fca5	155	print_a
a221d644 MW	156	inc hl
	157	jr print
	158
64b6fca5 MW	159	;; Initial state. The buffer notionally continues for another 254
64b6fca5 MW	160	;; bytes, but there's no point in including them in the image.
0bf6b60e	161	len: db 1, 0
64b6fca5	162	buf: db 1