dnl -*-autoconf-*-
dnl
dnl Configuration script for zoneconf
dnl
dnl (c) 2011 Mark Wooding
dnl

dnl----- Licensing notice ---------------------------------------------------
dnl
dnl This program is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2 of the License, or
dnl (at your option) any later version.
dnl
dnl This program is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with this program; if not, write to the Free Software Foundation,
dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

dnl Initialization.
mdw_AUTO_VERSION
AC_INIT([zoneconf], AUTO_VERSION, [mdw@distorted.org.uk])
AC_CONFIG_SRCDIR([zoneconf.in])
AC_CONFIG_AUX_DIR([config])
AM_INIT_AUTOMAKE([foreign])
mdw_SILENT_RULES

dnl Directories for things.
AC_MSG_CHECKING([where the BIND utility programs are])
bindprogsdir=none
for dir in \
  /bin /usr/bin /sbin /usr/sbin /usr/local/bin /usr/local/sbin \
  $(echo $PATH | tr : " ")
do
  foundp=t
  for prog in rndc named-checkzone dnssec-signzone; do
    if ! test -x "$dir/$prog"; then
      foundp=nil
      break
    fi
  done
  case $foundp in t) bindprogsdir=$dir; break ;; esac
done
case $bindprogsdir in
  none) AC_MSG_ERROR([Failed to find BIND utilties.]) ;;
esac
AC_MSG_RESULT([$bindprogsdir])
AC_SUBST([bindprogsdir])

dnl Tcl language support.
AX_PROG_TCL([8.5])

dnl Output.
AC_CONFIG_FILES(
  [Makefile])
AC_OUTPUT

dnl----- That's all, folks --------------------------------------------------