dnl ----- Licensing notice --------------------------------------------------
dnl
dnl This file is part of sw-tools.
dnl
dnl sw-tools is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2 of the License, or
dnl (at your option) any later version.
dnl 
dnl sw-tools is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl 
dnl You should have received a copy of the GNU General Public License
dnl along with sw-tools; if not, write to the Free Software Foundation,
dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

dnl --- Boring boilerplate ---

AC_INIT(src/sw.c)
AM_INIT_AUTOMAKE(sw-tools, 1.0.5mdw2)
AM_CONFIG_HEADER(config.h)

dnl --- Work out the architecture name ---

AC_MSG_CHECKING([architecture name])
arch=`$srcdir/sw.in --archname`
AC_MSG_RESULT($arch)
AC_DEFINE_UNQUOTED(ARCH, "$arch", [My architecture name.])
AC_SUBST(arch)

dnl --- Set up the C compiler ---

AC_PROG_CC
mdw_GCC_FLAGS

dnl --- Find a Perl ---

mdw_PROG_PERL(5.003)
mdw_CHECK_PERL(5.003)

dnl --- Find an appropriate remote shell program ---

AC_ARG_WITH(rsh,
[  --with-rsh=PROGRAM      use PROGRAM to start remote shells],
[RSH=$withval])
AC_PATH_PROGS(RSH, $RSH remsh rsh ssh, rsh)
AC_DEFINE_UNQUOTED(RSH, "$RSH", [Default remote shell program.])

dnl --- Various simple tests ---

AC_CHECK_HEADERS(unistd.h)
mdw_DECL_ENVIRON
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_UID_T
mdw_TYPE_SSIZE_T
AC_CHECK_FUNCS(strsignal _sys_siglist, break)
mdw_CURSES
mdw_MLIB
mdw_CHECK_MANYLIBS(socketpair, socket)

dnl --- Write in some useful paths ---


mdw_DEFINE_PATHS([
  mdw_DEFINE_PATH([PREFIX], [$prefix])
  mdw_DEFINE_PATH([DATADIR], [$datadir])
  mdw_DEFINE_PATH([ARCHTAB], [$datadir/archtab])
  mdw_DEFINE_PROG([PATH_SW], [sw])
  pkgdatadir=mdw_PATH([$datadir/$PACKAGE]) AC_SUBST(pkgdatadir)
  SW=mdw_PROG(sw) AC_SUBST(SW)
])

dnl --- Output the configuration ---

AC_OUTPUT(dnl
  Makefile src/Makefile perl/Makefile dnl
  perl/SWConfig.pm perl/sw perl/sw-tidy dnl
  sw sw-share dnl
)

dnl ----- That's all, folks -------------------------------------------------