log repository location

[userv-utils] / git-daemon / git-daemon.pl

#!/usr/bin/perl
#
# A git daemon with an added userv security boundary.
#
# This was written by Tony Finch <dot@dotat.at>
# You may do anything with it, at your own risk.
# http://creativecommons.org/publicdomain/zero/1.0/

use strict;
use warnings;

use POSIX;
use Socket;
use Sys::Syslog;

sub ntoa {
    my $sockaddr = shift;
    return ('[?.?.?.?]:?') unless defined $sockaddr;
    my ($port,$addr) = sockaddr_in $sockaddr;
    $addr = inet_ntoa $addr;
    return ("[$addr]:$port",$addr,$port);
}
our ($client,$client_addr,$client_port) = ::ntoa(getpeername(STDIN));
our ($server,$server_addr,$server_port) = ::ntoa(getsockname(STDIN));
our ($service,$path,$host,$uri,$user);

openlog 'userv-git-daemon', 'pid', 'daemon';
sub fail { syslog 'err', "$client @_"; exit }

sub xread {
    my $length = shift;
    my $buffer = "";
    local $SIG{ALRM} = sub { fail "timeout" };
    alarm 30;
    while ($length > length $buffer) {
        my $ret = sysread STDIN, $buffer, $length, length $buffer;
        fail "short read: expected $length bytes, got " . length $buffer
                            if defined $ret and $ret == 0;
        fail "read: $!" if not defined $ret and $! != EINTR and $! != EAGAIN;
    }
    alarm 0;
    return $buffer;
}

my $len_hex = xread 4;
fail "non-hex packet length" unless $len_hex =~ m{^[0-9a-fA-F]{4}$};
my $line = xread hex $len_hex;
if ($line !~ m{^(git-[a-z-]+) /*([!-~]+)\0host=([!-~]+)\0$}) {
    $line =~ s|[^ -~]+| |g;
    fail "could not parse \"$line\""
}
($service,$path,$host) = ($1,$2,$3);
$_ = $uri = "git://$host/$path";
for my $cf (@ARGV) { do $cf }

fail "no user configured for $uri" unless defined $user;
syslog 'info', "$client $service $uri";

my @opts = map "-D$_=${$main::{$_}}",
        grep defined ${$main::{$_}} && /^[a-z]+$/,
             sort keys %main::;

my @cmd = ('userv', @opts, $user, $service);
no warnings; # suppress errors to stderr
exec @cmd or fail "exec @cmd: $!";

# end