dnl -*-autoconf-*-
dnl
dnl Configuration script for X tools
dnl
dnl (c) 1998 Straylight/Edgeware
dnl

dnl ----- Licensing notice --------------------------------------------------
dnl
dnl This file is part of the Edgeware X tools collection.
dnl
dnl X tools is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2 of the License, or
dnl (at your option) any later version.
dnl
dnl X tools is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with X tools; if not, write to the Free Software Foundation,
dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

dnl--------------------------------------------------------------------------
dnl Initialization.

mdw_AUTO_VERSION
AC_INIT([xtoys], AUTO_VERSION, [mdw@distorted.org.uk])
AC_CONFIG_SRCDIR([xscsize.c])
AC_CONFIG_AUX_DIR([config])
AM_INIT_AUTOMAKE([foreign])
mdw_SILENT_RULES

dnl--------------------------------------------------------------------------
dnl C programming environment.

AC_PROG_CC
AX_CFLAGS_WARN_ALL
AC_PATH_XTRA

mdw_LIBS=$LIBS LIBS= mdw_have_xrandr_p=nil
AC_SEARCH_LIBS([XRRGetScreenInfo], [Xrandr], [mdw_have_xrandr_p=t])
case $mdw_have_xrandr_p in
  t)
    AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [], [mdw_have_xrandr_p=nil])
    ;;
esac
case $mdw_have_xrandr_p in
  t)
    XRANDR_LIBS=$LIBS
    AC_DEFINE([HAVE_XRANDR], [1], [Define if libXrandr is installed.])
    ;;
esac
LIBS=$mdw_LIBS
AC_SUBST([XRANDR_LIBS])

PKG_CHECK_MODULES([mLib], [mLib >= 2.0.4])
CFLAGS="$CFLAGS $mLib_CFLAGS"
LIBS="$LIBS $mLib_LIBS"

dnl--------------------------------------------------------------------------
dnl Python programming environment.

AM_PATH_PYTHON([2.4], [python=yes], [python=no])
AM_CONDITIONAL([HAVE_PYTHON], [test $python = yes])

if test $python = yes; then
  AC_PYTHON_MODULE([pygtk])
fi
AM_CONDITIONAL([HAVE_PYGTK], [test ${HAVE_PYMOD_PYGTK-no} = yes])

dnl--------------------------------------------------------------------------
dnl Output.

AC_CONFIG_FILES(
  [Makefile])
AC_OUTPUT

dnl ----- That's all, folks -------------------------------------------------